Handling tables in text files with VB6 - database

Question

I want to make a VB6 executable that can handle a text file (or more) that have the following format.
X1 field | Y1 field | Z1 field \n
X2 field | Y2 field | Z2 field \n
....\n
....\n
Xn field | Yn field | Zn field.
It look's like a table from db or csv file and I would like to make a VB6 program that can search, edit and add all these fields. Is there any library or framework in VB6 to help me?

Answer 1

A disconnected database.
Sub Randomise
Randomize
Set rs = CreateObject("ADODB.Recordset")
With rs
.Fields.Append "RandomNumber", 4
.Fields.Append "Txt", 201, 5000
.Open
Do Until Inp.AtEndOfStream
.AddNew
.Fields("RandomNumber").value = Rnd() * 10000
.Fields("Txt").value = Inp.readline
.UpDate
Loop
.Sort = "RandomNumber"
Do While not .EOF
Outp.writeline .Fields("Txt").Value
.MoveNext
Loop
End With
End Sub

Answer 2

It all depends on what you want to do with the data but you can use the following steps:
Read in the file, either per line or the complete file at once
Substract the data in the correct format
write the data to your favorite database/control
For example, to read in the whole file at once, and show its fields into a MSFlexGrid you can do the following:
'1 form with:
' 1 MSFlexFrid control: name=MSFlexGrid1
' 1 Command button: name=Command1
Option Explicit
Private Sub Command1_Click()
Dim lngLine As Long, lngField As Long
Dim intFile As Integer
Dim strFile As String
Dim strData As String
Dim strLine() As String, strField() As String
'read the file
strFile = "c:\temp\file.txt"
intFile = FreeFile
Open strFile For Input As #intFile
strData = Input(LOF(intFile), #intFile)
Close #intFile
'split the file in separate lines
strLine = Split(strData, "\n")
'fill the grid with the data
With MSFlexGrid1
.Rows = UBound(strLine) + 1
For lngLine = 0 To UBound(strLine)
'put all fields from 1 line on 1 row in the grid
strField = Split(strLine(lngLine), "|")
If UBound(strField) > .Cols - 1 Then
.Cols = UBound(strField) + 1
End If
For lngField = 0 To UBound(strField)
.TextMatrix(lngLine, lngField) = strField(lngField)
Next lngField
Next lngLine
End With 'MSFlexGrid1
End Sub
Private Sub Form_Resize()
Dim sngWidth As Single, sngHeight As Single
Dim sngGrdHeight As Single
Dim sngCmdHeight As Single
sngWidth = ScaleWidth
sngHeight = ScaleHeight
sngCmdHeight = 315
sngGrdHeight = sngHeight - sngCmdHeight
MSFlexGrid1.Move 0, 0, sngWidth, sngGrdHeight
Command1.Move 0, sngGrdHeight, sngWidth, sngCmdHeight
End Sub