Sequence number in JSON array for powerbi - arrays

Question

I get the below data from the 'World of Tanks' API and would like to show it in Power BI. The challenge is the arrays I get for damage and piercing_power. I would like to show 3 rows from this data with the damage and piercing power next to each other, how would I do that?
"4": {
"nation_i18n": "U.S.S.R.",
"name": "_76mm_L-11",
"price_gold": 0,
"level": 4,
"damage": [
110,
110,
156
],
"nation": "ussr",
"rate": 12.27,
"price_credit": 25990,
"tanks": [
1,
2049
],
"module_id": 4,
"name_i18n": "76 mm L-11",
"piercing_power": [
68,
75,
38
],
"turrets": [
259,
3,
3843
]
}

Answer 1

After converting to a Table and Expanding, I would Add a Column and use the Table.FromColumns function to construct a nested table on each row from the damage and piercing_power list-type columns. Here's my attempt at that:
= Table.FromColumns ( { [damage] , [piercing_power] } , { "damage" , "piercing_power" } )
That table can then be expanded to get your required output.
Here's my full script:
let
Source = Json.Document(File.Contents("C:\Users\mikeh\Downloads\WOT.json")),
#"Converted to Table" = Record.ToTable(Source),
#"Expanded Value" = Table.ExpandRecordColumn(#"Converted to Table", "Value", {"nation_i18n", "name", "price_gold", "level", "damage", "nation", "rate", "price_credit", "tanks", "module_id", "name_i18n", "piercing_power", "turrets"}, {"nation_i18n", "name", "price_gold", "level", "damage", "nation", "rate", "price_credit", "tanks", "module_id", "name_i18n", "piercing_power", "turrets"}),
#"Added MyTable" = Table.AddColumn(#"Expanded Value", "MyTable", each Table.FromColumns ( { [damage] , [piercing_power] } , { "damage" , "piercing_power" } )),
#"Expanded MyTable" = Table.ExpandTableColumn(#"Added MyTable", "MyTable", {"damage", "piercing_power"}, {"damage.1", "piercing_power.1"}),
#"Renamed Columns" = Table.RenameColumns(#"Expanded MyTable",{{"name", "name.1"}})
in
#"Renamed Columns"