How to set environment variable with & - batch-file

Question

So I have a bat file that I wrote, and I am having issues with setting variables that contain an & in the file path.
Right now this works, but I can't use the %SOURCE% or %DEST% variables in the copy command. I get an error. Hence the reason I have the full path written out in the copy command.
#echo off
echo Backing Up Build Files ^& Templates
echo.
:: do a dump of repo
echo Creating Dump File
svnadmin dump "Z:\Subversion\Build Files "^&" Templates" > "Z:\Subversion\Build Files "^&" Templates_repository-backup.dmp"
:: copy dump file to backup location
set YEAR=%date:~10,4%
set MONTH=%date:~4,2%
set DAY=%date:~7,2%
set THE_DATE=%MONTH%_%DAY%_%YEAR%
set SPACE_CHECK=%time:~0,1%
if "%SPACE_CHECK%"==" " goto handlehourspace
set HOURS=%time:~0,2%
goto hourdone
:handlehourspace
set HOURS=0%time:~1,1%
:hourdone
set MINUTES=%time:~3,2%
set SECONDS=%time:~6,2%
set THE_TIME=%HOURS%_%MINUTES%_%SECONDS%
set SOURCE="Z:\Subversion\Build Files "^&" Templates_repository-backup.dmp"
set DEST="K:\IETM_Repo_Backup\Build Files "^&" Templates\Build Files "^&" Templates_repository-backup.dmp"_%THE_DATE%_%THE_TIME%
echo Copying Dump File
copy /Z "Z:\Subversion\Build Files "^&" Templates_repository-backup.dmp" "K:\IETM_Repo_Backup\Build Files "^&" Templates\Build Files "^&" Templates_repository-backup.dmp"_%THE_DATE%_%THE_TIME%
echo Deleting Original Dump File
del "Z:\Subversion\Build Files "^&" Templates_repository-backup.dmp"

Answer 1

use this syntax: set "var=value" to be able to use special chars in a value:
set "x=this&that"
echo "%x%"
REM create a file:
break>"%x%"
dir this*
REM remove the file:
del "%x%"

Answer 2

With your style set DEST="K:\...." the quotes are part of the content. With the extended SET-syntax set "DEST=K:\...." they escape the string but aren't part of the string.
In the most cases you should use the extended syntax
set "SOURCE=Z:\Subversion\Build Files & Templates_repository-backup.dmp"
set "DEST=K:\IETM_Repo_Backup\Build Files & Templates\Build Files & Templates_repository-backup.dmp_%THE_DATE%_%THE_TIME%"
copy /Z "%SOURCE%" "%DEST%"
In the copy "%SOURCE%" ... line the quotes are necessary to escape again the ampersands and spaces.

Answer 3

To have a locale independent way to format the date/time I suggest using WMI
and the backup of the dump file stays better usable when the extension remains the last part of the file name, not the date/time stamp.
#echo off
echo Backing Up Build Files ^& Templates
echo.
:: get datetime string of the format yyyyMMddhhnnss.
for /f "tokens=1-3 delims=.+-" %%A in (
'wmic os get LocalDateTime^|findstr ^^[0-9]'
) do Set _DT=%%A
set THE_DATE=%_DT:~4,2%_%_DT:~6,2%_%_DT:~0,4%
set THE_TIME=%_DT:~8,2%_%_DT:~10,2%_%_DT:~12,2%
:: do a dump of repo
echo Creating Dump File
set "BFT=Build Files & Templates"
set "svnBFT=Z:\Subversion\%BFT%"
set "svnSRC=%svnBFT%_repository-backup.dmp"
svnadmin dump "%svnBFT%" > "%svnSRC%"
:: copy dump file to backup location
echo Copying Dump File
set "DEST=K:\IETM_Repo_Backup\%BFT%\%BFT%_repository-backup_%THE_DATE%_%THE_TIME%.dmp"
copy /Z "%svnSRC%" "%Dest%"
echo Deleting Original Dump File
del "%svnSRC%"