SET /P Not Working After Checking For Administrator Privileges - batch-file

Question

I'm trying to force the user to run the script using administrative privileges:
#echo off
net session >nul 2>&1
if %errorlevel% == 0 (
echo Success: Administrative permissions confirmed.
echo.
echo Please Choose:
echo 1. Enable
echo 2. Disable
echo 3. Exit
set /p choice="> "
echo Choice: "%choice%"
) else (
echo Failure: Please run as administrator
)
pause
The net session and errorlevel lines check the privilege, and this works. The weird thing is that no matter what gets entered for choice it behaves as if it was never initialized.
The code running inside the if block works fine by itself, so I suspect the issue has something to do with how I'm checking for privileges.
Can someone explain this behavior, and any fixes?

Answer 1

You'd need either delayed expansion or avoid it by reorganizing your code a bit, like:
#echo off
net session >nul 2>&1
if %errorlevel% == 1 (
echo Failure: Please run as administrator
exit 1
)
echo Success: Administrative permissions confirmed.
etc.

Answer 2

The issue is because you are setting a variable within an If block, without delaying variable expansion.
However, you don't need the if block at all, nor do you need to set a variable for the selection.
The following method uses the || which essentially means 'if previous command produced an error', replaces the Set /P command with Choice and uses timed pauses via the Timeout command:
#Echo Off
Net Session >Nul 2>&1 || (
Echo Failure: Please run as administrator
Timeout 3 /NoBreak >Nul
Exit /B
)
Echo Success: Administrative permissions confirmed.
Echo=
Echo 1. Enable
Echo 2. Disable
Echo 3. Exit
Choice /C 123 /M "Please Choose"
If ErrorLevel 3 Exit /B
If ErrorLevel 2 GoTo Disable
Echo Enabling
Timeout 3 /NoBreak >Nul
Exit /B
:Disable
Echo Disabling
Timeout 3 /NoBreak >Nul
Exit /B