Parse output of Printing Admin Scripts - batch-file

Question

For some reason or another when I run the code below it truncates the very end of the string I am echoing at the end. Is there a way to prevent that?
#echo off
chdir C:\Windows\System32\Printing_Admin_Scripts\en-US
For /f "skip=1 delims=" %%a in ('wmic computersystem get name') do for /f "delims=" %%b in ("%%a") do set "compName=%%a"
Set comp=%compName:~0,5%
Set pName=%comp%P1
For /f "delims=" %%a in ('cscript prnmngr.vbs -l ^|findstr /i /b /n /c:"printer name" ^|findstr /b "6:"') do set printerName0=%%a
For /f "delims=" %%a in ('cscript prnmngr.vbs -l ^|findstr /i /b /n /c:"printer name" ^|findstr /b "25:"') do set printerName1=%%a
For /f "delims=" %%a in ('cscript prnmngr.vbs -l ^|findstr /i /b /n /c:"printer name" ^|findstr /b "44:"') do set printerName2=%%a
If "%printerName0%" == "6:Printer name %pName%" (
For /f "delims=" %%a in ('cscript prnmngr.vbs -l ^|findstr /i /b /n /c:"driver name" ^|findstr /b "8:"') do set driverName=%%a
)
If "%printerName1%" == "25:Printer name %pName%" (
For /f "delims=" %%a in ('cscript prnmngr.vbs -l ^|findstr /i /b /n /c:"driver name" ^|findstr /b "27:"') do set driverName=%%a
)
If "%printerName2%" == "44:Printer name %pName%" (
For /f "delims=" %%a in ('cscript prnmngr.vbs -l ^|findstr /i /b /n /c:"driver name" ^|findstr /b "46:"') do set driverName=%%a
)
If "%printerName0%" == "6:Printer name %pName%" (
set pDriver=%driverName:~14%
)
If "%printerName1%" == "25:Printer name %pName%" (
set pDriver=%driverName:~15%
)
If "%printerName2%" == "44:Printer name %pName%" (
set pDriver=%driverName:~15%
)
echo %pDriver%
pause

Answer 1

Using my original script I was able to prevent the ) from being clipped by inserting "" around the variable being set in the final If Check and then removing them from the command I am inputting the variable into.
If "%printerName0%" == "6:Printer name %pName%" (
set pDriver="%driverName:~14%"
)
If "%printerName1%" == "25:Printer name %pName%" (
set pDriver="%driverName:~15%"
)
If "%printerName2%" == "44:Printer name %pName%" (
set pDriver="%driverName:~15%"
)
Where the variable is getting used later on:
cscript prndrvr.vbs -d -m %pDriver%
No quotes are needed as the are included in the first section of code where I set the final variable name. Where as this answer does require a few more lines of code it runs faster.
The Reason For The Issue:
When ) came up in the variable string Batch was seeing it as the end of the If Check and not as an included character in the variable string. In order to retain and prevent unwanted results from the code " " must encase the variable.

Answer 2

This is what I think you are trying to do. Was really baffled by all your extra findstr code and set commands.
#echo off
SETLOCAL ENABLEDELAYEDEXPANSION
PUSHD C:\Windows\System32\Printing_Admin_Scripts\en-US
SET I=0
For /f "tokens=1,2* delims= " %%G in ('cscript //Nologo //H:CScript prnmngr.vbs -l ^|findstr /i /c:"printer name"') do (
SET /A I+=1
SET "PRINTER.NAME[!I!]=%%I"
For /f "tokens=1,2* delims= " %%J in ('cscript //Nologo //H:CScript prncnfg.vbs -g -p "%%I" ^|findstr /i /c:"driver name"') do (
SET "PRINTER.DRIVER[!I!]=%%L"
)
)
FOR /L %%I IN (1,1,%I%) DO (
ECHO PRINTER %%I = !PRINTER.NAME[%%I]!
ECHO DRIVER %%I = !PRINTER.DRIVER[%%I]!
)
popd
pause
Output on my computer.
PRINTER 1 = Microsoft XPS Document Writer
DRIVER 1 = Microsoft XPS Document Writer
PRINTER 2 = Fax
DRIVER 2 = Microsoft Shared Fax Driver
PRINTER 3 = \\SERVER_NAME\WI5140-XEROX-9
DRIVER 3 = Xerox WorkCentre 5330 PCL6
PRINTER 4 = \\SERVER_NAME\WI5101-XEROX-12
DRIVER 4 = Xerox WorkCentre 5330 PS
PRINTER 5 = \\SERVER_NAME\WI5101-XEROX-1
DRIVER 5 = Xerox WorkCentre 7225 PS
PRINTER 6 = \\SERVER_NAME\WI5140-XEROX-31
DRIVER 6 = Xerox ColorQube 8870DN PS
PRINTER 7 = \\SERVER_NAME\WI5140-XEROX-15
DRIVER 7 = Xerox Phaser 5550DN PS
Press any key to continue . . .
EDIT: 20170225 14:35 CST
As you have said in previous comments you are only looking for one printer driver and I have said in previous comments you can do that with EXACTLY one FOR /F command since you already know the name of the printer. You don't need to use prnmngr.vbs to get the driver because prncnfg.vbs allows you to list the configuration for a printer and then you can use findstr to just get the driver. You know the name of the printer so you use that as your input to prncnfg.vbs to list the configuration for that printer.
For /f "tokens=1,2* delims= " %%J in ('cscript //Nologo //H:CScript prncnfg.vbs -g -p "%pName%" ^|findstr /i /c:"driver name"') do set "pDriver=%%L"
EDIT 20170225 15:20 CST
Lets brute force to get the driver with prnmngr.vbs since that seems to be what you want to use to get the driver.
Set "pName=%comp%P1"
set "flag="
For /f "tokens=1,2* delims= " %%G in ('cscript //nologo prnmngr.vbs -l ^|findstr /i /b /C:"printer name" /C:"driver name"') do (
IF DEFINED flag set "pDriver=%%I" &GOTO :BREAK
IF "%pName%"=="%%~I" SET flag=1
)
:BREAK
echo %pDriver%
pause