Batch to insert a line in a text file - batch-file

Question

My goal is to make a script which is able to insert a string under a specific line. This is what I have done:
SETLOCAL ENABLEDELAYEDEXPANSION
set outputFile=C:\Utilisateurs\a669884\Documents\script22.txt
set "_strInsert=import java.interceptor.ReportInterceptor;"
set "_strFind=import javax.interceptor.Interceptors;"
:Ask
echo Are you in the good folder (wlp-cas-provider)?(Y/N)
set INPUT=
set /P INPUT=Type input: %=%
If /I "%INPUT%"=="y" goto yes
If /I "%INPUT%"=="n" goto no
echo Incorrect input & goto Ask
:yes
for %%i in (*.java) DO (
FOR /F "usebackq delims=" %%A IN ("%%i") DO (
Echo %%A | Find "%_strFind%" && ECHO %%A>>"%outputFile%" && ECHO %_strInsert%>>"%outputFile%"
IF [!errorlevel!] == [1] ECHO %%A>>"%outputFile%"
)
MOVE /Y "%outputFile%" "%%i" && DEL /F /Q "%outputFile%"
)
:no
echo Oh no! Go to the right folder and comeback
cls
pause
The main idea is to copy the modified text in a temporary file and paste it in the original file. After that, the temporary file is deleted.
The code is working perfectly when it's done on only one file. With the for in order to do it on all .java files in a folder, it's not working anymore. The temporary file script22.txt is not deleted anymore and the text is piled up in it.

Answer 1

How about something along these lines: (untested)
#ECHO OFF
FOR %%A IN ("%CD%") DO IF /I NOT "%%~nxA"=="wlp-cas-provider" (
ECHO=Please change directory to wlp-cas-provider
ECHO= before running this script again.
ECHO=
ECHO=Press any key to exit ...
PAUSE>NUL
GOTO :EOF)
SET "_strFind=import javax.interceptor.Interceptors;"
SET "_strInsert=import java.interceptor.ReportInterceptor;"
SETLOCAL ENABLEDELAYEDEXPANSION
SET NL=^
SET "str2Add=%_strFind%!NL!%_strInsert%"
FOR /F "TOKENS=1-2* DELIMS=:" %%A IN ('FINDSTR/BLINC:"%_strFind%" *.java 2^>NUL'
) DO (SET/A "i=1+%%B"
FINDSTR/BLINC:"%_strInsert%" "%%A"|FINDSTR/B "!i!:">NUL
IF ERRORLEVEL 1 (( FOR /F "TOKENS=1* DELIMS=:" %%D IN ('FINDSTR/N $ "%%A"'
) DO IF %%D EQU %%B (ECHO=!str2Add!) ELSE ECHO=%%E)>>"%%A.tmp"))
FOR %%A IN (*.java.tmp) DO IF EXIST "%%~nA" (DEL "%%~nA" && REN "%%A" "%%~nA")

Answer 2

There is no heavy logical error in your script why the loop should fail. I suspect it is the pipe | that is causing the unexpected behaviour, because it initiates a new command prompt (cmd) instance for either side, where the left one receives an already expanded string (echo %%A), which may contain characters that have special meanings to cmd.
Here is a possible improvement of your script -- see all the explanatory remarks (rem):
#echo off
setlocal DisableDelayedExpansion
rem // Define constants here:
set "targetFolder=C:\Utilisateurs\wlp-cas-provider"
set "fileMask=*.java"
set "outputFile=C:\Utilisateurs\a669884\Documents\script22.txt"
set "_strInsert=import java.interceptor.ReportInterceptor;"
set "_strFind=import javax.interceptor.Interceptors;"
rem // Enumerate all matching files:
for %%I in ("%targetFolder%\%fileMask%") do (
rem /* Redirect the output of the whole `for /F` loop at once;
rem this improves the performance, and there is no appending `>>`,
rem so it does not matter whether the file already exists before: */
> "%outputFile%" (
rem /* Use `findstr /N` to precede every line by its line number
rem and a colon, so no line appears empty to `for /F` any more;
rem remember that `for /F` ignores empty lines otherwise: */
for /F "delims=" %%A in ('findstr /N "^" "%%~I"') do (
rem // Store the current line string with line number prefix:
set "line=%%A"
rem // Toggle delayed expansion to maintain exclamation marks:
setlocal EnableDelayedExpansion
rem // Remove the line number prefix and the colon:
set "line=!line:*:=!"
rem // Return the original line unconditionally:
echo(!line!
rem /* Explicitly initiate another child `cmd` instance on the
rem left side of the pipe with delayed expansion enabled;
rem escape the delayed expansion like `^^!` not to be
rem processed by the parent `cmd` instance, so the child
rem `cmd` instance receives the variable `!line!` only;
rem therefore strings potentially containing special
rem characters are expanded at the very latest point: */
(cmd /V /C echo(^^!line^^!| find "!_strFind!" > nul) && (
rem /* The string to search has been found, so return the
rem string to insert after it at this point: */
echo(!_strInsert!
)
endlocal
)
)
rem // Move the result file over the currently iterated one:
move /Y "%outputFile%" "%%~I" > nul
)
endlocal
exit /B
This allows literally all characters to appear in the search string. Note that quotation marks " need to be doubled to be processed correctly by find. If you want the whole line to match the search string, replace the find command line by findstr /X /C:"!_strFind!". In this case, if quotation marks appear in the search string, escape them like \"; literal backslashes need to be doubled like \\. Add the /I option to find or findstr if you want to search case-insensitively.
You can avoid the block containing the pipe...:
(cmd /V /C echo(^^!line^^!| find "!_strFind!" > nul) && (
echo(!_strInsert!
)
...when you use if statements to compare strings.
For example, use this instead if the line is expected to contain the search string:
if not "!line!"=="!line:*%_strFind%=!" echo(!_strInsert!
This always does a case-insensitive search because of the used sub-string replacement approach. This method may fail if any of the following characters occur in the search string: ^, !, %, =, ".
If the whole line is expected to match the search string, use this instead:
if "!line!"=="!_strFind!" echo(!_strInsert!
This does a case-sensitive search, unless you add the /I switch to the if statement.