How to change every i-th element of an array in Modelica - arrays

Question

I’m trying to change every i-th element of an array, as an event occurs. This could be reached by the following code. In this example every second element should be changed. Due to parameter defined array size, the second argument of the ‘inner’ loop should be set by the variable ‘Upper’.
model Test
Boolean Event;
Real Vector[6](start = ones(6), fixed = true);
Integer Upper;
algorithm
when Event then
Vector := ones(6);
Upper := 3;
for i in {2*j for j in 1:Upper} loop
Vector[i] := Vector[i]+1;
end for;
end when;
equation
Event = if time <=1 then false else true;
end Test;
Dymola doesn’t accept this solution, stating ‘Failed to calculate the last argument of 1:Upper’. When I enter 3 directly instead of ‘Upper’, the code works.
Is there a possibility to fix this? Or is there an easier way to change every i-th element in algorithm section?
Thanks in advance.

Answer 1

I would say this is a Dymola issue. OpenModelica handles it just fine.
This is an alternative formulation that might work better for you (hiding everything in a function should make Dymola happier since there are no dimension sizes that are hard to deduce).
function incrementEveryIth
input Real v[:];
input Integer i;
input Real increment := 1;
output Real o[size(v,1)] := v;
algorithm
o := {if mod(n,i)<>0 then v[n] else (v[n]+increment) for n in 1:size(v,1)};
end incrementEveryIth;
model Test
Boolean Event;
Real Vector[6](start = ones(6), each fixed = true);
algorithm
when Event then
Vector := incrementEveryIth(pre(Vector),2);
end when;
equation
Event = if time <=1 then false else true;
end Test;
Or perhaps this one:
model Test
Boolean Event;
Real Vector[6](start = ones(6), each fixed = true);
algorithm
when Event then
Vector := pre(Vector); // This should not really be needed, but OpenModelica insists
Vector[1:2:6] := Vector[1:2:6] + {1,1,1};
end when;
equation
Event = if time <=1 then false else true;
end Test;