I've created a single file.bat that execute correctly two different vbs files:
cscript "\\server_1\dir\file_M_1.vbs" "\\server_1\dir\muc1.xlsm"
cscript "\\server_2\dir\file_H_2.vbs" "\\server_2\dir\muc2.xlsm"
the code of the two files.vbs is the same, because it was created to do the same thing in two different servers.
This is the contents of file_M_1.vbs, that simply runs the macro called "copy_M":
Dim args, objExcel
Set args = WScript.Arguments
Set objExcel = CreateObject("Excel.Application")
objExcel.Workbooks.Open args(0)
objExcel.Visible = False
objExcel.Run "copy_M"
objExcel.ActiveWorkbook.Save
objExcel.ActiveWorkbook.Close(0)
objExcel.Quit
Instead this is the code of file_H_2.vbs, that runs macro called "copy_H":
Dim args, objExcel
Set args = WScript.Arguments
Set objExcel = CreateObject("Excel.Application")
objExcel.Workbooks.Open args(0)
objExcel.Visible = False
objExcel.Run "copy_H"
objExcel.ActiveWorkbook.Save
objExcel.ActiveWorkbook.Close(0)
objExcel.Quit
I' d like to know if there' s the possibility to collect all three pieces of code in only one file.bat or file.exe
(to be even scheduled to run in a specific time with the task scheduler of windows7.)
I' ve solved the problem in this way. With the help of others we have created only one file.bat:
cscript "\\server1\dir\file.vbs"
it runs the file.vbs:
Dim objExcel
Set objExcel = CreateObject("Excel.Application")
objExcel.Workbooks.open("\\server1\dir\muc1.xlsm")
objExcel.Visible = False
objExcel.Run "copy_M"
objExcel.ActiveWorkbook.Save
objExcel.ActiveWorkbook.Close
objExcel.Workbooks.open("\\server2\dir\muc2.xlsm")
objExcel.Visible = False
objExcel.Run "copy_H"
objExcel.ActiveWorkbook.Save
objExcel.ActiveWorkbook.Close
objExcel.Quit
it runs perfectly. I 've put in the task scheduler of windows7 the file.bat and all it' s ok.
I don' t know if it' s possible to create only one .exe (not a .bat that runs .vbs)
Related
I have a large number of image files spanning nearly two decades where the subject is identified by the directory name and most of the photos themselves have a generic name however some of them have more specific names.
I am writing a script to prepend the directory name to the filename for all files in a specific directory. Well, I am trying to at least.
It has been a few years since I used VBScript and it seems I am VERY rusty.
I am facing challenges with the syntax format.
When I have Option Explicit (on line 6) it gives an error of Line 6, Char 1, Error: Expected Statement, Code: 800A0400 (In my shared code it would be line 7 because of the added Beginning of File line)
If I comment that out, I get an error on the import statements instead of Line 3, char 1, Error: Type mismatch: 'Imports', Code: 800A000D (In my shared code, it would be line 4 because of the added Beginning of File line)
I have spent a few hours googling for possible causes but to no avail and so I am turning to the community for help with getting the formatting of this script set correctly.
Any comments on a better script approach for accomplishing this task would be appreciated as well.
I am going to put in the entire code for the file because I do not know what part of it will be the relevant aspect.
In the code, it is currently set to only create a message box for each file as a test measure to ensure the variables have the values I think they have.
The commented out code for renaming the file is the truly intended purpose.
I am stuck on the proper formatting of the first part of the file however.
In general, I am executing this from the command line using: cscript.exe c:\MyTools\addDir2FileName.vbs
I launched it through windows explorer to get the more specific error codes with line numbers though.
I added the Beginning of File and End of File comments just for the purpose of clarity in this post.
' ####### Beginning of File
' Renames all files in a directory prepending the directory name to the file name
Imports System
Imports System.IO
Option Explicit
Dim WshShell, strOldFull, strNewFull, strFullPath, strCurDir
Dim strCurrentName, strNewName, strMessage, dir, fileObj, fs, fo
' Get the current directory
Set WshShell = CreateObject("WScript.Shell")
strFullPath = WshShell.CurrentDirectory
'Get folder properties to get just the name without path
Set fs=Server.CreateObject("Scripting.FileSystemObject")
Set fo=fs.GetFolder(strFullPath)
strCurDir = fo.Name
'Iterate through the directory
set dir = DirectoryInfo(strFullPath)
For Each fileObj In dir.GetFiles()
strCurrentName = fileObj.Name
strNewName = strCurDir & " - " & strCurrentName
' For testing purposes to make sure everything is as expected
' Creates a message box for each file instead of actually renaming it
strMessage = "Old Name: " & strCurrentName & chr(13) & chr(10) & "New Name: " & strNewName
MsgBox strMessage
' Renaming the file
' strOldFull = fs.BuildPath(CurrentDirectory, strCurrentName)
' strNewFull = fs.BuildPath(CurrentDirectory, strNewName)
' My.Computer.FileSystem.RenameFile(strOldFull, strNewFull)
Next
WshShell = Nothing
fo = Nothing
fs = Nothing
' ### End of File
The expectation is that a file "C:\Pictures\Trip to Nice\DCM001.jpg" will get renamed to "C:\Pictures\Trip to Nice\Trip to Nice - DCM001.jpg" and that all files in the directory that the script is run in will be similarly renamed.
Well, to be more precise, the output as currently formatted will produce a message box that says "Old Name: C:\Pictures\Trip to Nice\DCM001.jpg New Name: C:\Pictures\Trip to Nice\Trip to Nice - DCM001.jpg" and that a message box will be produced for all files in the directory. Yes, I will only run message box version in a test directory with 3 files. I would hate to get 50,000 message boxes, lol.
There is no output at current because of the formatting issues with either the Import Statement or the Option Explicit, or perhaps some other syntax piece I am missing or have wrong.
Thank you for your time and any help that anyone is able to provide. This is the first time I am posting to the community but I have long appreciated the answers provided. Usually, I can find my questions already answered, but I am stumped on this one...
Okay, through a lot of trial and error, I figured out a method to complete the task where I did not use System and so avoided the error that I was receiving before.
I thought to post the final script, in case anyone was interested.
' Renames all files in a directory prepending the directory name to the file name
Option Explicit
Dim WshShell, strOldFull, strFullPath, strCurDir, lastSlash
Dim strCurrentName, strNewName, strMessage, fileObj, fileSpec, fs, fo, ff
' Get the current directory
Set WshShell = CreateObject("WScript.Shell")
strFullPath = WshShell.CurrentDirectory
'Get folder object
Set fs = CreateObject("Scripting.FileSystemObject")
Set fo = fs.GetFolder(strFullPath)
set ff = fo.Files
'Get just the folder name
lastSlash = inStrRev(strFullPath, "\")
strCurDir = right(strFullPath, len(strFullPath) - lastSlash )
'Iterate through the directory
For Each fileObj in ff
strCurrentName = fileObj.Name
strNewName = strCurDir & " - " & strCurrentName
' For testing purposes to make sure everything is as expected
' Creates a message box for each file instead of actually renaming it
' strMessage = "Old Name: " & strCurrentName & chr(13) & chr(10) & "New Name: " & strNewName
' MsgBox strMessage
' Renaming the file
strOldFull = strFullPath & "\" & strCurrentName
set fileSpec = fs.GetFile(strOldFull)
fileSpec.Name = strNewName
Next
' Declare variables
Dim objFSO, objParentFolder, objFolder, objFile
' Set the parent directory to be processed
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objParentFolder = objFSO.GetFolder("C:\path\to\parent\directory")
' Function to process the subfolders
Sub ProcessSubFolders(folder)
' Loop through all files in the folder
For Each objFile In folder.Files
' Get the current file name
strFileName = objFile.Name
' Get the folder name
strFolderName = folder.Name
' Build the new file name
strNewFileName = strFolderName & "_" & strFileName
' Rename the file
objFile.Name = strNewFileName
Next
' Loop through all subfolders
For Each objFolder In folder.SubFolders
' Recursively call the function for the subfolder
ProcessSubFolders(objFolder)
Next
End Sub
' Call the function to process the top-level folder
ProcessSubFolders(objParentFolder)
' Clean up
Set objFile = Nothing
Set objParentFolder = Nothing
Set objFSO = Nothing
I found a script for install fonts and I edited it to install some fonts (array of fonts) alongside but it doesn't run. This line raises an error:
array.InvokeVerb("Install")
It seems to replace InvokeVerb with another function but I dont know!
Can some one help me?
My script:
Option Explicit
'Installing multiple Fonts in Windows 7
Dim objShell, objFSO, wshShell
Dim strFontSourcePath, objFolder, objFont, objNameSpace, objFile
Dim array : Set array = CreateObject("System.Collections.ArrayList")
Set objShell = CreateObject("Shell.Application")
Set wshShell = CreateObject("WScript.Shell")
Set objFSO = createobject("Scripting.Filesystemobject")
strFontSourcePath = "C:\Users\Win7\Desktop\new_Software\Fonts"
If objFSO.FolderExists(strFontSourcePath) Then
Set objNameSpace = objShell.Namespace(strFontSourcePath)
Set objFolder = objFSO.GetFolder(strFontSourcePath)
For Each objFile In objFolder.Files
If LCase(Right(objFile,4)) = ".ttf" Or LCase(Right(objFile,4)) = ".otf" Then
array.Add objNameSpace.ParseName(objFile.Name)
End If
Next
array.InvokeVerb("Install")
Else
WScript.Echo "Font Source Path does not exists"
End If
ArrayList objects don't have an InvokeVerb method, and VBScript doesn't provide member enumeration like PowerShell does (which would allow the interpreter to invoke the method on the array items rahter than the array itself).
As ACatInLove already mentioned you need to use a For Each loop to enumerate the array elements and invoke the method on each element:
For Each el In array
el.InvokeVerb("install")
Next
I've read a lot about automating WinSCP, but some of it I had trouble understanding because it presumed knowledge of other things, like .NET assembly, PowerShell, etc.
I'm wondering if, speaking strictly in VBScript and batch file file type of lingo, once I've downloaded the portable winscp.exe, how to simply open a remote site, give a user name and password, and download a list of the files in a particular directory. FTP protocol only.
There's an example for using the Session.ListDirectory from VBScript:
<job>
<reference object="WinSCP.Session"/>
<script language="VBScript">
Option Explicit
' Setup session options
Dim sessionOptions
Set sessionOptions = WScript.CreateObject("WinSCP.SessionOptions")
With sessionOptions
.Protocol = Protocol_Ftp
.HostName = "ftp.example.com"
.UserName = "user"
.Password = "mypassword"
End With
Dim session
Set session = WScript.CreateObject("WinSCP.Session")
' Connect
session.Open sessionOptions
Dim directoryInfo
Set directoryInfo = session.ListDirectory("/remote/path")
Dim fileInfo
For Each fileInfo In directoryInfo.Files
WScript.Echo fileInfo.Name & " with size " & fileInfo.Length & _
", permissions " & fileInfo.FilePermissions & _
" and last modification at " & fileInfo.LastWriteTime
Next
' Disconnect, clean up
session.Dispose
</script>
</job>
Other than that:
download the WinSCP .NET assembly package and extract it along with the script.
register the assembly for COM. Typically like:
%WINDIR%\Microsoft.NET\Framework\v4.0.30319\RegAsm.exe WinSCPnet.dll /codebase /tlb:WinSCPnet32.tlb
%WINDIR%\Microsoft.NET\Framework64\v4.0.30319\RegAsm.exe WinSCPnet.dll /codebase /tlb:WinSCPnet64.tlb
Run the script (list.wsf) like:
cscript list.wsf
You can of course also just run winscp.com scripting like:
Set shell = CreateObject("WScript.Shell")
Set exec = shell.Exec("winscp.com /command ""open ftp://username:password#ftp.example.com/"" ""ls /remote/path"" ""exit""")
WScript.Echo(exec.StdOut.ReadAll())
For more details on this approach see guide to advanced FTP scripting from VB script.
I have a Code which passes dates arguments to a visual basic code which is inside excel file.Code inside the Date.txt file is pasted below:
`Set objExcel = CreateObject("Excel.Application")`
'With objExcel'
'.Workbooks.Open "C:\emailfetch\FetchEmails.xlsm"'
'.Visible = True'
'.Run "FolderTraverse",cLng(DateSerial(2014,3,1)),cLng(DateSerial(2014,3,4))'
'.ActiveWorkbook.Close True'
'.Quit'
'End With'
I need to execute the above code from execute.bat file. Execute.bat file consists 2 other files .Codes need to executed
In Steps
1.Date.txt
2.makezip.vbs
3.mailsend.cmd.
Can anybody helps how to execute the code which is inside Date.txt with the help of batch file execute.bat
You can do this two ways. Both require you to make 2 files.
1: Using a windows scripting host framework xml wrapper. Which allows you to execute windows scripts regardless of language via command prompt.
scriptrollout.wsf
<job>
<script language="VBScript" src="data.txt"/>
<script language="VBScript" src="makezip.vbs"/>
</job>
batchfile.bat
cscript.exe scriptrollout.wsf
mailsend.cmd
2: Using the ExecuteGlobal Command
ExecGlob.vbs
Function Include(vbs)
Dim fso, f, s : Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile(vbs) : s = f.ReadAll()
f.Close : ExecuteGlobal s
End Function
Include "Date.txt"
Include "makezip.vbs
batchfile.bat
cscript.exe ExecGlob.wsf
mailsend.cmd
Goal: To run a VBScript that checks a folder daily, and reports if no files were saved to it that day. Ignore the files that exist from previous days.
Scenario: A logfile is created everyday in C:\Temp at 3am. This is what tells us that the system performed a task. If a log file isn't generated, then the task crashed. I wrote this to check the Temp folder for a file created today, and to email me if it doesn't exist.
Solution thus far:
option explicit
dim fileSystem, folder, file
dim path
path = "C:\Temp"
Set fileSystem = CreateObject("Scripting.FileSystemObject")
Set folder = fileSystem.GetFolder(path)
for each file in folder.Files
if file.DateLastModified > dateadd("h", -24, Now) then
'WScript.Echo file.Name & " last modified at " & file.DateLastModified
else
SendEmail
'WScript.Echo "this should have sent an email."
end if
next
Function SendEmail()
'Send Email notification function here (this part works already)
End Function
Issue I am having:
I can't seem to wrap my head around a way to have the script ignore files in the folder from previous days.
In my test, I have C:\Temp populuated with a file modified today, and a file modified on 7/10/12. Because this scenario matches both the 'then' and the 'else' statement, it's doing both.
I think I just need a slight modification on the loop to tell it
- Ignore files not dated 'today'
- Send an email if no files exist today.
Any help would be awesome. I just can't seem to 'see' the answer.
You're close. The problem is is you were looping through and checking every single file. You need to only check if one file doesn't exist. I'm not that familiar with vbscript, so you may need to tweak this a bit, but what I did is add a variable found and initialized it to false. If you find a file created in past 24 hours, set it to true. once you're done looping, if it's still false, no files were modified in past 24 hours
option explicit
dim fileSystem, folder, file
dim path
Dim found
found = false
path = "C:\Temp"
Set fileSystem = CreateObject("Scripting.FileSystemObject")
Set folder = fileSystem.GetFolder(path)
for each file in folder.Files
if file.DateLastModified > dateadd("h", -24, Now) then
found = true
end if
next
if (found = false) then
SendEmail
End If
Function SendEmail()
'Send Email notification function here (this part works already)
End Function
I would suggest first removing the time from the date check
Second Since you stated that the file is created each night I would check the DateCreated and not DateModified.
I modified your code below to add a variable Dim myDate and then set it to the previous day
Dim myDate
myDate = dateadd("d", -1, FormatDateTime(Now, 2))
I then changed the line
if file.DateCreated > myDate then
to look at the new variable.
Running this with the echo command worked as you described
and notified my of only the file that was created today.
option explicit
dim fileSystem, folder, file
dim path
path = "C:\Temp"
Set fileSystem = CreateObject("Scripting.FileSystemObject")
Dim myDate
myDate = dateadd("d", -1, FormatDateTime(Now, 2))
Set folder = fileSystem.GetFolder(path)
for each file in folder.Files
if file.DateCreated > myDate then
'WScript.Echo file.Name & " last modified at " & file.DateCreated
SendEmail
'WScript.Echo "this should have sent an email."
end if
next
Function SendEmail()
'Send Email notification function here (this part works already)
End Function
This script:
Option Explicit
' config data, fixed
Const csPATH = "..\data"
' config data, computed, show use of DateValue() to cut off time
Dim dtCheck : dtCheck = DateValue(DateAdd("d", 0, Now))
WScript.Echo "dtCheck:", dtCheck
Dim oFS : Set oFS = CreateObject("Scripting.FileSystemObject")
Dim bFound : bFound = False ' assume no up-to-date file found
Dim oFile
For Each oFile In oFS.GetFolder(csPATH).Files
WScript.Echo "Check:", DateValue(oFile.DateLastModified), oFile.Name
If DateValue(oFile.DateLastModified) = dtCheck Then
WScript.Echo "Found:", DateValue(oFile.DateLastModified), oFile.Name
WScript.Echo "no need for further loopings"
bFound = True
Exit For
End If
Next
If Not bFound Then
WScript.Echo "Sending email ..."
End If
output 1:
dtCheck: 12.07.2012
Check: 11.07.2012 11434579.kpf
Check: 11.07.2012 11434579.notes
Check: 11.07.2012 11434579-UE15.prj
Sending email ...
output 2:
dtCheck: 12.07.2012
Check: 11.07.2012 11434579.kpf
Check: 11.07.2012 11434579.notes
Check: 11.07.2012 11434579-UE15.prj
Check: 12.07.2012 11458011.notes
Found: 12.07.2012 11458011.notes
no need for further loopings
expands on Ghost's approach by breaking/exiting the loop as soon as a/the up-to-date file is found, avoids re-computings of the check date (based on volatile Now!) in the loop, and demonstrates the importance of code you don't write (e.g.: Set folder = ..., If (found = false) ..).