string to integer conversion in batch - batch-file

Question

Script stores the lines along with line numbers where ever "firstword" is found, those line numbers are retrieved from temp_onsetTime.txt. trying to retrieve the 4th line from that line number and write it in another file.
line set var=%%g% set /a var=%var% + 4 , string var is not getting converted into integer.
cls
break>ontset_time.txt
break>temp_ontsetTime.txt
set firstword="stimuli\1200.wav"
set secondword="MainScreen.OnsetTime"
findstr /l /I /n %firstword% "C:\Users\BHAVYA\Desktop\AudOdd.txt">>temp_ontsetTime.txt
for /F " delims=: tokens=1 " %%g in ( C:\Users\BHAVYA\Desktop\temp_ontsetTime.txt ) do (
echo %%g
echo.
set var=%%g%
set /a var=%var% + 4
echo %var%
for /F " delims=: tokens=1,2 skip= %var%" %%h IN ( ' findstr /l /I %secondword% "C:\Users\BHAVYA\Desktop\AudOdd.txt" ' ) do (
echo %%h %%i
echo %%i%>>ontset_time.txt
goto loop_end
)
:loop_end
echo loop ended
)
pause

Answer 1

Problem 1: set var=%%g% is incorrect; set var=%%g is closer (%%g accesses the metavariable %%g); set /a var=%%g is better still (since %%g is apparently an integer).
Problem2: You need to learn about delayed expansion - there are hundreds of references here on SO. Batch replaces every %var% with its value as it stands when the for loop is parsed - not when it is executed, hence
set /a = var + 4
will increase the value of var by 4 - you then need to use
call echo %%var%%
to access the changed value of var if you are not using delayed expansion.
AAMOI, this is equivalent to
set /a var=%%g+4
Third problem - still the delayedexpansion problem - %var% will be replaced by its value at the time for...%%g... was parsed, not the value as modified within the loop.
Fourth problem : labels are not allowed within a block statement (a parenthesised series of statements).
Here's a cure without delayed expansion
for /F " delims=: tokens=1 " %%g in ( C:\Users\BHAVYA\Desktop\temp_ontsetTime.txt ) do (
echo %%g
echo.
set /a var=%%g + 4
call echo %%var%%
for /f "tokens=1,2delims==" %%m in ('set var') do if /i "%%m"=="var" (
echo var is %%n
set "show=Y"
for /F " delims=: tokens=1,2 skip=%%n" %%h IN ( ' findstr /l /I %secondword% "C:\Users\BHAVYA\Desktop\AudOdd.txt" ' ) do if defined show (
echo %%h %%i
set "show="
echo %%i%>>ontset_time.txt
)
)
echo loop ended
)
Note here that using set var will list the current environment values that begin var in the format var=99. We tokenise that on = and the first token (%%m) must be var, not var1 or anything else. If it is, its value is in %%n, so set the flag show to a value (any value will do) and then process the file. On the first "hit", clear the value in show- it is now undefined, so no more processing takes place until the next outer loop starts.
[I obviously can't test this]