Cut the text in braces from txt in batch - batch-file

Question

I have a lot of .txt files which has information like this:
randomtext[IMPORTANTTEXT]morerandomtext
How can I cut out the important text without the braces and maybe overwrite the original .txt in batch?

Answer 1

The following will also do multiple instances in the same line. I'll leave it to you to change it to use a path for the *.txt files.
Test data:
Test1.txt
randomtext[IMPORTANTTEXT1a]morerandomtext
randomtext[IMPORTANTTEXT1b]morerandomtext
Test2.txt
randomtext[IMPORTANTTEXT2]morerandomtext
randomtext[IMPORTANTTEXT2a]morerandomtext randomtext[IMPORTANTTEXT2b]morerandomtext
Batch file:
#echo off
SETLOCAL ENABLEDELAYEDEXPANSION
rem For each text file in the current directory...
for /f "tokens=*" %%F in ('dir /b *.txt') do (
set FileSpec=%%F
rem For each line of text in the file that has at least one [
for /f "tokens=1,* delims=[" %%a in (!FileSpec!) do (
rem This line of text has a [ so get the important text. %%a[%%b
rem below passes the entire line of text.
call :FindImportantText %%a[%%b
)
)
ENDLOCAL
pause
exit /b
:FindImportantText
for /f "tokens=1,* delims=[" %%c in ("%*") do (
rem The "%*" above is the entire line of text even if it contains
rem spaces which would normally delimit the line into pieces
if not "%%d"=="" (
rem There is a [ and text following the [. %%d is the portion
rem following the [.
rem so find the ending ]
for /f "tokens=1,* delims=]" %%e in ("%%d") do (
if not "%%f"=="" (
rem We have an ending ] so show it
echo ImportantText in !FileSpec!=%%e
rem Try again with the remaining portion of the line
call :FindImportantText %%f
)
)
)
)
exit /b

Answer 2

This will filter out the parts between the first pair of brackets:
for /f "tokens=2 delims=[]" %%a in ('type %1') do echo.%%a>>%2
If there are lines without any "important parts", you can skip them with findstr or by checking whether the output is empty:
for /f "tokens=2 delims=[]" %%a in ('type %1') do if "%%a" neq "" echo.%%a>>%2
To process all .txt files in the current directory, call the loop with another loop:
#echo off
for %%a in (*.txt) do call :brekkies "%%a" "%%~na_out.txt"&echo.%%a
echo.done.
exit /b
:brekkies
for /f "tokens=2 delims=[]" %%a in ('type %1') do if "%%a" neq "" echo.%%a>>%2
Files are going to be named "[name]_out.txt".