Windows batch using 2 lists in tandem - batch-file

Question

I'm writing a batch to kill several processes if they are running and subsequently delete the files whether they were running or not. I'm very new to this so please bear with the horrible script.
#echo off
echo deleting files...
tasklist /FI "IMAGENAME eq file1.exe" | find /I /N "file1.exe"> nul 2>&1
if errorlevel 1 (
echo file1.exe is not running
goto :delete
) else (
taskkill /F /IM file1.exe> nul 2>&1
if errorlevel 1 (
echo Killing process file1.exe... Failed!
) else (
goto :delete
)
)
:delete
ren c:\file1.exe c:\tmp.tmp> nul 2>&1
if errorlevel 1 (
echo Deleting file1.exe... Access Denied!
) else (
del /q /f "C:\tmp.tmp"> nul 2>&1
echo Deleting file1.exe... Success!
)
rather than doing this for all 8 files, i'd like to use two lists for filenames and filepaths and run them both through a for loop at the same time. unfortunately i can't find much info online on how to loop through 2 lists in tandem and the following script would run into obvious problems:
for %%f in (file1 file2 file3) do
for %%p in (path1 path2 path3) do (
taskkill %f etc
del %p etc
)
some help would be appreciated!

Answer 1

You only need a single FOR loop with the full paths, and then use the %~nx modifiers to get the name only.
Here is the pseudo code:
for %%F in ("path1\file1" "path2\file2" "path3\file3") do (
taskkill %%~nxF
del %%F
)
For more information about the modifiers, use help for or for /? from the command line, and look toward the bottom of the help.
But there are times when you want to process lists of paired values. This can be done easily enough with two loops. The first loop iterates delimited pairs, and the 2nd FOR /F loop parses out each value from the pair. You just need to choose a delimiter that never appears in a value.
Using space delimiters:
for %%A in ("val1a val1b" "val2a val2b" "val3a val3b") do (
for /f "tokens=1,2" %%B in ("%%~A") do (
echo value1 = %%B
echo value2 = %%C
echo(
)
)
Using pipe delimiters: Note how you can span multiple lines for improved readability
for %%A in (
"val 1a|val 1b"
"val 2a|val 2b"
"val 3a|val 3b"
) do for /f "delims=| tokens=1,2" %%B in ("%%~A") do (
echo value1 = %%B
echo value2 = %%C
echo(
)