Neo4j independent selection over several match clauses - database

Question

I want to select with neo4j the users, the amount of action movies they watched and how many of this action movies from each user where directed by Roland Emmerich.
I tried in various forms this query:
match (u:User)-[:watched]->(m:Movie)-[belongs_to]->
(Category{category_name:"Action"}) with count(m) as actionMovies, u
match (m:Movie)<-[directed]-(Director{director_name:"Roland Emmerich"})
return u, count(m) as MoviesFromRE, actionMovies
But the query execution never finishes. So I assume I'm doing something like a cross join.
Actually I expect to have the first count independent of the second since its already calculated when compiler comes to the second match clause.
Here is the relevant db view
Thanks for any suggestions and helps
Ok after get rid of the typos and including Movies in with clause:
match (u:User)-[:watched]->(m:Movie)-[:belongs_to]->
(:Category{category_name:"Action"}) with count(m) as actionMovies, u, m
match (m)<-[:directed]-(:Director{director_name:"Roland Emmerich"})
return u, count(m) as MoviesFromRE, actionMovies order by u.user_name
Now I get for actionMovies always 1. I think its because I group now in first with clause by Movies. I think I need a way to take the Movies from the first clause to the second but not group my first result by them.

Answer 1

The reason you are always getting 1 for actionMovies is in this clause:
WITH COUNT(m) AS actionMovies, u, m
That clause is saying (in part): "count the number of m nodes for every unique pair of u and m nodes". That count must always be 1.
This query should work better:
MATCH (u:User)-[:watched]->(am:Movie)-[:belongs_to]->(:Category{category_name:"Action"})
WITH u, COLLECT(am) AS ams
UNWIND ams AS m
OPTIONAL MATCH (m)<-[dir:directed]-(:Director{director_name:"Roland Emmerich"})
RETURN u, COUNT(dir) AS MoviesFromRE, SIZE(ams) AS actionMovies
ORDER BY u.user_name;