How to use Vector with offset from parent Haxe class instance? - arrays

Question

What methods are available to achieve accessing parent instance Vector cell from another class?
My question is about the lines commented with "??":
class Test {
static function main() {
var a:A = new A();
var b:B = new B(a, 115);
}
}
class A {
public var cells:haxe.ds.Vector<Float>;
public function new() {
cells = new haxe.ds.Vector(1000);
}
}
class B {
public var a:A; // the "parent"
public var my_offset:Int;
public var my_cells:haxe.ds.Vector<Float>; //??
public function new(a:A, offset:Int) {
my_offset = offset;
my_cells[2] = 0.5; //?? actually a.cells[my_offset + 2];
}
}
Is it possible to:
access parent Vector memory directly?
use a macro?
use an abstract?
"Try Haxe" link

Answer 1

You could create an abstract type that wraps a Vector, automatically adding the desired offset by defining #:arrayAccess() methods:
class Main {
static function main() {
var cells = new haxe.ds.Vector(1000);
cells[115] = 1.5;
var cellsWithOffset = new VectorWithOffset(cells, 115);
trace(cellsWithOffset[0]); // 1.5
}
}
abstract VectorWithOffset<T>(VectorWithOffsetData<T>) {
public function new(vector:haxe.ds.Vector<T>, offset:Int) {
this = {vector: vector, offset: offset};
}
#:arrayAccess inline function get(i:Int):T {
return this.vector[i + this.offset];
}
#:arrayAccess inline function set(i:Int, v:T):T {
return this.vector[i + this.offset] = v;
}
}
typedef VectorWithOffsetData<T> = {
var vector:haxe.ds.Vector<T>;
var offset:Int;
}
Note: the abstract doesn't need to necessarily wrap a structure, it could also be a class. You can't wrap Vector directly though, as the offset needs to be stored somewhere, and abstracts can't have member variables of their own.