How to calculate length of an environment variable - batch-file

Question

This may have been solved, but I looked and couldn't find a satisfactory answer. How does one quickly calculate the length of an environment variable in a .bat script?
My problem involves environment variables of a couple thousand characters (I understand the practical limit is around 8k... the max size of a command line).
The straightforward approach simply counts characters. I'll use %path% below as an example. Assume the environment variable is known to exist -- which it does in my case -- so its length is at least 1. No special characters (eg double-quote) are involved:
#echo off& setlocal enabledelayedexpansion
set /a length=1
:loop
if not "!path:~%length%,1!"=="" set /a length+=1& goto loop
This calculates and leaves the value in environment variable 'length'.
I have seen such solutions, but they are extremely slow for longer length variables. A better approach (a couple order of magnitudes faster, and deterministic) is a binary search, such as:
#echo off& setlocal enabledelayedexpansion
set /a p2=16384, length=p2-1
:loop
if "!path:~%length%,1!"=="" set /a length-=p2
if !p2! geq 2 (set /a length+=p2/=2& goto loop) else set /a length+=1
I suppose I can live with that, but still I wonder if I'm being stupid and missing something obvious. I am looking for a pure .bat solution.
below added 6/12/2017
Learning from this method suggested by Compo led me to solution simpler/faster then dostips' (18% faster over all strings length 1 .. 8k). That seemed significant enough to post:
#echo off& setlocal enabledelayedexpansion
set "str=A%path%"
set length=0
for %%p in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
if not "!str:~%%p,1!"=="" set "str=!str:~%%p!"& set /a length+=%%p
)

Answer 1

PURE BATCH
#echo off
del temp.txt
for /F "delims=:" %%G in ('findstr /N "<resource>" "%~F0"') do set "start=%%G"
(for /F "usebackq skip=%start% delims=" %%G in ("%~F0") do echo %%G) > temp.txt
rem echo everything after "<resource>" - code by #Aacini
for %%G in (temp.txt) do set /a size=%%~zG - 2
rem get the file length and remove the CR\LF count
echo %size%
pause
exit/b
<resource>
things to test length
and can be mutli-line
This script echoes the string to file, and use a for loop to retrieve the file size, which is the string length. To maximize speed, code-golf it.
Some facts:
It took around .54 seconds to process a 1.04 mb long string.
Getting the length of a 1.04 MB string is more efficient than getting a string with 1-byte length.
OLD POWERSHELL
You can bypass the 8191 bytes limit by calling Powershell.
echo $characters = "yourString" > temp.ps1
echo $x= $characters.length >> temp.ps1
echo write-host $x >> temp.ps1
powershell -command "C:\PathToPS1file\temp.ps1
del /f /s /q temp.ps1
This is a slow powershell method, and requires lots of escaping.