Breaking out of for loop in batch file when using goto - batch-file

Question

I need to run a program for each line in a file. I am triggering four instances at a time. After four instances, waiting for some time and triggering another one. After wait time batch script is breaking.
Please suggest if I'm doing wrong.
for /F "tokens=*" %%J in ( %JobListFile% ) do (
SET JobName=%%J
echo job name !JobName!
if "!JobName!" equ "" (
echo joblist not found... rerun the script..
REM exit /b
) else (
:waittofinish
for /F "tokens=*" %%a in ( 'tasklist /fi "IMAGENAME eq dsexport.exe" ^| grep -c "dsexport.exe"' ) do ( SET /A CurrInstances=%%a )
echo current instance is !CurrInstances!
echo parallelism set to !NoOfParallelInstances!
if "!CurrInstances!" gtr "!NoOfParallelInstances!" (
echo going to wait
sleep 5
goto waittofinish
echo failed to go wait label...
) else (
echo Exporting job: !JobName! ...............Starting
start /b cmd /C "C:/IBM/9.1/InformationServer/Clients/Classic/dsexport.exe /D=%vDomain% /U=%vuserID% /P=%vpassword% /H=%vServer% %vDSProject% /NODEPENDENTS /JOB=!JobName! %tmppath%\!JobName!.dsx"
echo.
echo.
)
)
)
echo script completed...
exit /b

Answer 1

goto :Label breaks the block context of a code block in parentheses ( ... ); this is also true for for ... do ( ... ) loops and if ... ( ... ) else ( ... ) conditions.
To overcome this, you can put the code portion with goto and :Label into a subroutine, because this hides the block context of the calling code portion from goto, like this:
for /F "usebackq tokens=*" %%J in ( "%JobListFile%" ) do (
SET "JobName=%%J"
echo job name !JobName!
if "!JobName!" equ "" (
echo joblist not found... rerun the script..
REM exit /b
) else (
rem /* The `goto` and `:Label` code fragment has been transferred to a subroutine,
rem which receives the current value of variable `JobName` as an argument: */
call :waittofinish "!JobName!"
)
)
echo script completed...
exit /b
:waittofinish JobName
rem // This subroutine contains the `goto` and `:Label` code fragment so that it does no longer appear inside of a block `( ... )`:
for /F "tokens=*" %%a in ( 'tasklist /fi "IMAGENAME eq dsexport.exe" ^| grep -c "dsexport.exe"' ) do ( SET /A CurrInstances=%%a )
echo current instance is !CurrInstances!
echo parallelism set to !NoOfParallelInstances!
if "!CurrInstances!" gtr "!NoOfParallelInstances!" (
echo going to wait
sleep 5
goto :waittofinish
echo failed to go wait label...
) else (
echo Exporting job: %~1 ...............Starting
rem // Not sure if some arguments should be enclosed in `""` in the next line (but I do not know `dsexport.exe`):
start "" /b cmd /C "C:/IBM/9.1/InformationServer/Clients/Classic/dsexport.exe /D=%vDomain% /U=%vuserID% /P=%vpassword% /H=%vServer% %vDSProject% /NODEPENDENTS /JOB=%~1 %tmppath%\%~1.dsx"
echo.
echo.
)
exit /b
N. B.: I didn't check the logic of your script, because I don't have/know grep.exe or dsexport.exe.