Windows batch: using goto in a loop - batch-file

Question

The following code runs a continuous loop, which increments the variable counter. When counter reaches 10, it should call the set_varibles routine, and then continue in the loop from the place set_variables was called. However, the goto does not work. What is wrong, and is there a better solution? Thanks
#echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
:set_variables
SET t=ooo
:my_loop
set /a counter=0
for /L %%n in (1,0,10) do (
echo !counter!
set /a counter=counter+1
if !counter! equ 10 (
echo now TEN
goto set_variables
)
)
#echo on
ENDLOCAL

Answer 1

CALL a subroutine (:label)
The following code runs a continuous loop, which increments the
variable counter. When counter reaches 10, it should call the
set_varibles routine, and then continue in the loop from the place
set_variables was called.
Exactly as proposed: echo now TEN and call :set_variables every tenth pass the endless loop.
#echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
call :set_variables
:my_loop
set /a counter=0
for /L %%n in (1,0,10) do (
echo !counter!
set /a counter=counter+1
set /a auxcounter=counter%%10
if !auxcounter! equ 0 (
echo now TEN
call :set_variables
)
)
#echo on
ENDLOCAL
#goto :eof
:set_variables
SET t=ooo
#goto :eof

Answer 2

Your main problem is not the goto command, but the for /l
While usually a goto command will cancel any block of code (code in parenthesis), for /l loops are a different beast. There are only two ways to leave a running for /l: an exit command (not exit /b unless the code is running in a command line context), or if the counter is greater than the end value.
Than means that the goto can not go out of the loop. It will cancel the execution of the code inside the do clause, but the loop will not be finished until the end value is reached, and your for loop
start step end
for /L %%n in ( 1, 0, 10 ) do ...
has a step value of 0 making it impossible to reach the end value.
The equivalent to your posted code could be
#echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
:set_variables
SET t=ooo
:my_loop
for /L %%n in (0,1,9) do (
echo %%n
set /a counter=%%n+1
rem ....
)
echo now TEN
goto set_variables

Answer 3

Isn't this what you want:
#echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
:set_variables
:my_loop
for /L %%n in (1,1,10) do (
echo %%n
if %%n equ 10 (
echo now TEN
SET t=ooo
)
)
goto my_loop
#echo on
ENDLOCAL

Answer 4

Using GOTO within parenthesis - including FOR and IF commands - will break their context.
Some things look odd in your script. Why have a continuous loop and then restart it when a counter reaches 10? Why not use "in (1,1,10)" like in Monacraft's answer?
Why does this tweaked version not do what you want?
#echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
set /a outer_counter=0
:set_variables
echo start of set_variables
SET t=ooo
:my_loop
set /a counter=0
for /L %%n in (1,1,10) do (
echo !counter!
set /a counter=counter+1
set /a outer_counter=outer_counter+1
if !counter! equ 10 (
echo now TEN
)
)
if !outer_counter! geq 100 goto after_loop
goto set_variables
:after_loop
echo FINISHED
#echo on
ENDLOCAL
pause

Answer 5

I hate when additional specifications are placed in comments instead of the question description, but this comment appeared below Monacraft's answer:
I want to re-run the routine which is called periodically within the loop.
Everytime the counter reaches a certain value, the routine must be called
and the counter variable reset.
So I think that the solution to all OP's requests is this:
#echo off
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
call :set_variables
:my_loop
for /L %%n in (1,0,10) do (
echo !counter!
set /a counter=counter+1
if !counter! equ 10 (
echo now TEN
call :set_variables
)
)
No matter what is placed here, because a *continuous loop* NEVER ENDS!
#echo on
ENDLOCAL
:set_variables
SET t=ooo
set /a counter=0
exit /B