Using sp_helptext in classic asp - sql-server

Question

When I want to get the definition of a stored procedure (in SQL Server) I use SQL Server Management Studio.
I sometimes run the `sp_helptext' to output the definition of a stored procedure.
Link: https://msdn.microsoft.com/en-us/library/ms176112.aspx
In a nutshell, I'd like to have a simple html popup window that would output any stored procedure's definition to text.
The asp code below is making a successful connection to my Database, but I'm not getting any output.
<%
' .......
sql = "exec sp_helptext 'some_ProcName_Here'"
objRs.open sql, objConn
Text=objRs("Text")
response.write(Text)
%>
I also attempted creating a new Stored Procedure that takes 1 parameter, which would execute the sp_helptext.
<%
' .......
sql = "exec See_Proc_Definition #ProcName=some_ProcName_Here"
objRs.open sql, objConn
Text=objRs("Text")
response.write(Text)
%>
Neither of these display anything, but I don't get any returned errors neither.
Can anyone see what I'm doing wrong?

Answer 1

The problem is you are only displaying the first line of the sp_HelpText output. SQL Server returns the output as a single column recordset containing a column called [Text].
This means you need to iterate through the rows to display the rest of the output.
Using your first example;
<%
' .......
sql = "exec sp_helptext 'some_ProcName_Here'"
objRs.open sql, objConn
Do While Not objRs.EOF
Text=objRs("Text")
response.write(Text)
objRS.MoveNext
Loop
%>
This isn't ideal but will work, from experience (especially with more complex stored procedures) I find something like this is better in the long run;
Dim sql, cmd, rs, data
Set cmd = Server.CreateObject("ADODB.Command")
sql = "sp_HelpText"
With cmd
'Use your connection string instead of instantiating an ADODB.Connection object.
.ActiveConnection = conn_string
.CommandType = adCmdStoredProc
.CommandText = sql
.Parameters.Append(.CreateParameter("#objname", adVarWChar, adParamInput, 776))
.Parameters.Append(.CreateParameter("#columnname", adVarWChar, adParamInput, 128))
Set rs = .Execute(, Array("some_ProcName_Here"))
If Not rs.EOF Then data = rs.GetRows()
Call rs.Close()
Set rs = Nothing
End With
Set cmd = Nothing
This method gives you a 2-Dimensional Array containing the row data in the data variable. You can then use standard Array techniques to manipulate the output.
Dim output, row, rows
If IsArray(data) Then
rows = UBound(data, 2)
For row = 0 To rows
output = output & "<br />" & data(0, row)
Next
Call Response.Write(output)
End If
Links
Using METADATA to Import DLL Constants - If your having trouble with the ADO constants (adCmdStoredProc etc.) this will fix it for you.