Embedded Implicit Loops in SAS with two Set Statements - loops

Question

I have the below code to track specific manufacturer coupon issuings. Each issue can have dollars in the redeemed, expired and remaining fields. I have an ISSUE table that gives all of the issuings and amounts and the REDEMPTIONS table that is an accounting of amounts redeemed or expired. The objective is to track all coupon dollars for each issue by putting the appropriate amounts in each category.
This code is supposed to loop through the ISSUE table and tie matching records from the REDEMPTIONS table to each record in the ISSUE table.
/*create sample tables*/
data ISSUE; input
Coupon_NBR $ AMOUNT REDEEMED EXPIRED REMAINING; datalines;
A 500 0 0 500
A 500 0 0 500
B 500 0 0 500
B 500 0 0 500
B 500 0 0 500
B 1250 0 0 1250
B 750 0 0 750
C 500 0 0 500
C 500 0 0 500
C 500 0 0 500
C 500 0 0 500
C 500 0 0 500
run;
data REDEMPTIONS; input
Redemp_coupon_NBR $ TRANS_AMOUNT TYPE $16.; datalines;
A -150 REDEMPTION
A -350 REDEMPTION
A -200 EXPIRATION
B -300 REDEMPTION
B -200 EXPIRATION
B -1000 REDEMPTION
C -1500 REDEMPTION
C -500 EXPIRATION
run;
/*begin looping code*/
data Tracking;
if _n_ = 1 then Link get_redemptions;
set issue;
if (remaining > 0) and (Coupon_NBR = Redemp_coupon_NBR) then do;
if trans_amount = 0 then
link get_redemptions;
if trans_amount + remaining >=0 then do;
remaining = remaining + trans_amount;
if type = 'EXPIRATION' then;
expired = expired - trans_amount;
if type = 'REDEMPTION' then;
redeemed = redeemed - trans_amount;
link get_redemptions;
end;
else do;
remaining = 0;
if type = 'EXPIRATION' then do;
expired = expired - trans_amount;
end;
else do;
redeemed = redeemed - trans_amount;
trans_amount = trans_amount + remaining;
remaining = 0;
end;
end;
end;
else do;
link get_redemptions;
end;
return;
get_redemptions:
set redemptions;
return;
run;
This is the output I'm getting:
Coupon_NBR AMOUNT REDEEMED EXPIRED REMAINING redemp_coupon_nbr trans_amount type
A 500 150 150 350 A -350 REDEMPTION
A 500 350 350 150 A -200 EXPIRATION
B 500 0 0 500 B -300 REDEMPTION
B 500 300 300 200 B -200 EXPIRATION
B 500 200 200 300 B -1000 REDEMPTION
B 1250 1000 1000 250 C -1500 REDEMPTION
B 750 0 0 750 C -500 EXPIRATION
In this example, the correct output is:
redemp_coupon_nbr AMOUNT REDEEMED EXPIRED REMAINING
A 500 500 0 0
A 500 0 200 300
B 500 300 200 0
B 500 500 0 0
B 500 500 0 0
B 1250 0 0 1250
B 750 0 0 750
C 500 500 0 0
C 500 500 0 0
C 500 500 0 0
C 500 0 500 0
C 500 0 0 500
Obviously my result is far from where I want it to be. My main concern, however, is that the output only has seven rows, when I want it track every coupon issue, which means I need it to have 12 rows (one for each row in the ISSUE table). There is some kind of a problem with my loop I think specifically in the Get Redemptions definition. I've been debugging for a while without success.

Answer 1

Jarom:
A robust solution requires a transactional ledgering approach in order to properly deal with the alternatives of fetching multiple redemptions per coupon and tracking overages, and applying overages to a coupon before fetching additional redemptions.
The following sample code has numerous put statements so you can observe the algorithm decision points in the log. The balance goal is to approach zero (from above or below) at each transaction reconciliation, and track any portions that go beyond the goal.
For the sample these variable names substitutions were done with respect to your data.
coupon_nbr -> G
redemp_coupon_nbr -> XG
trans_amount -> XAMOUNT
You were correct in needing a LINK to fetch the redemptions.
The group wise processing is further facilitated by adding BY XG and END=.
Tests for the redemptions end= variable prevent a premature halting of the data step (which would occur if a subsequent unconditional set is reached after a data sets last record is read).
data reconciliation (keep=G AMOUNT REDEEMED EXPIRED REMAINING EXCESS APP_COUNT _redem_bal _expir_bal fetch_sum)
; * / debug;
set issue;
by G;
REDEEMED = 0;
EXPIRED = 0;
REMAINING = 0;
EXCESS = 0;
if 0 then set redemptions; %* prep pdv;
retain _balance 0;
retain _redem_sum 0;
retain _expir_sum 0;
retain _redem_bal 0;
retain _expir_bal 0;
if first.g then put / '----------- ' G= '-------------';
put '#set ' _N_=;
put 'balance: ' _balance _redem_bal= _expir_bal=;
put 'coupon : ' amount first.g= /;
if first.G then do;
put #3 '#first in group';
_balance = amount;
_redem_sum = 0;
_redem_bal = 0;
_expir_sum = 0;
_expir_bal = 0;
put #3 'balance: ' _balance _redem_bal= _expir_bal= G= XG=;
* spin to first matching redemption or first redemption in a higher by-group;
if (XG ne G) then
do while (not EOT);
link fetch;
if XG >= G then leave;
end;
if (G = XG) then
link apply_redemp;
put #6 'spin: ' G= XG=;
end;
else do; * additional couponage;
put #3 '#next in group';
if (G = XG) then
_balance + amount;
else
_balance = amount;
put #3 'balance: ' _balance _redem_bal= _expir_bal=;
link apply_excess_to_balance;
put #3 'balance: ' _balance _redem_bal= _expir_bal= xg= last.xg=;
if (_balance > 0 and G = XG and not last.XG) then
link fetch_apply;
end;
if (G = XG) then
do while (not EOT and not last.XG and _balance > 0);
link fetch_apply;
end;
redeemed = _redem_sum;
expired = _expir_sum;
remaining = min (_balance, amount);
excess = sum (_redem_bal, _expir_bal, max (0, _balance - amount));
output;
put #4 'output: ' amount= redeemed= expired= remaining= excess= /;
_redem_sum = 0;
_expir_sum = 0;
return;
apply_excess_to_balance:
if (_redem_bal > 0 and _balance > 0) then do;
apply = min ( _balance, _redem_bal );
_redem_sum + apply;
_redem_bal + -apply;
_balance + -apply;
app_count = sum(app_count,1);
put #4 'excess: ' apply= _redem_bal= _redem_sum= _balance= 'reduced amount by excess redemption';
end;
if (_expir_bal > 0 and _balance > 0) then do;
apply = min ( _balance, _expir_bal );
_expir_sum + apply;
_expir_bal + -apply;
_balance + -apply;
app_count = sum(app_count,1);
put #4 'excess: ' apply= _expir_bal= _expir_sum= _balance= 'reduced amount by excess expiration';
end;
return;
fetch:
set redemptions end=EOT;
by XG;
put #5 'fetch: ' xg= xamount= type= first.xg= last.xg= EOT=;
return;
fetch_apply:
link fetch;
if (G = XG) then
link apply_redemp;
return;
apply_redemp:
if type in: ('RED' 'EXP') then do;
apply = min (_balance, -XAMOUNT);
excess = max (0, -XAMOUNT - _balance);
if type =: 'RED' then do;
_redem_sum + apply;
_redem_bal + excess;
end;
else
if type =: 'EXP' then do;
_expir_sum + apply;
_expir_bal + excess;
end;
_balance + -apply;
app_count = sum(app_count,1);
fetch_sum = sum(fetch_sum, -xamount);
put #5 'apply: ' apply= _balance= _redem_sum= _expir_sum= _redem_bal= _expir_bal=;
end;
return;
run;
Here is some additional sample data with
non matching redemption
B group has a first redemption which is a large excess that spans two coupons.
coupon group with no redemptions
Trickier data
data ISSUE; input
G $ AMOUNT;
A 500
A 500
B 500
B 500
B 500
B 1250
B 750
B2 100
B2 200
C 500
C 500
C 500
C 500
C 500
run;
data REDEMPTIONS; input
XG $ XAMOUNT TYPE $16.; datalines;
! -1000 REDEMPTION
A -150 REDEMPTION
A -350 REDEMPTION
A -200 EXPIRATION
B -1100 REDEMPTION was -300
B -200 EXPIRATION
B -1000 REDEMPTION
C -1500 REDEMPTION
C -500 EXPIRATION
run;