Rest parameter problems - arrays

Question

I'm attempting to have a class inherit a rest parameter from a parent class. Unfortunately for some reason the inherited rest parameter's inputs are treated as one whole index rather than each one acting like its own index.
Here's the code for the parent class with a rest parameter that works properly:
package {
import flash.events.MouseEvent;
import flash.display.Stage;
public class SubClassText extends ClassText {
protected var parentText:ClassText;
protected var setStatValues;
protected var className:String;
protected var classType:int;
public function SubClassText(textKey:String, textName:String, stageInstance:Stage, isVisible:Boolean, alignToObject:Object, direction:String, xDistance:Number, yDistance:Number, onOverText:String, parentText:ClassText, className:String, classType:int, ... setStatValues) {
super(textKey, textName, stageInstance, isVisible, alignToObject, direction, xDistance, yDistance, onOverText);
this.parentText = parentText;
this.parentText.subClassArray.push(this);
this.setStatValues = setStatValues;
this.className = className;
this.classType = classType;
}
//Called when the player clicks this object
override protected function onClick(e:MouseEvent) {
trace(this.setStatValues.length);
Entity.getEntity("entityName", "player").setStat("className", this.className);
Entity.getEntity("entityName", "player").setStat("classType", this.classType);
for(var i:int = 0; i < this.setStatValues.length; i++) {
Entity.getEntity("entityName", "player").setStat(Main.statArray[i], this.setStatValues[i]);
}
Main.setClassVisibility(this.parentText.subClassArray, true);
}
//Adds this object to it's parent's class array
override protected function addToArray() {
Main.subClasses.push(this);
}
}
}
I have the trace() call in the onClick listener to see the length of the rest parameter. In all instances of this class the rest parameter returns the proper amount of inputs (in this case, 5 since that's how many stats an entity has).
And here's the class that extends this parent class:
package {
import flash.events.MouseEvent;
import flash.display.Stage;
public class AllySubClassText extends SubClassText {
private var displayName:String;
public function AllySubClassText(textKey:String, textName:String, stageInstance:Stage, isVisible:Boolean, alignToObject:Object, direction:String, xDistance:Number, yDistance:Number, onOverText:String, parentText:ClassText, displayName:String, className:String, classType:int, ... setStatValues) {
super(textKey, textName, stageInstance, isVisible, alignToObject, direction, xDistance, yDistance, onOverText, parentText, className, classType, setStatValues);
this.displayName = displayName;
}
//Called when the player clicks this object
override protected function onClick(e:MouseEvent) {
trace(this.setStatValues.length);
Main.tryAddAlly(this.displayName, this.className, this.classType, this.setStatValues);
Main.setAllyVisibility(this.parentText.subClassArray, true);
}
//Adds this object to it's parent's class array
override protected function addToArray() {
Main.allySubClasses.push(this);
}
}
}
As you can see, I have the same rest parameter and the same trace() call.
For a better understanding here's an example piece of an instance of SubClassText:
var beserker:SubClassText = new SubClassText("beserker", "Beserker", stage, false,
warrior, "downCenter", 0, 0, "Beserkers are crazy strong fighters", warrior, "Beserker",
0, 15, 5, 10, 10, 10);
Then I can go into that SubClassText and trace its rest parameter length (setStatValues, I'm going to trace it from the fla document so for now I'm going to make that parameter public instead of protected):
trace(beserker.setStatValues.length); //5
Now here's an example of an instance of AllySubClassText:
var knight:AllySubClassText = new AllySubClassText("knight", "War: The Knight",
stage, false, warriors, "downCenter", 0, 0, "War is a strong Knight", warriors, "War",
"Knight", 0, 15, 5, 10, 10, 10);
Then when I trace the knight instance's rest parameter length:
trace(knight.setStatValues.length); //1
The example pieces were taken directly from my code, I just shortened the onHover string so it's easier to read. Sorry for the huge amount of inputs on the classes, UI code quickly took a lot of parameters to work correctly. I'm not sure why all inputs are being treated as one index rather than individual indexes. I even know it's doing this because here's what happens when I trace just the rest parameter:
trace(knight.setStatValues + ", " + knight.setStatValues.length); //15,5,10,10,10, 1
Any help would be greatly appreciated. It could be a minor oversight, but I'm stumped right now.

Answer 1

The problem is that ...rest parameters are an array.
That means when you pass that array to yet another function as a ...rest parameter, it will be of length 1, because you only passed one parameter: the single array.
It doesn't automatically "unwrap" an array into its elements.
Try this:
function first(...firstRest):void
{
trace(firstRest.length);
second(firstRest);
}
function second(...secondRest):void
{
trace(secondRest.length);
}
first(1,2,3);
I wouldn't recommend using ...rest anyway.
Create a class that holds all the status variables and pass an object of that class to the constructor. That allows you to do boundary checks on the values, dispatch change events to update views displaying the stats, etc.
These constructor calls you show there look quite bloated.
Passing a configuration object will help in reducing the mess.