file search across partitions in batch files - file

Question

I am trying to create a batch file that will return a file location, including partition (or drive) so I can use it for more manipulation in that batch file.
The file name is known but the partition and directory are not known. Is that possible?

Answer 1

You can try something like that :
#echo off
Title Searching for file by name
Mode con cols=75 lines=3
cls & color 0A
Set SearchResult=SearchResult.txt
If Exist %SearchResult% Del %SearchResult%
echo(
set /P "FileName=Type the file name for looking for = "
Setlocal EnableDelayedExpansion
for /f "tokens=2" %%i in ('wmic logicaldisk where "drivetype=3" ^|find /i ":"') do (
Set MyDrive=%%i
echo( & cls
echo( & echo Please Wait for moment .... Searching for "%FileName%" on "!MyDrive!\"
#where /r !MyDrive!\ "%FileName%" >> %SearchResult%
)
Start %SearchResult%

Answer 2

The following script -- let us call it findfile.bat -- searches for a file with the name given as a command line argument (for instance, findfile.bat "lostfile.txt") on local disks and network drives as an example:
#echo off
for /F "skip=1" %%I in (
'wmic LOGICALDISK WHERE ^( ^
DriveType^=3 OR^
DriveType^=4^
^) GET DeviceID'
) do (
for /F "delims=" %%J in ("%%I") do (
2> nul where /R %%J\ "%~1"
)
)
The wmic command is used to retrieve the drives available on the current system. In the example there are two DriveType values allowed: 3, meaning local disks, and 4, meaning network drives. You can adapt the filter as you like -- reference site Win32_LogicalDisk class for all the possible values. To not filter any drive types, simply remove the entire WHERE clause and use the remaining wmic command line wmic LOGICALDISK GET DeviceID instead.