How can I merge the data files with matching the data at Windows batch - batch-file

Question

I'm sorry but I'm not good at Windows batch.
I want to merge two or more files with matching by key value. Those files has different numbers of the lines.
For example:
File_A.txt
Time, D1, D2
1.1, 11, 12
1.2, 21, 22
1.3, 31, 32
1.4, 41, 42
1.5, 51, 52
File_B.txt
Time, D3, D4
1.1, 13, 14
1.3, 33, 34
1.4, 43, 44
File_C.txt
Time, D5, D6
1.2, 25, 26
1.4, 45, 46
1.5, 55, 56
I want to get:
Merged.txt
Time, D1, D2, D3, D4, D5, D6
1.1, 11, 12, 13, 14
1.2, 21, 22, , , 25, 26
1.3, 31, 32, 33, 34
1.4, 41, 42, 43, 44, 45, 46
1.5, 51, 52, , , 55, 56
If I make it at C / C++, then it will be easy, but because of my situation, I have to make it at Windows batch, and I cannot imagenate how I have to do.
Please give your favor.

Answer 1

This solution process all files named File_*.txt in current directory and assume that the "master file" (the one with all keys) is the first file.
#echo off
setlocal EnableDelayedExpansion
set "keys="
for %%f in (File_*.txt) do (
if not defined keys (
for /F "usebackq tokens=1* delims=," %%a in ("%%f") do (
set "line[%%a]=%%a,%%b"
set "keys=!keys! %%a"
)
) else (
set "rest=!keys!"
for /F "usebackq tokens=1* delims=," %%a in ("%%f") do (
set "line[%%a]=!line[%%a]!,%%b"
set "rest=!rest: %%a=!"
)
for %%k in (!rest!) do set "line[%%k]=!line[%%k]!, , "
)
)
(for %%k in (%keys%) do echo !line[%%k]!) > Merged.txt
Using your three example files as input, this is the output:
Time, D1, D2, D3, D4, D5, D6
1.1, 11, 12, 13, 14, ,
1.2, 21, 22, , , 25, 26
1.3, 31, 32, 33, 34, ,
1.4, 41, 42, 43, 44, 45, 46
1.5, 51, 52, , , 55, 56

Answer 2

Here is a batch script that should do what you want, although it is not very efficient on large files. It relies on the fact that all the files have got the same number of columns (three in our situation), and that the first file provided has got all possible values in its first column. Supposing the script is saved as merge.bat, you need to provide the files to merge as command line arguments, like:
merge.bat "File_A.txt" "File_B.txt" "File_C.txt"
The result file will always be Merged.txt in the current working directory. So here is the code:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem // Define constants here:
set "_SEPAR=, "
set "_FILL=%_SEPAR% %_SEPAR% "
set "_RESULT=Merged.txt"
set "FIRST=#"
for %%A in (%*) do (
if defined FIRST (
> nul copy /Y "%%~nxA" "%_RESULT%"
set "FIRST="
) else (
> "%_RESULT%.tmp" (
for /F usebackq^ delims^=^ eol^= %%F in ("%_RESULT%") do (
set "FLAG=" & set "LINE=%%F"
for /F usebackq^ delims^=^ eol^= %%I in ("%%~A") do (
for /F "eol=%_SEPAR:~,1% delims=%_SEPAR%" %%E in ("%%F") do (
for /F "tokens=1* eol=%_SEPAR:~,1% delims=%_SEPAR%" %%J in ("%%I") do (
if "%%E"=="%%J" set "STR=%%K" & set "FLAG=#"
)
)
)
setlocal EnableDelayedExpansion
if defined FLAG (
echo(!LINE!%_SEPAR%!STR!
) else (
echo(!LINE!%_FILL%
)
endlocal
)
)
> nul move /Y "%_RESULT%.tmp" "%_RESULT%"
)
)
endlocal
exit /B
With your sample files as input, the output in Merged.txt is going to be this:
Time, D1, D2, D3, D4, D5, D6
1.1, 11, 12, 13, 14, ,
1.2, 21, 22, , , 25, 26
1.3, 31, 32, 33, 34, ,
1.4, 41, 42, 43, 44, 45, 46
1.5, 51, 52, , , 55, 56
Here is an alternative batch script. In contrast to the other one, the first file is no longer expected to contain all possible values in its first column. This is the code:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem // Define constants here:
set "_SEPAR=, "
set "_FILL=%_SEPAR% %_SEPAR% "
set "_RESULT=Merged.txt"
for /F "delims==" %%E in ('set "$" 2^> nul') do set "%%E="
set /A "INDEX=0"
for %%A in (%*) do (
for /F "usebackq eol=%_SEPAR:~,1% delims=%_SEPAR%" %%E in ("%%~A") do (
call set "NUMBER=000000000000%%INDEX%%"
if not defined $[%%E] call set "$[%%E]=%%NUMBER:~-12%%%_SEPAR%%%E"
set /A "INDEX+=1"
)
)
> "%_RESULT%.tmp" (
for /F "tokens=1* delims==" %%E in ('set "$"') do #(
echo(%%F
)
)
> "%_RESULT%" (
for /F "tokens=1* delims=%_SEPAR%" %%E in ('sort "%_RESULT%.tmp"') do #(
echo(%%F
)
)
del "%_RESULT%.tmp"
for %%A in (%*) do (
> "%_RESULT%.tmp" (
for /F usebackq^ delims^=^ eol^= %%F in ("%_RESULT%") do (
set "FLAG=" & set "LINE=%%F"
for /F usebackq^ delims^=^ eol^= %%I in ("%%~A") do (
for /F "eol=%_SEPAR:~,1% delims=%_SEPAR%" %%E in ("%%F") do (
for /F "tokens=1* eol=%_SEPAR:~,1% delims=%_SEPAR%" %%J in ("%%I") do (
if "%%E"=="%%J" set "STR=%%K" & set "FLAG=#"
)
)
)
setlocal EnableDelayedExpansion
if defined FLAG (
echo(!LINE!%_SEPAR%!STR!
) else (
echo(!LINE!%_FILL%
)
endlocal
)
)
> nul move /Y "%_RESULT%.tmp" "%_RESULT%"
)
endlocal
exit /B