Batch file to copy files with unique timestamps measured to the minute - batch-file

Question

Like the question says, I have a folder full of photos but many of the photos are duplicates. The pictures are in groups of 10-15 in the same minute and then the next group has a timestamp of a few minutes later. I want to copy 1 photo from each group to a new folder. I found some code that I think might mostly work, but the command copies and excludes based on file name, not timestamp. Any help would be greatly appreciated.
For %%F In ("G:\Bad\*.*") Do If Not Exist "G:\Good\%%~nxF" Copy "%%F" "C:\Good\%%~nxF"

Answer 1

This file copying task could be done with following batch file:
#echo off
setlocal EnableExtensions EnableDelayedExpansion
set "LastFileTime="
for %%I in ("C:\Path To\Source Folder\*") do (
if "%%~tI" NEQ "!LastFileTime!" (
set "LastFileTime=%%~tI"
copy /B /Y "%%I" "C:\Path To\Destination Folder\" >nul
)
)
endlocal
Command FOR runs for each non hidden file in specified source folder the IF comparison which compares case-sensitive last modification time of current file with the file time last assigned to environment variable LastFileTime using delayed expansion as required here because the environment variable value is changed and referenced in same command block.
On a difference the last modification file time of current file is assigned to the environment variable and the file is copied to destination folder which must already exist on running this batch file.
Note: On an NTFS drive the list of file names processed by FOR is sorted by file name and not by file time. On a FAT16, FAT32 and ExFAT drive the list of file names is not sorted at all. This means this simple approach works only reliable on an NTFS drive with all files with same last modification date have nearly the same file name.
So it would be better to process the list of files sorted by last modification time for example using following code:
#echo off
setlocal EnableExtensions EnableDelayedExpansion
set "LastFileTime="
cd /D "C:\Path To\Source Folder"
for /F %%I in ('dir * /A-D /B /OD /TW 2^>nul') do (
if "%%~tI" NEQ "!LastFileTime!" (
set "LastFileTime=%%~tI"
copy /B /Y "%%I" "C:\Path To\Destination Folder\"
)
)
endlocal
DIR outputs all directory entries
matching the wildcard pattern * (*.* is interpreted as * by Windows),
not having attribute directory set because of /A-D which means only the names of files including hidden and system files,
in bare format because of /B which means just file name without any additional information,
with the output list ordered by date/time because of /OD with oldest first and newest last
whereby the date/time to use for sort is the last modification (write) date because of /TW which would not be necessary as the last modification date is the default.
The help output by running dir /? in a command prompt window explains also all these options. And running just dir * and next dir * /A-D /B /OD /TW in a command prompt window in a directory with files and comparing the two output lists makes the difference very clear.
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
cd /?
copy /?
dir /?
echo /?
endlocal /?
for /?
if /?
set /?
setlocal /?
Read also the Microsoft article about Using Command Redirection Operators to understand >nul used here to suppress the message about number of copied files by redirecting it to device NUL.
2>nul suppresses the error message output by DIR if there is no file in source directory by redirecting the error message output to handle STDERR to device NUL whereby the redirection operator > needs to be escaped here with caret character ^ for being parsed as literal character on parsing the FOR command line by Windows command interpreter and as redirection operator later on execution of DIR command line in a separate command process.