WorksheetFunction.Small ERROR? - arrays

Question

I have the following code:
Option Explicit
Dim ArrTest() As Variant
Dim ArrSmall() As Variant
Dim ArrTemp() As Variant
Dim k As Integer
Dim i As Integer
Sub test()
ReDim ArrTest(10, 2)
ReDim ArrSmall(10, 2)
ReDim ArrTemp(10, 1)
ArrTest = Range("A1:B10")
For k = 1 To 2
For i = 1 To 10
ArrTemp(i, 1) = ArrTest(i, k)
ArrSmall(i, k) = WorksheetFunction.Small(ArrTemp, i)
Cells(i, k + 10) = ArrSmall(i, k)
Next i
Next k
End Sub
Range("A1:B10") is an arbitrary range of numbers which should be ordered from small to big according to the WorksheetFunction.Small. With a single column this works perfectly fine. However, when applied as such (with a loop) the function copies values from the original range and the output is wrong.
Please try for yourself in an Excel sheet and tell me what I'm doing wrong or the function is wrong?
Thanks.
EDIT: I have it working with Application.Index which works in this particular example. See:
Sub test()
ReDim ArrTest(10, 2)
ReDim ArrSmall(10, 2)
ReDim ArrTemp(10, 1)
ArrTest = Range("A1:B10")
For k = 1 To 2
For i = 1 To 10
ArrTemp = Application.Index(ArrTest, 0, k)
'ArrTemp(i, 1) = ArrTest(i, 1)
ArrSmall(i, 1) = WorksheetFunction.Small(ArrTemp, i)
Cells(i, k + 10) = ArrSmall(i, 1)
Next i
Next k
End Sub
Which works fine. But when I apply the exact same logic to my original code it gives me the 1004 error: unable to get Small property. I have no clue.

Answer 1

to leave your code as much as it was (first example) works perfect:
Option Explicit
Dim ArrTest() As Variant
Dim ArrSmall() As Variant
Dim ArrTemp() As Variant
Dim k As Integer
Dim i As Integer
Sub test()
ReDim ArrTest(10, 2) '*
ReDim ArrSmall(10, 2)
ReDim ArrTemp(10, 1)
ArrTest = Range("A1:B10")
For k = 1 To 2
For i = 1 To 10
ArrTemp(i, 1) = ArrTest(i, k)
Next i
For i = 1 To 10
ArrSmall(i, k) = WorksheetFunction.Small(ArrTemp, i)
Cells(i, k + 10) = ArrSmall(i, k)
Next i
Next k
End Sub
No errors or whatever at all...
the '* just is not used at all ArrTest = Range("A1:B10") will set automatically all ranges... still the ranges would be to big for the other ranges...
I get exactly the same output like in your second example...
EDIT:
If you want to sort the full range (not every column itself) then you need something like:
Option Explicit
Dim ArrTest() As Variant
Dim ArrSmall() As Variant
Dim ArrTemp() As Variant
Dim k As Integer
Dim i As Integer
Sub test()
ReDim ArrTest(10, 2)
ReDim ArrSmall(10, 2)
ReDim ArrTemp(10, 1)
ArrTest = Range("A1:B10")
For k = 1 To UBound(ArrTest, 2)
For i = 1 To UBound(ArrTest)
ArrSmall(i, k) = WorksheetFunction.Small(ArrTest, i + ((k - 1) * UBound(ArrTest)))
Cells(i, k + 10) = ArrSmall(i, k)
Next i
Next k
End Sub
Still I beleave the first code should do what you desire ;)

Answer 2

The way you are using the ReDim statement is creating too many elements in the arrays. Try using the LBound function and UBound function after setting the worksheet range values into the first variant array.
Option Explicit
Sub test()
Dim ArrTest() As Variant, ArrSmall() As Variant, ArrTemp() As Variant
Dim k As Long, i As Long
ReDim ArrTest(10, 2) '<~~ unnecessary if writing values from the worksheet
Debug.Print LBound(ArrTest, 1) & ":" & UBound(ArrTest, 1)
Debug.Print LBound(ArrTest, 2) & ":" & UBound(ArrTest, 2)
'^^ this results in 0:10, 0:2. Not 1:10, 1:2
ArrTest = Range("A1:B10").Value2 '<~~ make sure you are putting values in
Debug.Print LBound(ArrTest, 1) & ":" & UBound(ArrTest, 1)
Debug.Print LBound(ArrTest, 2) & ":" & UBound(ArrTest, 2)
'^^ this results in 1:10, 1:2.
ReDim ArrSmall(LBound(ArrTest, 1) To UBound(ArrTest, 1), _
LBound(ArrTest, 2) To UBound(ArrTest, 2))
ReDim ArrTemp(LBound(ArrTest, 1) To UBound(ArrTest, 1), 1 To 1)
For k = LBound(ArrTest, 2) To UBound(ArrTest, 2)
For i = LBound(ArrTest, 1) To UBound(ArrTest, 1)
ArrTemp(i, 1) = ArrTest(i, k)
ArrSmall(i, k) = WorksheetFunction.Small(ArrTemp, i)
Cells(i, k + 10) = ArrSmall(i, k)
Next i
Next k
End Sub
    

Answer 3

It depends on how you write the code.
Sub test()
With Range("A1:B10")
For Each Column In .Columns
x = x + 1
For i = 1 To Column.Cells.Count
Cells(i, 10 + x).Value = Application.Small(Column, i)
Next i
Next Column
End With
End Sub
Edit:
Although this would work with Range my goal is to extract the columns
from an array without having to return to a Sheet. I think this is
limited somehow
Adding Array approach too..
Sub test()
Dim vArr As Variant, varrTemp As Variant
vArr = Application.Transpose(Range("A1:B10").Value)
For i = LBound(vArr, 1) To UBound(vArr, 1)
varrTemp = Application.Index(Application.Transpose(vArr), , i)
For x = LBound(varrTemp) To UBound(varrTemp)
Cells(x, 10 + i).Value = Application.Small(varrTemp, x)
Next x
Next i
End Sub