creating thousands of folders with different names - batch-file

Question

I have to create a couple of thousand directories.
The directories look like this: 10P001 being YEAR/P,S,L,R,F/Numberfrom001to600
the letters are not systematic, so i have to write them for every folder.
my script until now looks like this, but cmd doesnt like the for loop.
#echo off
setlocal enabledelayedexpansion
set /p jahr=Welches Jahr?
set /p anzahl=Wieviele Projekte?
set looop=%anzahl+1000
for /l %%x in (1001, 1, looop) do (
set nummer=%%x
set /p welches=P1 S2 L3 R4 F5 nichtexistent6?
if %welches%==1 mkdir %jahr%P!nummer:~-3!
if %welches%==2 mkdir %jahr%S!nummer:~-3!
if %welches%==3 mkdir %jahr%L!nummer:~-3!
if %welches%==4 mkdir %jahr%R!nummer:~-3!
if %welches%==5 mkdir %jahr%F!nummer:~-3!
if %welches%==6 echo "nicht existent"
)
pause

Answer 1

#ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /f "tokens=1,2delims= " %%a IN (q28608207.txt) DO (
FOR /l %%x IN (1001,1,1011) DO (
SET seq=%%x
ECHO(MD %%a%%b!seq:~-3!
)
)
GOTO :EOF
I used a file named q28608207.txt containing this data for my testing.
10 P
10 S
The routine reads the two fields from the file as %%a and %%b, then for a loop varying %%x from 1001 by 1 to 1011 (it can of course be 1600 - 1011 just proves the point), copy %%x to a temporary veriable (because substringing can't be applied to the metavariable %%x) create a directory named %%a%%b and the last 3 characters of the temporary variable.
Note that the setlocal enabledelayedexpansion command enables the use of !var! (accessing the value of var as it varies)
The required MD commands are merely ECHOed for testing purposes. After you've verified that the commands are correct, change ECHO(MD to MD to actually create the directories. Append 2>nul to suppress error messages (eg. when the directory already exists)
To create a file containing the required numbers:
#echo off
setlocal enabledelayedexpansion
set /p jahr=Welches Jahr?
set /p anzahl=Wieviele Projekte?
set looop=%anzahl+1000
(
for /l %%x in (1001, 1, looop) do (
set nummer=%%x
echo %jahr%P!nummer:~-3!
)
)>J%jahr%.txt
This would produce a list (for jahr=14,say) in J14.txt
14P001
14P002
14P003
and then all you need do is edit the file (use notepad, not a word-processor) to replace the "P" with whatever letter is required. delete any line where no directory is required.
The resultant file could then be processed to directories by using
#ECHO OFF
SETLOCAL
FOR /f %%a IN (J14.txt) DO (
ECHO(MD "%%a"
)
GOTO :EOF

Answer 2

my solution for now (i know its worse than bad habit, but it works and will save me a lot of time (or at least my company some money)):
#echo off
setlocal enabledelayedexpansion
set /p jahr=Welches Jahr?
set /p anzahl=Wieviele Projekte?
set /a looop=%anzahl%+1000
set /a count=1001
:LoopStart
set /p welches=P1 S2 L3 R4 F5 nichtexistent6?
if !welches!==1 mkdir %jahr%P!count:~-3!
if !welches!==2 mkdir %jahr%S!count:~-3!
if !welches!==3 mkdir %jahr%L!count:~-3!
if !welches!==4 mkdir %jahr%R!count:~-3!
if !welches!==5 mkdir %jahr%F!count:~-3!
if !welches!==6 echo "nicht existent"
set /a count=%count%+1
if %count% leq %looop% (goto LoopStart) else (goto:eof)
pause