Accessing Public Variant Array from Module - arrays

Question

Say I have two files Form1.frm and Module1.bas in a Visual Basic 6 project.
Form1.frm:
Public myArray As Variant
Private Sub Form_Load()
ReDim myArray(2)
Call PopulateArrays
End Sub
Module1.bas:
Public Sub PopulateArrays()
Form1.myArray(0) = Array(1, 2, 3)
Form1.myArray(1) = Array(4, 5, 6)
Form1.myArray(2) = Array(7, 8, 9)
End Sub
The issues is that once the code runs, 'myArray' remains empty.
If I put the PopulateArrays Sub within the main Form1.frm the arrays do populate.
Any thoughts?

Answer 1

There are certain things you can't declare in an object module (userforms are just special object modules) and one of them is arrays. If you had declared
Public myArray() As Variant
Then you would have got a compile error that said as much and would have known. But since you declared as Variant, the compiler didn't complain, but the assignment just doesn't work.
One option is to make the Variant array private and use property statements (this is VBA, but should be the same for VB6). In the userform
Private mmyArray() As Variant
Public Property Get myArray() As Variant
myArray = mmyArray
End Property
Public Property Let myArray(lmyArray As Variant)
mmyArray = lmyArray
End Property
Private Sub UserForm_Click()
MsgBox Join(Me.myArray(0), "_")
End Sub
Private Sub UserForm_Initialize()
ReDim mmyArray(2)
PopulateArrays
End Sub
And in a standard module
Public Sub PopulateArrays()
Dim ar(0 To 2) As Variant
ar(0) = Array(1, 2, 3)
UserForm1.myArray = ar
End Sub

Answer 2

I see you've used a workaround to let your Form1 hold a public array. However, I think a better solution would be: (A) move the array to the module and make it public (B) create accessor/mutator functions for it.
If you aren't keeping multiple instances of the form at the same time, then (A) is the simplest solution.
Here is the code I tested for (A),
Form:
Private Sub UserForm_Initialize()
Call PopulateArrays
Call displayArray
End Sub
Private Sub displayArray()
Dim v1 As Variant
Dim s As String
For Each v1 In myArray
s = s + Join(v1, ", ") + vbNewLine
Next v1
MsgBox s
End Sub
Module:
Dim form1 As UserForm1
Public myArray As Variant
Public Sub start()
Set form1 = New UserForm1
End Sub
Public Sub PopulateArrays()
ReDim myArray(2)
myArray(0) = Array(1, 2, 3)
myArray(1) = Array(4, 5, 6)
myArray(2) = Array(7, 8, 9)
End Sub