extracting specified match from find/findstr results - batch-file

Question

so this is related to
compare #defines in two C files using a batch file
but different:
System is Win 7(no Linux commands).
I have 2 files with content like
Fil1.c
#define V1 6
...
int Var[V1] ;
******************************
Fil2.c
ifdef USE_V1
#define V1 6
#else
#define V1 5
#endif
I need to compare V1 with V2 in a batch file, and throw an error if they don't match.
The solution
for /f "tokens=3" %%A in ('find "#define V1" "Fil1.c"') DO (
set Var1=%%A)
for /f "tokens=3" %%A in ('find "#define V1" "Fil2.c") DO (
set Var2=%%A)
if "%VAR1%" neq "%VAR2%" goto Error2
works well when USE_V1 preprocessor is set to 0.However, when set to 1, V1 in File2.c still reads value 5 ,as findtsr finds 2 occurrences of #define , and gets the last one.
Is there a way for findstr to read only 1st or second occurrence of #define ( which I can specify based on GOTO, wherein I read USE_V1 defined in VS project xml and decide which findstr I need to execute, that which reads first occurence or that which reads second one.)
For example, I can try :
TYPE nul >%tmpPth%
findstr /N /C:"#define V1" "Fil2.c" > %tmpPth%
writes following to tmp.txt
46:#define V1 6
49:#define V1 5
but then, I should be able to read token 3 using find/findstr either from first line or second line.
I have seen solutions on stack overflow ([Batch file to output last line of findstr2) that read/print only last occurrence of
search string but I need solution where I can probably choose which line out of the matched results I need to re-run the search for, and not just print but extract tokens out of the line result.
Update: I was able to do following:
set USE_V1="0"
for /f "delims= " %%A in ('findstr /C:"USE_V1" %VCProjPath%') DO (
set USE_V1="1")
set Var3="0"
for /f "tokens=3" %%A in ('find "#define V1" "Fil1.c"') DO (
set Var1=%%A)
if %USE_V1% equ "1" goto USE_V1_USED
for /f "tokens=3" %%A in ('find "#define V1" "Fil2.c"') DO (
set Var2=%%A)
goto MOVEON
:USE_V1_USED
TYPE nul >%tmpPth1%
findstr /C:"#define V1" "Fil2.c" > %tmpPth1%
for /f "tokens=3 delims= " %%A in ('findstr /C:"#define V1" %tmpPth1%') Do (
set Var2=%%A
if "%VAR2%" neq "%VAR3%" goto MOVEON
)
:MOVEON
if "%VAR1%" neq "%VAR2%" goto Error0
The problem i face is that supposing #define V1 match in File1.c and File2.c and
findstr /C:"#define V1" "Fil2.c" > %tmpPth1%
writes to tmp file as
#define NUMATTR1MEMS 6
#define NUMATTR1MEMS 5
which when read using
for /f "tokens=3 delims= " %%A in ('findstr /C:"#define V1" %tmpPth1%') Do (
set Var2=%%A
if "%VAR2%" neq "%VAR3%" goto MOVEON
)
give op with %VAR2% from both files as
As seen, the second value corresponding to first line read from temp file has extra blank spaces ,so, even though values match numerically, the command to match these fails.
So, is there a way to redirect findstr op to text file without extra blanks at line endings?
Thanks
sedy

Answer 1

Let us go through the quite huge amount of tasks step by step...
At first, let's concentrate on retrieving the definition of USE_V1. As far as I understand, you have a project definition file that contains USE_V1; if USE_V1 is present in that file literally, it is considered as defined, otherwise not.
The following code snippet seeks USE_V1 and sets %VVALGLOB% if found (I place a couple of set statements for initially setting up everything at one place for convenience):
#echo off
rem global project definitions
set FILEPROJ="\path\to\project\file"
set VNAMGLOB=USE_V1
set VVALGLOB=
rem seek %VNAMGLOB% in project file and set %VVALGLOB% if found
for /F %%A in ('findstr /L /I "%VNAMGLOB%" %FILEPROJ%') do (
set VVALGLOB=1
)
The next thing is to extract the value of variable V1 from Fil1.c. Here I assume that always the first occurrence of the #define directive is the one to regard:
rem definition of data of file 1
set FILE1="Fil1.c"
set VNAM1=V1
set VVAL1=
rem processing file 1, always take FIRST occurrence of "#define"
for /F "tokens=3" %%A in ('findstr /R /I /C:"^ *#define *%VAR1%" %FILE1%') do (
set /A "VVAL1=%%A"
goto :CONT1
)
:CONT1
I used set /A rather than set here to treat the gathered value as a number.
Now let's extract the value of V1 from Fil2.c conditionally: Here I check whether or not %VVALGLOB% is defined (remember it is when USE_V1 has been defined); if it is, the first occurrence of the #define directive is taken; otherwise, the last one is checked:
rem definition of data of file 2
set FILE2="Fil2.c"
set VNAM2=V1
set VVAL2=
rem processing file 2, take FIRST OR LAST occurrence of "#define" conditionally
for /F "tokens=3" %%A in ('findstr /R /I /C:"^ *#define *%VAR2%" %FILE2%') do (
set /A "VVAL2=%%A"
if defined VVALGLOB goto :CONT2
)
:CONT2
Alternatively, if only the first or second occurrence of #define is relevant, which is the case when there are more than two such directives, the for /F portion of the code must be replaced by the following lines:
rem processing file 2, take FIRST OR SECOND occurrence of "#define" conditionally
for /F "tokens=3" %%A in ('findstr /R /I /C:"^ *#define *%VAR2%" %FILE2%') do (
if defined VVAL2 (
set "VVAL2=%%A"
goto :CONT2
)
set /A "VVAL2=%%A"
if defined VVALGLOB goto :CONT2
)
:CONT2
Having extracted the correct values from the two files, we need to compare them. For this, I assumed that they must not equal zero to be considered as valid. If one or both are zero, or if they are not equal, a message is thrown and the batch script is exited; otherwise, the batch script continues executing:
rem compare found values for equality in a NUMERICAL manner (both != 0)
if %VVAL1% neq 0 if %VVAL2% neq 0 if %VVAL1% equ %VVAL2% goto :MOVEON
echo They don't match! & exit /B
:MOVEON
rem ...
Since there are no double-quotes around all the values, a numerical comparison is done rather than a string comparison. Hence any trailing spaces do not matter.
Notes:
I added the /I switch to all findstr occurrences in order to do case-insensitive searches. However, if all the variable names like V1 are case-sensitive, just remove it.
For searching the #define directive, I established a regular expression rather than a literal search string, telling findstr to allow leading spaces and more than one space between the keyword and the variable name.
As already mentioned in the above I treat variable (V1) values of zero as invalid to avoid trouble with values other than integers. For instance, if V1 is a string abc in your file, the batch script reads 0.