IF variable LSS variable fails when variable is blank - batch-file

Question

I have the following batch file that will check and compare two variables, however, it fails when one of the variables are blank.. any ideas how to handle a case where LocalVersion can be blank aka the file version.txt does not exist.
test.bat:
for /f "tokens=1 " %%a in ('%Tools%\cat.exe version.txt') do set LocalVersion=%%a
for /f "tokens=1 " %%a in ('%Tools%\cat.exe \\UNC_Share\version.txt') do set RemoteVersion=%%a
echo LocalVersion %LocalVersion%
echo RemoteVersion %RemoteVersion%
if %LocalVersion% LSS %RemoteVersion% ( goto :skip )
if %LocalVersion% GTR %RemoteVersion% ( goto :Update)
Results:
c:\test.bat
LocalVersion
RemoteVersion 4.0.1
4.0.1 was unexpected at this time.

Answer 1

For comparisons of versions it is strongly recommended not running a literal comparison if the version numbers contain points. It is better to convert the version numbers with points into integers and compare the integers.
Example 1 using multiplications and additions:
#echo off
setlocal EnableExtensions
set "LocalVersion=0.0.0"
set "LocalVersNum=0"
set "RemoteVersion=0.0.0"
set "RemoteVersNum=0"
if exist "version.txt" (
for /F "usebackq tokens=1-3 delims=." %%A in ("version.txt") do (
set "LocalVersion=%%A.%%B.%%C"
set /A LocalVersNum=%%A * 1000000 + %%B * 1000 + %%C
)
)
if exist "\\Sever\Share\version.txt" (
for /F "usebackq tokens=1-3 delims=." %%A in ("\\Sever\Share\version.txt") do (
set "RemoteVersion=%%A.%%B.%%C"
set /A RemoteVersNum=%%A * 1000000 + %%B * 1000 + %%C
)
)
if %LocalVersNum% LSS %RemoteVersNum% goto Skip
if %LocalVersNum% GTR %RemoteVersNum% goto Update
echo %LocalVersion% is equal %RemoteVersion%.
goto EndBatch
:Skip
echo %LocalVersion% is lower %RemoteVersion%.
goto EndBatch
:Update
echo %LocalVersion% is greater %RemoteVersion%.
:EndBatch
endlocal
Example 2 using bit operations:
#echo off
setlocal EnableExtensions
set "LocalVersion=0.0.0"
set "LocalVersNum=0"
set "RemoteVersion=0.0.0"
set "RemoteVersNum=0"
if exist "version.txt" (
for /F "usebackq tokens=1-3 delims=." %%A in ("version.txt") do (
set "LocalVersion=%%A.%%B.%%C"
set /A "LocalVersNum=(%%A << 24) | (%%B << 16) | %%C"
)
)
if exist "\\Sever\Share\version.txt" (
for /F "usebackq tokens=1-3 delims=." %%A in ("\\Sever\Share\version.txt") do (
set "RemoteVersion=%%A.%%B.%%C"
set /A "RemoteVersNum=(%%A << 24) | (%%B << 16) | %%C"
)
)
if %LocalVersNum% LSS %RemoteVersNum% goto Skip
if %LocalVersNum% GTR %RemoteVersNum% goto Update
echo %LocalVersion% is equal %RemoteVersion%.
goto EndBatch
:Skip
echo %LocalVersion% is lower %RemoteVersion%.
goto EndBatch
:Update
echo %LocalVersion% is greater %RemoteVersion%.
:EndBatch
endlocal
Both examples produce the right result for LocalVersion being for example 4.0.10 and RemoteVersion being 4.0.9 on which a literal comparison like if %LocalVersion% LSS %RemoteVersion% goto Skip produces the wrong result.
The command line
if "%LocalVersion%" LSS "%RemoteVersion%" goto Skip
results always in a literal comparison because the double quotes are not ignored on comparing the strings. So with using double quotes the referenced values are not compared anymore after an implicit conversion from string to integer on both values using an integer comparison, but doing a string comparison.
The solution for avoiding an exit of batch execution because of a syntax error if one of the two version.txt files does not exist is an initialization of the used environment variables.
The additional if exist condition before each FOR is for avoiding an error message on execution of command FOR and the appropriate version.txt file does not exist.
FOR reads the version.txt file directly without the tool cat which is ported from Unix to Windows and therefore not available by default on Windows. The native Windows command for cat is type which is most likely not really needed here.