Replacing strings with batch file command - batch-file

Question

I have many files that are name "12739-5468768.xml", what they have in common is the "12739", inside these files I want to replace every & with " AND " and every </ with nothing. I tried many commands and python command but it doesn't seem to operate on my computer.
#echo off
setlocal
setlocal enabledelayedexpansion
set "search=&"
set "replace= AND "
set "textfile=12739*"
set "newfile=Output.txt"
(
for /f "delims=" %%i in (%textfile%) do (
set "line=%%i"
set "line=!line:%search%=%replace%!"
echo(!line!
)
) > "%newfile%"
del %textfile%
rename %newfile% %textfile%
endlocal

Answer 1

Solution for a single file
This handles also !^, empty lines and lines beginning with ; in the file content.
#echo off
setlocal
call :replaceFile "12739-5468768.xml"
exit /b
:replaceFile
set "search=&"
set "replace= AND "
set "textfile=%~1"
set "newfile=%~1.replaced"
setlocal DisableDelayedExpansion
(
for /f "usebackq delims=" %%i in (`findstr /N "^" "%textfile%"`) do (
set "line=%%i"
setlocal EnableDelayedExpansion
set "line=!line:*:=!"
if defined line (
set "line=!line:%search%=%replace%!"
set "line=!line:</=!"
)
(echo(!line!)
endlocal
)
) > "%newfile%"
endlocal
exit /b

Answer 2

Download something called "FART"
then include it in the folder of the batch then do a bat with this code
"#echo off
FART -i -r "12739*" "&" " AND " "

Answer 3

You need to escape the & Ampersand using the ^ character.
#echo off
setlocal
setlocal enabledelayedexpansion
set "search=^&"
set "replace= AND "
set "textfile=12739*"
set "newfile=Output.txt"
(
for /f "delims=" %%i in (%textfile%) do (
set "line=%%i"
set "line=!line:%search%=%replace%!"
echo(!line!
)
) > "%newfile%"
del %textfile%
rename %newfile% %textfile%
endlocal