Merge two files with different header value - file

Question

I need to merge 2 files into a new file using .vbs. Both files contains header and data. For header, I need to sum both files row count & also the total amount. For the data, I need to merge both data from these two files.
Header format:
yyyymmdd|FILENAME|row count|total amount
Sample of files & format as below:
File 1:
20160204|FILENAME|3|17
20160204|SARAH|OWEN|SCIENCE BOOK|20090717|USD|2|SCIENCE|0|
20160204|KYLE|PARKER|ENGLISH BOOK|20090717|USD|10|ENGLISH|0|
20160204|LILY|MORGAN|POLITICAL BOOK|20090717|USD|5|POLITICS|0|
File 2:
20160204|FILENAME|1|4
20160204|ADAM|HANSEL|HISTORY BOOK|20090717|USD|4|HISTORY|0|
Output:
20160204|FILENAME|4|21
20160204|SARAH|OWEN|SCIENCE BOOK|20090717|USD|2|SCIENCE|0|
20160204|KYLE|PARKER|ENGLISH BOOK|20090717|USD|10|ENGLISH|0|
20160204|LILY|MORGAN|POLITICAL BOOK|20090717|USD|5|POLITICS|0|
20160204|ADAM|HANSEL|HISTORY BOOK|20090717|USD|4|HISTORY|0|
I only managed to merge the two files. But it is not the output I want.
So far I only have this:
Const ForReading = 1
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objOutputFile = objFSO.CreateTextFile("MYFILE.txt")
Set objTextFile = objFSO.OpenTextFile("D:\Testing\MYFILE1.txt", ForReading)
strText = objTextFile.ReadAll
objTextFile.Close
objOutputFile.WriteLine strText
Set objTextFile = objFSO.OpenTextFile("D:\Testing\MYFILE2.txt", ForReading)
strText = objTextFile.ReadAll
objTextFile.Close
objOutputFile.WriteLine strText
objOutputFile.Close

Answer 1

What you need to do is:
read the data rows of the two files
extract the 7th field of each data row
calculate the sum of all extracted values
write the new header with sum and total number of data rows
write all data rows to the file
For small-ish files one way would be something like this:
datafiles = Array("D:\Testing\MYFILE1.txt", "D:\Testing\MYFILE2.txt")
Set fso = CreateObject("Scripting.FileSystemObject")
Dim header
ReDim data(-1)
sum = 0
For Each filename In datafiles
Set f = fso.OpenTextFile(filename)
header = Split(f.ReadLine, "|")
Do Until f.AtEndOfStream
ReDim Preserve data(UBound(data)+1)
line = f.ReadLine
data(UBound(data)) = line
sum = sum + CInt(Split(line, "|")(6))
Loop
f.Close
Next
Set f = fso.CreateTextFile("MYFILE.txt")
f.WriteLine header(0) & "|" & header(1) & "|" & (UBound(data)+1) & "|" & sum
For Each row In data
f.WriteLine row
Next
f.Close
Beware that this won't perform too well for large files, though. If you need to process files like that you'll have to handle them differently (writing the data rows line by line to a temporary file instead of keeping them in memory, then writing header and merged data to the final file line by line in a second step).

Answer 2

Hope this helps:
<%
Class contFiles
Public Files
Private Sub Class_Initialize()
Set Files = Server.CreateObject("Scripting.Dictionary")
End Sub
Private Sub Class_Terminate()
If IsObject(Files) Then
Files.RemoveAll()
Set Files = Nothing
End If
End Sub
Public Sub addFile(theFileName)
Files.Add theFileName, theFileName
End Sub
Public Default Function makeFile(fileName)
On Error Resume Next
theKeys = Files.Keys
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
Do Until IDx = Files.Count
Set TheTextStream = FSO.OpenTextFile(Server.MapPath(theKeys(IDx)), 1)
html = html & TheTextStream.ReadAll
IDx = IDx + 1
Loop
Set objTxt = FSo.CreateTextFile(Server.MapPath(fileName), True, False)
objTxt.Write(html)
objTxt.Close
If ( err.Number <> 0 ) Then
makeFile = False
Else
makeFile = True
End If
End Function
End Class
Set testFiles = New contFiles
testFiles.addFile("default.aspx")
testFiles.addFile("events.aspx")
testFiles.addFile("about.aspx")
response.write(testFiles.makeFile("test.txt"))
%>