batch script that updates the version number values in a text file - batch-file

Question

Hi I am trying to write a script that updates the MAJOR and MINOR version numbers in a header/text file, I am trying to use the "FOR /F " command but out of ideas.
Below is the Header file to which I need to update the values corresponding to "MAJOR_VERSION" and "MINOR_VERSION "
#ifndef _VERSION_H_
#define _VERSION_H_
//---------- Lock Firmware Package Version ------------
//Lock firmware package
#define MAJOR_VERSION 3 //0-255
#define MINOR_VERSION 58 //0-255
#define REVISION_VERSION 0 //0-255 should generally always be 0 unless the meaning change
//---------- VERSION ----------------------

Answer 1

The following script -- let us call it update-versions.bat -- should do what you want:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem // Parse command line arguments:
set "DIRN=#define"
set "FILE=%~1"
if not defined FILE (>&2 echo ERROR: too few arguments!) & exit /B 1
shift /1
set /A "IDX=0"
:ARGS
set "ARGV=%~1"
if not defined ARGV goto :SKIP
set /A "IDX+=1"
set "KEY[%IDX%]=%ARGV::=" & rem "%"
if not defined KEY[%IDX%] set /A "IDX-=1" & goto :SKIP
set "VER[%IDX%]=10000%ARGV:*:=%"
set /A "VER[%IDX%]%%=10000"
shift /1
goto :ARGS
:SKIP
rem // Process file:
for /F "delims=" %%L in ('findstr /N /R "^" "%FILE%" ^& ^> "%FILE%" rem/') do (
set "LINE=%%L"
setlocal EnableDelayedExpansion
(
for /F "tokens=1-3*" %%A in ("!LINE:*:=!") do (
endlocal
if /I "%%A"=="%DIRN%" (
set "VER=" & set "ITEM=%%B" & set "REST=%%D"
setlocal EnableDelayedExpansion
for /L %%I in (1,1,%IDX%) do (
if /I "!ITEM!"=="!KEY[%%I]!" (
set "KEY=!KEY[%%I]!"
set "VER=!VER[%%I]!"
)
)
if defined VER (
>> "!FILE!" echo(!DIRN! !KEY! !VER! !REST!
) else (
>> "!FILE!" echo(!LINE:*:=!
)
) else (
setlocal EnableDelayedExpansion
>> "!FILE!" echo(!LINE:*:=!
)
)
) || (>> "!FILE!" echo/)
endlocal
)
endlocal
exit /B
To use it, you need to provide the file to modify and the version information as command line arguments:
update-versions.bat "\path\to\file.h" MAJOR_VERSION:3 MINOR_VERSION:59 REVISION_VERSION:0
As you can see the first argument is the path to the file, which is mandatory. Each of the remaining arguments specifies a version number keyword (appearing after the #defined directive) and the related new version number, separated by a colon; all these are optional arguments.

Answer 2

This is my answer to an identical question That was deleted by the owner "Dinesh" after I'd answered it yesterday.
#ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "filename1=%sourcedir%\q40733227.txt"
SET "itemlist=major_version minor_version"
FOR /f "usebackqtokens=1-3*" %%a IN ("%filename1%") DO (
FOR %%i IN (%itemlist%) DO IF /i "%%b"=="%%i" SET "%%b=%%c"
)
FOR %%i IN (%itemlist%) DO SET %%i
GOTO :EOF
You would need to change the setting of sourcedir to suit your circumstances.
I used a file named q40733227.txt containing your data for my testing.
Tokenise each line using the defaults. The string in the second token (for the values selected by itemlist) should take on the value in the third token.
You could extend the values extracted in the obvious way, extend itemlist

Answer 3

Here is a simple script that uses JREPL.BAT - a regular expression find/replace utility. JREPL is pure scrpt (hybrid batch/JScript) that runs natively on any Windows machine from XP onward - no 3rd party exe file required. Full documentation is available from the command line via jrepl /?, or jrepl /?? for paged help.
updateHeader.bat
#echo off
setlocal
set "var="
:loadVar
set "%~2=%~3"
set "var=%Var%%~2|"
shift /2
shift /2
if "%~2" neq "" goto :loadVar
call jrepl "(#define +(%var:~0,-1%) +)\d+" "$txt=$1+env($2)" /jq /f %1 /o -
The batch script parses the command line arguments. It builds a list of variable names to be replaced (simple regular expression alternation), and also sets an environment variable for each specified variable. The JREPL call replaces each value with the value of the corresponding environment variable.
The syntax for using the above script is updateHeader File Variable=Value[ Variable=Value].... The Variable names are case sensitive.
For example, to update file "version.h" with major version=4 and minor version=01:
updateHeader version.h MAJOR_VERSION=4 MINOR_VERSION=01
Or you could update just the revision version to 1, and specify a different path for the file:
updateHeader "c:\somePath\version.h" REVISION_VERSION=1
You can specify as many replacements as you like, as long as each line to be replaced has the form #define VARIABLE value .... The number of spaces can vary.