Loop Through Files - Use Directory Name - batch-file

Question

TL;DR: I want to be able to loop through each file in a folder / subfolders and use the directory name the file is in, in each loop.
If I had a directory structure like:
-- Main
----- Printer 1
------- File 1
------- File 2
----- Printer 2
------- File 1
Ideally what I need to do is loop through 'Main' and get the files in 'Printer 1' and 'Printer 2', but I need to use the name of the printer directories in the script. Eg:
At the moment I'm using the below:
:loop
for /f %%f in ('dir /b D:\FireflyWebApps\www\apps\label\resources\labels_to_print\') do (
"C:/Program Files/Java/jre1.8.0_66/bin/java" -jar C:\test\pdfbox.jar PrintPDF -silentPrint D:\FireflyWebApps\www\apps\label\resources\labels_to_print\%%f
del D:\FireflyWebApps\www\apps\label\resources\labels_to_print\%%f
)
ping localhost -n 5 > nul
goto loop
Which works well, it loops trough the directory and prints the PDF's, but I need this to work with multiple printers. I know it's not an ideal solution, but I need to change the default printer to the 'Printer X' file names ( so I'll store the printer name as the folder, then run the change default printer command using it ).
How can I use the folder name the file is in, in the batch script?
Possible Solution
The below script will cd to the directory, loop through the directories in it, performing the inner loop on each one. Before it runs the inner loop, it gets the directory name and sets the default printer. I had to do an IF == 1 as it's a printer and I can't use '\' in folder name.
cd C:\test
for /D %%d in (*) do (
IF "%%d" == "1" (
RUNDLL32 PRINTUI.DLL,PrintUIEntry /y /n "\\192.168.102.131\lp1"
)
for /f %%f in ('dir /b C:\test\%%d') do (
echo %%f
)
)
pause

Answer 1

Here is my solution to your problem of getting folder name of a file:
#echo off
setlocal EnableDelayedExpansion
:loop
for /F "delims=" %%F in ('dir /A-D /B /S "D:\FireflyWebApps\www\apps\label\resources\labels_to_print\*" 2^>nul') do (
set "FolderPath=%%~dpF"
set "FolderPath=!FolderPath:~0,-1!"
for %%P in ("!FolderPath!") do (
echo Printer name is: %%~nxP
"%ProgramFiles%\Java\jre1.8.0_66\bin\java.exe" -jar C:\test\pdfbox.jar PrintPDF -silentPrint "%%F"
del "%%F"
)
)
ping localhost -n 5 > nul
goto loop
Command DIR with the options /A-D /B /S returns a list of all file names with full path without double quotes from specified directory and all subdirectories.
Drive and path with a backslash at end is assigned to an environment variable. The backslash at end must be removed which is done with a string substitution copying folder path string with exception of last character.
This folder path now without backslash at end is used in a second FOR loop which of course has always only 1 loop run to get with %%~nxP the name of the folder in which current file is stored which is the printer name.
The batch file as is just outputs the printer name.
Delayed variable expansion must be used here because of FolderPath being defined within a block.
Command DIR outputs an error message if it can't find any file in any directory. This error message is redirected from stderr to nul as of no interest for this batch file running continuously.
An alternate method without using command DIR working also for Unicode file names (© Joey):
#echo off
setlocal EnableDelayedExpansion
:loop
for /R "D:\FireflyWebApps\www\apps\label\resources\labels_to_print" %%F in (*) do (
set "FolderPath=%%~dpF"
set "FolderPath=!FolderPath:~0,-1!"
for %%P in ("!FolderPath!") do (
echo Printer name is: %%~nxP
"%ProgramFiles%\Java\jre1.8.0_66\bin\java.exe" -jar C:\test\pdfbox.jar PrintPDF -silentPrint "%%F"
del "%%F"
)
)
ping localhost -n 5 > nul
goto loop
For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.
dir /?
echo /?
for /?
goto /?
ping /?
set /?
setlocal /?