How to read the 2 first chars of multiple files in cmd - batch-file

Question

At work I need to create a .bat script that reads the first 2 chars on the first line, of multiple files, and then echo them to the screen.
So far I have this:
#echo off
setlocal enabledelayedexpansion
for /r I:\Test\Filer %%F in (*.*) do (
set first2 =<%%F
set first2=%first2:~0,2%
echo %first2%
)
But all it writes is: ECHO is off
Anyone got an idea what I have done wrong?

Answer 1

You are missing /p! This should work:
#ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /r I:\Test\Filer %%F in (*.*) do (
SET /p first2=<%%F
SET first2=!content:~0,2!
ECHO !first2!
)
PAUSE

Answer 2

#echo off
setlocal enabledelayedexpansion
for /r I:\Test\Filer %%F in (*.*) do (
set /p first2=<%%F
set "first2=!first2:~0,2!"
echo(!first2!
)
In delayedexpansion mode, %var% is the value of var at parse-time and !var! is the run-time value.
The ( in the echo will ensure that a newline is shown if var is not set (or "set" to a zero-length string)
The quotes in a set statement ensure that trailing spaces are not included in the value assigned to the variable.
Note that spaces are not allowed after the variablename in a string "set" statement; a variable with a trailing space in its name will be set, and this is not the same as the variable with no space in its name.
set /p is required to assign a value from a file. Be carefu of zero-length files and files containing a newline (CR LF) at the start!

Answer 3

Delayed Expansion will cause variables to be expanded at execution time rather than at parse time, this option is turned on with the SETLOCAL command. When delayed expansion is in effect variables may be referenced using !variable_name! (in addition to the normal %variable_name% )
#echo off
setlocal enableextensions enabledelayedexpansion
for /r I:\Test\Filer %%F in (*.*) do (
set /p first2=<"%%~F"
set "first2=!first2:~0,2!"
echo !first2!
)
Here in set /p first2=<"%%~F" use double quoted "%%~F" (for a case if a path or file name contains e.g. space) and ~ modifier (to avoid doubling of double quotes)
Resources:
EnableDelayedExpansion
Command Line arguments (Parameters) and their ~ modifier(s)