How to read and parse a line from file? - file

Question

There is a file consisted of lines in the following format:
John, D E 100
Bob, F I 200
Oli, G H 1500
...
in general:
string, char char integer
The file needs to be read and stored in two arrays of which the first should store the string and characters1 and the second should store the integer.
How could this be done?
An initial attempt is made here.
1. Concatenated into single string as they are with the comma and the white spaces.

Answer 1

If the items in the input file are delimited by whitespaces or commas, we can read them using list-directed input (fmt=*), as suggested in the comments in the linked question, such that
read (funit, [fmt =] *, iostat = ios) surname, first_name, second_name, consumption
where the part "fmt =" is optional. The following is a slightly modified version of the original code in the linked page (please see comments in the code for more details):
module MyModule
implicit none !<-- this propagates to all routines in this module
contains
subroutine ReadFileIntoArrays (filename, name_arr, kWh_arr, ndata)
character(*), intent(in) :: filename !<-- an assumed-length string
character(*), intent(out) :: name_arr(:) !<-- an array of assumed-length strings
integer, intent(out) :: kWh_arr(:), ndata
character :: first_name, second_name !<-- a single char
character(50) :: surname !<-- a string of 50 chars
integer :: consumption, funit, ios, idx
funit = 10 ! use >= 10 (or open( newunit=funit, ... ) for recent compilers)
open (funit, file = filename, status = 'old')
idx = 0
do
read (funit, fmt = *, iostat = ios) & !<-- "&" means line continuation
surname, first_name, second_name, consumption
! "fmt = *" (list-directed input) tells the compiler
! to use whitespaces/commas as delimiters.
if (ios > 0) then
print *, "Wrong input format!" ; exit
else if (ios < 0) then
print *, "finished reading data." ; exit
else
idx = idx + 1
if (idx > size( name_arr )) stop "size of name_arr(:) too small"
! trim() chops trailing spaces in a string
name_arr( idx ) = trim(surname)//','//first_name//'.'//second_name//'.'
kWh_arr( idx ) = consumption
end if
end do
ndata = idx
close (funit)
end subroutine
end module
program MyMain
use MyModule
implicit none
integer :: consumption( 10 ), ndata, idx
character(50) :: names( 10 ) !<-- an array of size 10 (each element = 50-char string)
character(200) :: filename !<-- a string of 200 chars
filename = "clients.txt"
names = ""
consumption = 0
call ReadFileIntoArrays (filename, names, consumption, ndata)
print "(2a20)", "name", "consumption"
do idx = 1, ndata
print "(a20,i20)", trim( names( idx ) ), consumption( idx )
enddo
end program
Then, with the input in the question, the output becomes
finished reading data.
name consumption
John,D.E. 100
Bob,F.I. 200
Oli,G.H. 1500