Base64 decoding of a String batch file - batch-file

Question

I want to decode a base64 encoded text and use it to login to a website. The base64 encoded text is the username and password. I hav found tools like Base64.exe and b64.exe but they take input as a file whereas in my case input is a string. plz help me out. All this shud be done in a batch file only and also am reading the encoded text from a config.txt file.

Answer 1

You can use the CERTUTIL command without installing external software (though it will need temp files):
#echo off
del /q /f "%temp%\b64" >nul 2>nul
del /q /f "%temp%\decoded" >nul 2>nul
set "base64string=YmFzZTY0c3RyaW5n"
echo -----BEGIN CERTIFICATE----->"%temp%\b64"
<nul set /p=%base64string% >>"%temp%\b64"
echo -----END CERTIFICATE----->>"%temp%\b64"
certutil /decode "%temp%\b64" "%temp%\decoded" >nul 2>nul
for /f "useback tokens=* delims=" %%# in ("%temp%\decoded") do set "decoded=%%#"
echo %decoded%
del /q /f "%temp%\b64" >nul 2>nul
del /q /f "%temp%\decoded" >nul 2>nul
You can also use powershell which will be slower despite there will be no temp files:
set "base64string=YmFzZTY0c3RyaW5n"
for /f "tokens=* delims=" %%# in ('powershell [System.Text.Encoding]::UTF8.GetString([System.Convert]::FromBase64String("""%base64string%"""^)^)') do set "decoded=%%#"
echo %decoded%
You can try also with atob.bat :
call atob.bat YmFzZTY0c3RyaW5n decoded
echo %decoded%
Or with base64.bat
for /f "tokens=* delims=" %%# in ('base64.bat -decode YmFzZTY0c3RyaW5n') do set "decoded=%%#"
echo %decoded%

Answer 2

I found the solution. I am extracting the base64 encoded text from "config.txt" to a new file say "tmp.txt". now I run the cmd "b64.exe -d tmp.txt tmp2.txt".I get the decoded text in the new "tmp2.txt" file. I delete the "tmp.txt" and "tmp2.txt" once i read the username and password.
Thank you

Answer 3

You can use the macro style invented by #jeb, #dbenham and #Ed Dyreen:
#echo off
====SETLOCAL DisableDelayedExpansion EnableExtensions
set ^"LF=^
%===EXPANDS TO NOTHING===%
"
REM \n is an escaped LF + caret
set ^"\n=^^^%LF%%LF%^%LF%%LF%^^"
REM Initalize macro
set ^"$b64d=FOR %%$ in (%%$ MainMacro) do if "%%$" == "MainMacro" (%\n%
^>nul %__APPDIR__%CERTUTIL.EXE -f -decodehex args.tmp proc.tmp 1%\n%
type proc.tmp%\n%
del args.tmp proc.tmp%\n%
) ELSE ^>args.tmp echo("
echo BEFORE :: %time%
%$b64d%dGhpcwppcwpzaWNrIQo=
echo AFTER :: %time%
Output:
BEFORE :: 21:13:31.94
this
is
sick!
AFTER :: 21:13:32.02