Subscript out of range on Class - arrays

Question

I created this class named "CInventory". This class generates an array of "valid data". To see this array on a range I tried to "paste" the array to see the result. I get a "subscript out of range". The error appears on line 6 (cinv.AllocateInventoryData) of the simple module.
This is the Class Module called CInventory:
Option Explicit
Private Path As String
Private TextFileNumber As Integer
Private InventoryData() As String
Public Property Get GetInventoryData() As String
GetInventoryData = InventoryData
End Property
Public Property Let SPath(Text As String)
Path = Text
End Property
Public Sub AllocateInventoryData()
Dim ColumnArray() As String
TextFileNumber = FreeFile
Dim FileContent As String
Dim i, j As Integer
j = 0
Open Path For Input As TextFileNumber
FileContent = Input(LOF(TextFileNumber), TextFileNumber)
Close TextFileNumber
ColumnArray() = Split(FileContent, vbCrLf)
For i = LBound(ColumnArray) To UBound(ColumnArray)
If IsValidRow(ColumnArray(i)) Then
ReDim Preserve InventoryData(j, 4)
InventoryData(j, 0) = Left(ColumnArray(i), 8)
InventoryData(j, 1) = Trim(Mid(ColumnArray(i), 10, 8))
InventoryData(j, 2) = Trim(Mid(ColumnArray(i), 19, 18))
InventoryData(j, 3) = Trim(Mid(ColumnArray(i), 57, 2))
InventoryData(j, 4) = Trim(Mid(ColumnArray(i), 60, 12))
j = j + 1
End If
Next i
End Sub
Private Function IsValidRow(Text As String) As Boolean
If Left(Text, 6) = "iclorp" Or Left(Text, 5) = "Page:" Or Len(Trim(Text)) < 3 _
Or Left(Text, 4) = "Site" Or Left(Text, 6) = "------" Then
IsValidRow = False
Else
IsValidRow = True
End If
End Function
And this is the Module from which I call the class CInventory (simple module)
Option Explicit
Sub example()
Dim cinv As CInventory
Set cinv = New CInventory
cinv.SPath = "H:\Joel\invent_2.prn"
cinv.AllocateInventoryData '<-- here appears the error
Worksheets(1).Cells(1, 1) = cinv.GetInventoryData
End Sub

Answer 1

here is the answer!, after a while but it works as I wanted
The class module 'CInventory'
Option Explicit
Private Path As String
Private TextFileNumber As Integer
Private InventoryData() As String
Private UBoundInventoryDataRows As Integer
Private UBoundInventoryDataColumns As Integer
Public Property Get GetUBoundInventoryDataRows() As Integer
GetUBoundInventoryDataRows = UBoundInventoryDataRows
End Property
Public Property Get GetUBoundInventoryDataColumns() As Integer
GetUBoundInventoryDataColumns = UBoundInventoryDataColumns
End Property
Public Property Get GetInventoryData() As String()
GetInventoryData = InventoryData
End Property
Public Property Let SPath(Text As String)
Path = Text
End Property
Public Sub AllocateInventoryData()
Dim tempArray() As String
Dim TempLineArray() As String
Dim ColumnArray() As String
Dim FileContent As String
Dim i, j As Integer
TextFileNumber = FreeFile
j = 0
Open Path For Input As TextFileNumber
FileContent = Input(LOF(TextFileNumber), TextFileNumber)
Close TextFileNumber
ColumnArray() = Split(FileContent, vbCrLf)
For i = LBound(ColumnArray) To UBound(ColumnArray)
If LCase(Left(Trim(ColumnArray(i)), 2)) = "mx" Then
ReDim Preserve tempArray(j)
tempArray(j) = Trim(Left(ColumnArray(i), 9)) & ":" & _
Trim(Mid(ColumnArray(i), 10, 9)) & ":" & _
Trim(Mid(ColumnArray(i), 19, 18)) & ":" & _
Trim(Mid(ColumnArray(i), 37, 20)) & ":" & _
Trim(Mid(ColumnArray(i), 57, 4)) & ":" & _
Trim(Mid(ColumnArray(i), 61, 12)) & ":" & _
Trim(Mid(ColumnArray(i), 73, 9)) & ":" & _
Trim(Mid(ColumnArray(i), 82, 9)) & ":" & _
Trim(Mid(ColumnArray(i), 91, 8)) & ":" & _
Trim(Mid(ColumnArray(i), 99, 6)) & ":" & _
Trim(Mid(ColumnArray(i), 105, 9)) & ":" & _
Trim(Mid(ColumnArray(i), 114, 6)) & ":" & _
Trim(Mid(ColumnArray(i), 120, 4)) & ":" & _
Trim(Mid(ColumnArray(i), 124, 3))
j = j + 1
End If
Next i
'in a normal module we shall transpose this next array.
'I did this in this way because of redim agreement
' "the last dimension only could be re-dimensioned"
ReDim InventoryData(13, UBound(tempArray))
For i = LBound(tempArray) To 13
For j = LBound(tempArray) To UBound(tempArray)
TempLineArray = Split(tempArray(j), ":")
InventoryData(i, j) = TempLineArray(i)
Next j
Next i
UBoundInventoryDataRows = UBound(InventoryData, 1)
UBoundInventoryDataColumns = UBound(InventoryData, 2)
End Sub
and here the simple module
Option Explicit
Sub example()
Dim cinv As CInventory
Set cinv = New CInventory
cinv.SPath = "H:\Joel\invent_2.prn"
cinv.AllocateInventoryData
Dim row, column As Integer
row = cinv.GetUBoundInventoryDataRows
column = cinv.GetUBoundInventoryDataColumns
Dim Destination As Range
Set Destination = Range("a1")
Destination.Resize(column, row).Value = Application.Transpose(cinv.GetInventoryData)
Set cinv = Nothing
End Sub