Batch - Ghost File Passing 'If Not Exist' Check - batch-file

Question

My Code
I have some straight forward code below that:
Checks if a file exists in my directory
Runs a for loop to get the first filename
Does stuff based on filename
Deletes the file
Checks if any other files exist in directory (if yes, repeat, if not, move on)
:MYLOOP
IF NOT EXIST "%mypath%\*.*" GOTO nofile
FOR %%F IN ("%mypath%\*.*") DO (
set filenameWithExt=%%~nxF
set filename=%%~nF
set filepath=%%~pF
)
do other filename specific tasks
del "%mypath%\%filenameWithExt%"
IF NOT EXIST "%mypath%\*.*" GOTO nofile
GOTO MYLOOP
:nofile
My Issue
I've used this code repeatedly and its worked like a charm, but on my most recent use it looks like its finding a 'ghost' file. When there are no FILES (there is a single archive FOLDER) in the directory, the if not exist check from step 1 above somehow is still passing. As a result, the set code in the for loop results in:
The system cannot find the file specified.
And it then appears as though it tries to delete my directory, saying:
\\mypath*, Are you sure (Y/N)?
I then have to manually terminate an otherwise automated batch.
My Question
Why is it passing the if not exist check, rather than skipping to :nofile?
How can I account for this 'ghost' file (or if it is detecting the archive folder -- how else can I ignore it)?

Answer 1

Windows kernel and therefore also Windows command interpreter interprets the wildcard pattern *.* like * which means any file or folder. On using wildcard pattern *.* it does not mean there must be a file (or folder) with a dot in name.
For that reason using the condition IF NOT EXIST "%mypath%\*.*" is the same as using IF NOT EXIST "%mypath%\*".
IF EXIST "%mypath%\*" is often used in batch files to verify that %mypath% specifies a folder and not a file because this condition checks if there is a folder %mypath%. The condition is true if that folder exists, independent on number of files and folders in that folder.
So the condition at top of your batch file does not check if there is not at least 1 file in folder %mypath%, it checks if this folder does not exist at all.
You could use the following batch code which avoids the usage of delayed expansion by using a subroutine.
#echo off
for /F "delims=" %%I in ('dir /A-D /B /ON "%mypath%\*" 2^>nul') do call :ProcessFile "%mypath%\%%I"
goto :EOF
:ProcessFile
set "FilenNmeWithExt=%~nx1"
set "FileName=%~n1"
set "FilePath=%~p1"
rem do other filename specific tasks
del "%~1"
goto :EOF
The command FOR executes the command line
dir /A-D /B /ON "%mypath%\*" 2>nul
in a separate command process in background and captures the output of DIR written to handle STDOUT.
DIR would output an error message to handle STDERR if the directory does not exist at all or does not contain any file. This error message is suppressed by redirecting it to device NUL using 2>nul. The redirection operator > must be escaped here with caret character ^ to be interpreted first by Windows command interpreter as literal character on parsing the entire FOR command line as otherwise a syntax error would be the result.
Option /A-D means that DIR should output all directory entries NOT having directory attribute set, i.e. just files, not folders. /B changes output of DIR to bare format which means only the file names without any additional data. /ON results in ordering the list by file name before DIR outputs the entire list. This option would not be really necessary here.
FOR processes now the captured output of DIR. So it does not matter that files from that directory are deleted while FOR is running. FOR processes the initial list as output by DIR.
For each file name output by DIR the subroutine ProcessFile is executed which is like calling another batch file with that name. Passed to the subroutine is the file name with its path. DIR outputs just the file name without path on not using additionally /S to get a list of all file names in specified directory and all its subdirectories.
The command goto :EOF after the FOR loop is required to avoid a fall through to the subroutine once all file names output by DIR have been processed.
The command goto :EOF after the subroutine would not be required if the line above is the last line of the batch file. But it is in general good practice to end a subroutine always with goto :EOF in case of ever adding more command lines like another subroutine below. For Windows command interpreter it does not matter where the subroutine starting with its label is located in the file.

Answer 2

The if exist test looks for anything in the directory.
I'd restructure you code:
:MYLOOP
set "found1="
FOR %%F IN ("%mypath%\*.*") DO (
set filenameWithExt=%%~nxF
set filename=%%~nF
set filepath=%%~pF
set "found1=Y"
)
if not defined found1 goto nofile
do other filename specific tasks
del "%mypath%\%filenameWithExt%"
GOTO MYLOOP
:nofile
If the for finds no files, found1 will remain undefined so we go to the :nofile label, else we have a file to process. Having deleted the file, just go back to the beginning, clear the flag and repeat...