Creating a mini-game about guessing - batch-file

Question

So I'm programming a mini-game about writing an id code, and then letting someone guess it. The problem i am facing, is that whenever someone tries to change the font color using the game syntax, just shows an error: "( was unexpected at this time." and just instantly crashes. This is my code at the moment:
#echo off
cls
:play
set /p id=Identification code:
if %id% == color:0 (
color 0
cls
goto play
) else if %id% == color:a (
color a
cls
goto play
) else if %id% == color:b (
color b
cls
goto play
) else if %id% == color:c (
color c
cls
goto play
) else if %id% == color:d (
color d
cls
goto play
) else if %id% == color:e (
color e
cls
goto play
) else if %id% == color:f (
color f
cls
goto play
) else (
cls
echo Identification stored.
pause
cls
set /p conf=Enter identification:
if %conf% == %id% (
cls
echo Access granted.
pause
exit
) else if %conf% == #cheat.code:(acss_grnt.admn)$ (
color c
cls
echo Cheating system..
timeout 3 >nul
tree
dir
timeout 1 >nul
cls
echo Access granted.
pause
exit
else (
cls
echo Access denied.
pause
exit
)

Answer 1

You should be aware from COLOR /? "Color attributes are specified by TWO hex digits"; you are just using one. You have not added any code to determine what the current foreground colour is. "The COLOR command sets ERRORLEVEL to 1 if an attempt is made to execute the COLOR command with a foreground and background color that are the same". Don't assume the foreground color attribute, if you're assuming it is currently 8 then add 8 after the background attribute in your COLOR commands.
You do not need to use all those ELSE IF combinations:
#ECHO OFF
:PLAY
SET/P "ID=Identification code: "
IF /I "%ID%"=="color:0" (
COLOR 08
GOTO PLAY
)
IF /I "%ID%"=="color:a" (
COLOR A8
GOTO PLAY
)
IF /I "%ID%"=="color:b" (
COLOR B8
GOTO PLAY
)
IF /I "%ID%"=="color:c" (
COLOR C8
GOTO PLAY
)
IF /I "%ID%"=="color:d" (
COLOR D8
GOTO PLAY
)
IF /I "%ID%"=="color:e" (
COLOR E8
GOTO PLAY
)
IF /I "%ID%"=="color:f" (
COLOR F8
GOTO PLAY
)
I have removed all of those CLS commands, just begin :PLAY with CLS instead.

Answer 2

You are missing a closing parenthesis for this block :
else if %conf% == #cheat.code:(acss_grnt.admn)$ (
color c
cls
echo Cheating system..
timeout 3 >nul
tree
dir
timeout 1 >nul
cls
echo Access granted.
pause
exit
You are also missing a closing parenthesis for this else block :
else (
cls
echo Identification stored.
pause
cls
set /p conf=Enter identification:

Answer 3

You should try to keep the structure simple computers/programs are there to avoid tiresome repetitions so the color thing is put in one logical line with a line continuation char ^ at the end and using conditional execution on success && or fail || of the result of the findstring.
I don't know if I could always follow your logic, so try it out.
#echo off
Set "Wait=timeout /T 3 /nobreak>NUL"
:play
cls
set "id="
set /p id=Identification code:
If "%id%"=="" Echo no input&timeout 3>NUL&goto play
IF /i "%id:~0,6%"=="color:" Echo:%id%|findstr /I "^color:[0a-f]$" >NUL 2>&1 ^
&&(color %id:~-1%&Goto play)||(Echo wrong color&%Wait%&goto play)
cls
echo Identification stored.
%Wait%
cls
set "conf="
set /p conf=Enter identification:
if "%conf%"=="%id%" (
cls
echo Access granted.
%Wait%
exit
) else if /i "%conf%"=="#cheat.code:(acss_grnt.admn)$" (
color c&cls&echo Cheating system..
%Wait%
tree&dir
timeout 1 >nul
cls&echo Access granted.
%Wait%
exit
)
cls&echo Access denied.
%Wait%
exit