Batch - How to perform mathematical operations on time codes? - batch-file

Question

I've been working on a batch script, to change some .xml files format/type.
It's almost done, but I'm facing a problem changing the time codes.
Here is an example
<Events>
<Event In="00:00:20.650" Out="00:00:22.970"
<Event In="00:00:23.050" Out="00:00:26.300"
This Time Format hh:mm:ss.ms should be changed to hh:mm:ss:ff
which means, changing the Milliseconds to Frames.
The Formula for doing so goes like this: ms*25/1000 or for simplicity ms*0.025
Output should be
<Events>
<Event In="00:00:20:16" Out="00:00:22:24"
<Event In="00:00:23:01" Out="00:00:26:08"
Notes
0.025 is the number of frames per Milliseconds.
The number of frames MUST be an integer w/o any fractional component.
I'm Using GNUWin and Cygwin library Tools, so it's okay to use bc expr , tr , awk sed or whatever solution to get the job done.

Answer 1

You can do it with an awk script:
script.awk
{
re = "[0-9]{2}:[0-9]{2}:[0-9]{2}.([0-9]{3})"
while( match( $0, re, grps) ) {
frames = sprintf("%02.0f",( grps[1] *0.025 ) )
gsub( "." grps[1], ":" frames)
}
print
}
Run it like this awk -f script.awk yourfile.
It tries to match such a timestamp and captures the last part (the milliseconds) into grps[1]. Then the calculation is done and sprintf is used to format the frames.
After that gsub replaces the milliseconds with the frames.

Answer 2

PowerShell:
[xml]$xml = gc events.xml
function fix([timespan]$ts) {
"{0}:{1:D2}" -f $ts.ToString("hh\:mm\:ss"),[int]($ts.Milliseconds * 0.025)
}
$xml.SelectNodes('//Event') | %{
$_.In = fix $_.In
$_.Out = fix $_.Out
}
$xml.Save("events_fixed.xml")
If you'd rather have it as a batch script, you can convert this to a Batch + PowerShell polyglot by inserting this at the top and saving it with a .bat extension:
<# : batch portion
#echo off & setlocal
powershell "iex (${%~f0} | out-string)"
goto :EOF
: end Batch / begin PowerShell hybrid code #>

Answer 3

Here is a pure batch-file solution. This script is secure against all characters that have special meanings to cmd. Basically, it searches the given input file for keywords or attribute names In and Out, followed by = and a time code enclosed in quotation marks "". If found, the milliseconds portion is split off, converted to frames and appended to the remaining time code, separated by :. There can be an arbitrary number of time codes per line, all of them are recognised and converted as long as their format is like given in your sample data and one of the given keywords is preceded.
The script supports rounding of the converted values -- see the remarks (rem) at variable definition FORMULA at the beginning of the file (look it up in the block with the remark Define constants here:).
This is the code:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem // Define constants here:
set KEYWORDS="In","Out" & rem // (provide a list of attribute names)
set "PATTERN=[0-9][0-9]:[0-9][0-9]:[0-9][0-9].[0-9][0-9][0-9]"
set /A PLENGTH=12 & rem // (char. length of resolved `PATTERN` string)
set "FORMULA=(MS*25+0)/1000" & rem /* (`+0` means to round frames down;
rem use `+999` instead to round up, or `+500` to round to nearest) */
set /A PADDING=2 & rem // (number of digits of resulting frame value)
set "FILE=%~1"
if not defined FILE exit /B 1
for /F "delims=" %%L in ('findstr /N /R "^" "%FILE%"') do (
set "LINE=%%L"
setlocal EnableDelayedExpansion
set "LINE=!LINE:*:=!"
if defined LINE (
for /F delims^=^ eol^= %%E in ("!LINE!") do (
endlocal
set "LINE=%%E"
setlocal EnableDelayedExpansion
)
) else (
endlocal
set "LINE="
setlocal EnableDelayedExpansion
)
for %%P in (!KEYWORDS!) do (
endlocal
set "KEYWORD=%%~P"
call :PROCESS LINE LINE KEYWORD
setlocal EnableDelayedExpansion
)
echo(!LINE!
endlocal
)
endlocal
exit /B
:PROCESS rtn_string ref_string ref_key
setlocal EnableDelayedExpansion
set "COLL="
set "LINE=!%~2!"
set "KEYW=!%~3!"
:LOOP
if defined LINE (
call :LEN LLENGTH LINE
call :LEN KLENGTH KEYW
for /F delims^=^ eol^= %%T in ("!KEYW!") do (
set "SEEK=!LINE:*%%T=!"
)
if defined SEEK (
if not "!SEEK!"=="!LINE!" (
call :LEN SLENGTH SEEK
set /A TLENGTH=LLENGTH-^(SLENGTH+KLENGTH^)
for /F "tokens=1,2" %%M in ("!TLENGTH! !KLENGTH!") do (
set "DONE= !LINE:~,%%M!"
set "TEST=!LINE:~%%M,%%N!"
)
set "CHAR=!DONE:~-1!" & set "CHAR=!CHAR: = !"
set "DONE=!DONE:~1!"
if "!TEST!"=="!KEYW!" (
if "!CHAR!"==" " (
set "DONE=!DONE!!KEYW!"
set "TEST=!SEEK!"
set /A TLENGTH=PLENGTH+3
for /F %%N in ("!TLENGTH!") do (
set "TEST=!SEEK:~,%%N!" & set "SEEK=!SEEK:~%%N!"
)
echo(!TEST! | > nul findstr /R /C:^^^"^^^^^^^=\"!PATTERN!\"^^^ $^^^"
if not ErrorLevel 1 (
for /F "tokens=1,2 delims=." %%S in ("!TEST:~1!") do (
set "HHMMSS=%%~S" & set "MS=%%~T"
set /A "FF=%FORMULA%"
set "FF=0000!FF!" & set "FF=!FF:~-%PADDING%!"
)
set "COLL=!COLL!!DONE!="!HHMMSS!:!FF!"" & set "LINE=!SEEK!"
) else (
set "COLL=!COLL!!DONE!!TEST!" & set "LINE=!SEEK!"
)
) else (
set "COLL=!COLL!!DONE!!TEST!" & set "LINE=!SEEK!"
)
) else (
set "COLL=!COLL!!DONE!!TEST!" & set "LINE=!SEEK!"
)
) else (
set "COLL=!COLL!!LINE!" & set "LINE="
)
) else (
set "COLL=!COLL!!LINE!" & set "LINE="
)
goto :LOOP
)
if defined COLL (
for /F delims^=^ eol^= %%E in ("!COLL!") do (
endlocal
set "%~1=%%E"
setlocal EnableDelayedExpansion
)
) else (
endlocal
set "%~1="
setlocal EnableDelayedExpansion
)
endlocal
exit /B
:LEN rtn_length ref_string
setlocal EnableDelayedExpansion
set "STR=!%~2!"
if not defined STR (set /A LEN=0) else (set /A LEN=1)
for %%L in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
if defined STR (
set "INT=!STR:~%%L!"
if not "!INT!"=="" set /A LEN+=%%L & set "STR=!INT!"
)
)
endlocal & set "%~1=%LEN%"
exit /B
Supposing the script is saved as convert-ms-to-frames.bat, the input file is called sample.xml and the output file is called return.xml, use the following command line:
convert-ms-to-frames.bat "sample.xml" > "return.xml"
Simply remove the > "return.xml" part to display the output data on the console for testing.
Supposing the input file sample.xml contains the following data...:
<?xml version="1.0"?>
<Events>
<Event In="00:00:20.650" Out="00:00:22.970" />
<Event In="00:00:23.050" Out="00:00:26.300" />
</Events>
...the output file return.xml will contain the data below:
<?xml version="1.0"?>
<Events>
<Event In="00:00:20:16" Out="00:00:22:24" />
<Event In="00:00:23:01" Out="00:00:26:07" />
</Events>

Answer 4

Using bc
$ ms="650"
$ ff=$(echo ${ms} "*0.025/1" |bc)
$ echo $ff
16
I leave to you when the result is less then 10 to add the additonal "0"