do some math/manipulate 'find' output in a windows batch file - batch-file

Question

I am trying to output a file (count.txt) with the name of each csv and tab file in the current directory and the number of lines in that file. Although the tab file needs its value divided by 4. Also, I would like to get rid of the 10 dashes 'find' outputs and maybe rework the filename. How do i grab the out put of find and manipulate it?
del count.txt
for %%f in (*.csv) do (
find /c /v "" %%f >> count.txt
)
for %%f in (*.tab) do (
::need to divide the next value by 4
find /c /v "" %%f >> count.txt
)

Answer 1

edited to correct errors and adapt to comments
#echo off
setlocal enableextensions disabledelayedexpansion
rem Define extensions to handle
set "extensions=.tab .csv"
rem Define dividers for each extension
set ".tab=4"
set ".csv=1"
rem Retrieve starting folder from command line
rem If not present, assume current folder
set "root=%~1" & if not defined root set "root=%cd%"
rem For each folder starting at the indicated root
rem Change current path to the folder that will be processed and
rem (%%X) For each extension in list
rem (%%a/%%b) For each matching file/lines number processed by find command
rem Calculate the number of lines
rem Echo file information
rem Return to previous active directory
(for /r "%root%" /d %%F in (.) do (
pushd "%%~fF" && (
for %%X in (%extensions%) do if exist ".\*%%~X" (
for /f "tokens=2,3 delims=\:" %%a in ('
find /c /v "" ".\*%%~X" 2^>nul
') do (
set /a "numLines=%%b / %%~xa"
setlocal enabledelayedexpansion
for %%c in (!numLines!) do (
endlocal
echo [%%~fa] [%%c]
)
)
)
popd
)
)) > count.txt
Where the task of each of the for loops is
%%F will recurse the folder hierarchy from the indicated starting point
%%X will iterate over the list of extensions to handle
%%a will execute the find command over all the indicated files and split each line using a backslash and a colon. The slash is included in the output of the find command because we use a relative reference to each file (.\*.csv). That way the initial dashes and space are removed. Then the colon is used to separate the file name from the line count. At the end %%a will hold the file name and %%b the line count.
Once we have the required elements, we will need delayed expansion active to access the result of the calculation. The file extensions is used to determine the divider using variables defined for each case.
%%c Having delayed expansion active generates a problem with files that contain an ! it its name, so we need to disable (endlocal) the delayed expansion before executing the echo, so an aditional for command is used to hold the value of the number of lines that need to be echoed. With delayed expansion disabled, the information is echoed.
The outer for loop is enclosed in parenthesis so we can redirect all the output opening the output file only once instead of one open/write operation for each file.