Combining scores from multiple Neo4j queries - database

Question

We have a movie graph. There are actors, directors, and movies. It's possible that a director has also played in another movie, or even the same movie. We give an actor a score for each movie he plays in. We also give a director a score for each of his movies. Now, we are looking to get a list of individuals and their scores, sorted from highest to lowest score. So these are the queries we currently have:
MATCH (p:Person)-[idr:IsDirectorOf]->(m:Movie)
RETURN p.name AS name, COUNT(idr) AS numberOfMoviesDirected
ORDER BY numberOfMoviesDirected DESC;
and
MATCH (p:Person)-[iai:IsActorIn]->(m:Movie)
RETURN p.name AS name, COUNT(iai) AS numberOfMoviesPlayed
ORDER BY numberOfMoviesPlayed DESC;
I want to combine these queries, to get the person who has the highest score from both queries together at the top. Also, please note that we may later need to add another query to the mix, so solutions that work for only two queries may not be the best.

Answer 1

You should try this query :
MATCH (p:Person)
RETURN p, size((p:Person)-[:IsDirectorOf]->(:Movie)) + size((p:Person)-[:IsActorIn]->(:Movie)) AS score
ORDER BY score DESC
And if you want to add additional score, just continue your query with a WITH.
Cheers
UPDATE
To respond to your comment, this is the query :
MATCH (p:Person)
WITH
max(size((p)-[:IsActorIn]->())) As maxActed,
max(size((p)-[:IsDirectorOf]->())) AS maxDirected
MATCH (p:Person)
RETURN
p,
size((p)-[:IsActorIn]->(:Movie)) / toFloat(maxActed) + size((p)-[:IsDirectorOf]->(:Movie)) / toFloat(maxDirected) AS score
ORDER BY score DESC