batch to vbs for loop translation [closed] - batch-file

Question

Closed. This question needs details or clarity. It is not currently accepting answers.
Want to improve this question? Add details and clarify the problem by editing this post.
Closed 6 years ago.
Improve this question
I have directory with executable files like
tool-7.0.20.exe
tool-7.0.23.exe
tool-7.0.24.exe
tool-7.0.25.exe
tool-7.0.26.exe
and I'm using a for loop in a batch file to get the latest version in a variable and run it
I need to convert this for loop to a vbs script
for /f "tokens=*" %%a in ('dir /ON /B %~dps0tool*.exe') do set latest=%%a
then run the latest file variable with objShell.Exec or objShell.Run
Thanks

Answer 1

You can do it using Shell.Application ActiveX:
Option Explicit
Const SHCONTF_NONFOLDERS = &H40
Const SHCONTF_INCLUDEHIDDEN = &H80
Dim strCurDir, strPath, objWshShell
strCurDir = Left(WScript.ScriptFullName, InStrRev(WScript.ScriptFullName, "\"))
With CreateObject("Shell.Application").Namespace(strCurDir).Items
.Filter SHCONTF_NONFOLDERS + SHCONTF_INCLUDEHIDDEN, "tool-*.exe"
strPath = .Item(.Count - 1).Path
End With
WScript.Echo strPath
Set objWshShell = CreateObject("WScript.Shell")
objWshShell.Run strPath
Or by retrieving files with Scripting.FileSystemObject and filtering them with VBScript.RegExp:
Option Explicit
Dim strFiles, objMatches, strPath, objWshShell
With CreateObject("Scripting.FileSystemObject")
With .GetFolder(.GetParentFolderName(WScript.ScriptFullName))
strFiles = ""
For Each strPath In .Files
strFiles = strFiles & strPath & vbCrLf
Next
End With
End With
With CreateObject("VBScript.RegExp")
.Global = True
.MultiLine = True
.IgnoreCase = True
.Pattern = "^.+?\\tool-.*?\.exe$"
Set objMatches = .Execute(strFiles)
strPath = objMatches(objMatches.Count - 1).Value
End With
WScript.Echo strPath
Set objWshShell = CreateObject("WScript.Shell")
objWshShell.Run strPath
Or even running your cmd code (cmd instructions were slightly modified to be executed in one liner command line mode):
Option Explicit
Dim objWshShell, strCurDir, strCmd, strRes
Set objWshShell = CreateObject("WScript.Shell")
strCurDir = Left(WScript.ScriptFullName, InStrRev(WScript.ScriptFullName, "\"))
strCmd = "%comspec% /v /c (for /f %a in ('dir /ON /B /S " & strCurDir & "tool-*.exe') do #set latest=%a)&echo !latest!"
strRes = objWshShell.Exec(strCmd).StdOut.ReadAll()
strRes = Replace(strRes, vbCrLf, "")
WScript.Echo strRes
objWshShell.Run strRes
If you want to get rid of the flashing console window, the above code may be modified as follows to launch second instance of the script in hidden mode, and execute cmd instructions within it:
Option Explicit
Dim objWshShell, strCurDir, strCmd, strRes, objWnd, objParent, strSignature
Set objWshShell = CreateObject("WScript.Shell")
If WScript.Arguments.Named.Exists("signature") Then WshShellExecCmd
strCurDir = Left(WScript.ScriptFullName, InStrRev(WScript.ScriptFullName, "\"))
strCmd = "%comspec% /v /c (for /f %a in ('dir /ON /B /S " & strCurDir & "tool-*.exe') do #set latest=%a)&echo !latest!"
RunCScriptHidden
strRes = Replace(strRes, vbCrLf, "")
WScript.Echo strRes
objWshShell.Run strRes
Sub RunCScriptHidden()
strSignature = Left(CreateObject("Scriptlet.TypeLib").Guid, 38)
GetObject("new:{C08AFD90-F2A1-11D1-8455-00A0C91F3880}").putProperty strSignature, Me
objWshShell.Run ("""" & Replace(LCase(WScript.FullName), "wscript", "cscript") & """ //nologo """ & WScript.ScriptFullName & """ ""/signature:" & strSignature & """"), 0, True
End Sub
Sub WshShellExecCmd()
For Each objWnd In CreateObject("Shell.Application").Windows
If IsObject(objWnd.getProperty(WScript.Arguments.Named("signature"))) Then Exit For
Next
Set objParent = objWnd.getProperty(WScript.Arguments.Named("signature"))
objWnd.Quit
objParent.strRes = objWshShell.Exec(objParent.strCmd).StdOut.ReadAll()
WScript.Quit
End Sub