Bat file to remove last character in a file? - batch-file

Question

I'm trying to figure this out but I think I'm way off. This is what I found on the interwebs:
copy /A data.js data.js.new /B > nul
del data.js
ren data.js.new data.js
Somehow, it does nothing.
How can I create a bat file to remove the last character in a file (the character is a comma, if that matters)?

Answer 1

#echo off
setlocal EnableDelayedExpansion
rem Count the number of lines, minus one
for /F %%a in ('find /C /V "" ^< data.js') do set /A lines=%%a-1
< data.js (
rem Copy number-1 lines
for /L %%i in (1,1,%lines%) do (
set "line="
set /P "line="
echo(!line!
)
rem Process last line
set /P "line="
echo(!line:~0,-1!
) > data.js.new
move /Y data.js.new data.js

Answer 2

Perhaps more complicated than it needs to be, but I wanted to avoid delayed expansion clobbering exclamation marks in your file contents while preserving blank lines. Batch isn't the best language for this sort of thing. If I were you, I'd just use PowerShell or JScript and substring(0, data.length - 1) or similar.
Anyway, here is a pure batch solution:
#echo off
setlocal
set "file=test.txt"
set "idx=0"
for /f "delims=" %%I in ('findstr /n "^" "%file%"') do (
set /a idx += 1
setlocal enabledelayedexpansion
for %%x in (!idx!) do endlocal & set "line[%%x]=%%I"
)
setlocal enabledelayedexpansion
for %%I in ("!line[%idx%]!") do endlocal & set "lastline=%%~I"
set "line[%idx%]=%lastline:~0,-1%"
setlocal enabledelayedexpansion
>"%file%" (
for /L %%I in (1,1,%idx%) do echo(!line[%%I]:*:=!
)
Here's a batch snippet that abuses PowerShell to accomplish the same task.
>out.txt powershell "$c = (gc test.txt) -join \"`n\"; $c.substring(0, $c.length - 1)"
move /y out.txt test.txt >NUL
Or here's a hybrid batch + JScript solution. Save it with a .bat extension.
#if (#CodeSection == #Batch) #then
#echo off & setlocal
>out.txt (
cscript /nologo /e:Jscript "%~f0" < test.txt
)
move /y out.txt test.txt >NUL
goto :EOF
#end // end batch / begin JScript hybrid chimera
var data = WSH.StdIn.ReadAll();
WSH.StdOut.Write(data.substring(0, data.length - 1));

Answer 3

The following batch file removes the last character from the file data.js. The advantage of this approach is, that there is only a single loop, for the sake of performance. The idea behind it is to walk though the lines of the file and output each one, but delayed by one iteration, so the last line can be handled separately after the loop:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
> "data.js.new" (
for /F "delims=" %%L in ('
findstr /N /R "^" "data.js"
') do (
setlocal EnableDelayedExpansion
if defined PREV (
set "PREV=!PREV:*:=!"
echo(!PREV!
)
endlocal
set "PREV=%%L"
)
setlocal EnableDelayedExpansion
set "PREV=!PREV:*:=!"
if defined PREV (
echo(!PREV:~,-1!
)
endlocal
)
endlocal
> nul move /Y "data.js.new" "data.js"
The for /F loop does not iterate through the lines directly, but through the output of findstr /N /R "^", which returns all lines prefixed by the line number and :, even empty lines get prefixed, so no line appears empty to for /F, which would ignore such otherwise. To retrieve the original line in the loop, everything up to the first : is stripped off.
The delayed environment variable expansion (by setlocal/endlocal; see also set /?) is toggled in order for the script not not lose any special characters and/or not to crash on them.