Script works in CMD but not in batch - batch-file

Question

I have this script below to track process time of each part of my script. When I run this in a CMD prompt, it works perfectly, but when put into a .bat, it fails to run. This is also constructed in two IF statements.
Also shout out to #driblio who I got this from.
#echo off
set starttime=%TIME%
set startcsec=%STARTTIME:~9,2%
set startsecs=%STARTTIME:~6,2%
set startmins=%STARTTIME:~3,2%
set starthour=%STARTTIME:~0,2%
set /a starttime=(%starthour%*60*60*100)+(%startmins%*60*100)+(%startsecs%*100)+(%startcsec%)
::Process
set endtime=%time%
set endcsec=%endTIME:~9,2%
set endsecs=%endTIME:~6,2%
set endmins=%endTIME:~3,2%
set endhour=%endTIME:~0,2%
if %endhour% LSS %starthour% set /a endhour+=24
set /a endtime=(%endhour%*60*60*100)+(%endmins%*60*100)+(%endsecs%*100)+(%endcsec%)
set /a timetaken= ( %endtime% - %starttime% )
set /a timetakens= %timetaken% / 100
set timetaken=%timetakens%.%timetaken:~-2%
echo.
echo Took: %timetaken% sec.

Answer 1

Read entire set /?
Numeric values are decimal numbers, unless prefixed by 0x for
hexadecimal numbers, and 0 for octal numbers. So 0x12 is the same
as 18 is the same as 022. Please note that the octal notation can
be confusing: 08 and 09 are not valid numbers because 8 and
9 are not valid octal digits.
So echo "%startttime%" could return something like
" 9:08:09.04"
↑↑ invalid in set /a 08
↑↑ invalid in set /a 09
↑↑ valid in set /a 04
Use
#ECHO OFF
SETLOCAL EnableExtensions DisableDelayedExpansion
set starttime=%TIME%
rem debugging output echo "%starttime%"
set /A startcsec=1%STARTTIME:~9,2% %% 100
set /A startsecs=1%STARTTIME:~6,2% %% 100
set /A startmins=1%STARTTIME:~3,2% %% 100
set starthour=%STARTTIME:~0,2%
set /a starttime=(%starthour%*60*60*100)+(%startmins%*60*100)+(%startsecs%*100)+(%startcsec%)
rem debugging output set start
::Process
:: pause to ensure that endtime >> starttime
pause
set endtime=%time%
rem debugging output echo "%endtime%"
set /A endcsec=1%endTIME:~9,2% %% 100
set /A endsecs=1%endTIME:~6,2% %% 100
set /A endmins=1%endTIME:~3,2% %% 100
set endhour=%endTIME:~0,2%
if %endhour% LSS %starthour% set /a endhour+=24
set /a endtime=(%endhour%*60*60*100)+(%endmins%*60*100)+(%endsecs%*100)+(%endcsec%)
rem debugging output set end
set /a timetaken= ( %endtime% - %starttime% )
set /a timetakens= %timetaken% / 100
set timetaken=%timetakens%.%timetaken:~-2%
echo.
echo Took: %timetaken% sec.
Please note that above code snippet still depends on locale and user preferences. For locale and user preference independent solution, use output from wmic os get localdatetime rather than %time% as follows:
for /F %%G in ('wmic OS get localdatetime /Value ^| find "="') do #set %%G
Then, %localdatetime% would contain something like 20170413030820.447000+120 in (fixed-length) CIM_DATETIME format yyyymmddHHMMSS.mmmmmmsUUU where the fields in the format are
yyyy Four-digit year (0000 through 9999). Your implementation can restrict the supported range. For example, an implementation can
support only the years 1980 through 2099.
mm Two-digit month (01 through 12).
dd Two-digit day of the month (01 through 31). This value must be appropriate for the month. For example, February 31 is not valid.
However, your implementation does not have to check for valid data.
HH Two-digit hour of the day using the 24-hour clock (00 through 23).
MM Two-digit minute in the hour (00 through 59).
SS Two-digit number of seconds in the minute (00 through 59).
mmmmmm Six-digit number of microseconds in the second (000000 through 999999). Your implementation does not have to support
evaluation using this field. However, this field must always be
present to preserve the fixed-length nature of the string.
s Plus sign (+) or minus sign (-) to indicate a positive or negative offset from Coordinated Universal Times (UTC).
UUU Three-digit offset indicating the number of minutes that the originating time zone deviates from UTC. For WMI, it is encouraged,
but not required, to convert times to GMT (a UTC offset of zero).