Array Comparision - arrays

Question

I have a array with 8 columns and 42 rows B2 TO I43. I have to compare this array with other arrays in the same sheet so that every array have same values. I defined array1 Rang('B2;I43") and need to compare every other array of same size. how to that in VBA.
My code is
Sub driver()
Dim array1, array2, m, n
Set array1 = Range("B2,I43")
total_rows = 42
total_cols = 8
Set array2 = Range("B44:I85")
For i = 1 To total_rows
For j = 1 To total_cols
If array1(i, j) = array2(i, j) Then
array2.Cells(i, j).Interior.ColorIndex = 0
ElseIf array1(i, j) <> array2(i, j) Then
array2.Cells(i, j).Interior.ColorIndex = 3
End If
Next j
Next i
End Sub
I want array2 to point to other set of values. Every array start after 42 rows.

Answer 1

Have you tried to use Conditional formatting instead? Your suggested VBA code can easily be solved with conditional formatting by comparing each cell in array2 with the same cell in array1 and use colours to mark if the cells are equal or not
Edit
I have modified your code. Instead of using two ranges I have used an "row offset" for each array you have on your sheet. It then compares the cells from your source array (array1 in your code) with the cells that are found next_array_offset rows down. When the comparison has been made, the offset is increased with 42. The loop ends when there are no more values to be found.
Is this what you was looking for?
Sub driver()
Dim r As Integer
Dim c As Integer
Dim source_row As Integer
Dim source_col As Integer
Dim total_rows As Integer
Dim total_cols As Integer
Dim next_array_offset As Integer
source_row = 2 ' row B
source_col = 2 ' col 2
total_rows = 42
total_cols = 8
next_array_offset = 42 ' distance in rows to next array
Do Until IsEmpty(Cells(source_row + next_array_offset, source_col).Value)
For r = 0 To total_rows - 1
For c = 0 To total_cols - 1
If Cells(source_row + r, source_col + c) = Cells(source_row + next_array_offset + r, source_col + c) Then
Cells(source_row + next_array_offset + r, source_col + c).Interior.ColorIndex = 0
Else
Cells(source_row + next_array_offset + r, source_col + c).Interior.ColorIndex = 3
End If
Next
Next
next_array_offset = next_array_offset + 42
Loop
End Sub

Answer 2

Your main task is to define the ranges accurately. In the code below I've assumed it's every 42 rows until end of data. You simply iterate your 42-row test arrays and compare against the reference array. To do this you basically need two row variables: one for your test array and one for your reference array.
The quickest way would be to read the test data just once into one big array and to create two ranges (one with matches and one with mis-matches) and then colour them at the end of the routine.
I don't know your colour palette (and therefore the color indexes) so I've used the .Color property. You can adjust this to suit.
Const ROW_COUNT As Long = 42
Const COL_COUNT As Long = 8
Const START_ROW As Long = 2
Dim refArray As Variant, testArray As Variant
Dim rowSize As Long, r As Long, c As Long, i As Long
Dim cell As Range, yesRng As Range, noRng As Range
'Read data into arrays
With Sheet1
'Find last row of data
rowSize = .Cells(.Rows.Count, "B").End(xlUp).Row
'Adjust last row to be multiple of 42
rowSize = Int((rowSize - START_ROW) / ROW_COUNT) * ROW_COUNT
refArray = .Cells(START_ROW, "B").Resize(ROW_COUNT, COL_COUNT).Value2
testArray = .Cells(START_ROW + ROW_COUNT, "B").Resize(rowSize, COL_COUNT).Value2
End With
'Compare test array with reference array
i = 1 'refArray row index
For r = 1 To UBound(testArray, 1)
For c = 1 To UBound(testArray, 2)
Set cell = Sheet1.Cells(r + START_ROW + ROW_COUNT - 1, c + 1)
If testArray(r, c) = refArray(i, c) Then
'It's a match so add to yes range
If yesRng Is Nothing Then
Set yesRng = cell
Else
Set yesRng = Union(yesRng, cell)
End If
Else
'It's a miss so add to no range
If noRng Is Nothing Then
Set noRng = cell
Else
Set noRng = Union(noRng, cell)
End If
End If
Next
'Increment ref row index or set back to 1 if at 42
i = IIf(i < ROW_COUNT, i + 1, 1)
Next
'Colour the ranges
If Not yesRng Is Nothing Then yesRng.Interior.Color = vbGreen
If Not noRng Is Nothing Then noRng.Interior.Color = vbRed