Batch or VB script to initiate Win7 RunAs login box? - batch-file

Question

I'm looking for a batch command or VBscript to execute what would a Shift+Right-click > "Run as different user" It pops up with a login box that just says "Windows Security" in the title
http://i.imgur.com/EDeCCND.jpg
I've searched far and wide and the closest I've gotten was the "runas" from the command line, and I've found a VBscript that can do "Run as administrator." But I just want a script that will initiate a login box like in the picture above, which is the same as the "Run as different user"
Thanks
Edit - Some background of my issue:
I have a batch file that I use to install software to remote computer via psexec, as well as running some scripts and stuff. Now in order to run my batch file successfully, the user will need to run it under a domain admin account. And I'm basically trying to force that to happen.
At first I tried forcing the UAC to come up via this beautiful script...and that works great! Unfortunately I found out that will not work if a local administrator is logged on and launches the file (it will see that it already has admin rights on the local machine, but it won't have rights on the remote machine when it goes to run psexec).
I can't really do a runas via batch because I don't know what domain admin is going to be running the batch. I also would rather not have the user enter their credentials in a command line window...And I could just tell them to do the shift+right-click on the bat file, but I'd like to avoid that if possible, since users can be forgetful :)
So the solution to my problem, I believe, is a script that will do exactly what a Shift+right-click > "Run as different user" will do.
Any help is greatly appreciated

Answer 1

Shverb - Lists or runs an explorer verb (right click menu)
Drag and drop or use in a command line.
HelpMsg = vbcrlf & " ShVerb" & vbcrlf & vbcrlf & " David Candy 2014" & vbcrlf & vbcrlf & " Lists or runs an explorer verb (right click menu) on a file or folder" & vbcrlf & vbcrlf & " ShVerb <filename> [verb]" & vbcrlf & vbcrlf & " Used without a verb it lists the verbs available for the file or folder" & vbcrlf & vbcrlf
HelpMsg = HelpMsg & " The program lists most verbs but only ones above the first separator" & vbcrlf & " of the menu work when used this way" & vbcrlf & vbcrlf
HelpMsg = HelpMsg & " The Properties verb can be used. However the program has to keep running" & vbcrlf & " to hold the properties dialog open. It keeps running by displaying" & vbcrlf & " a message box."
Set objShell = CreateObject("Shell.Application")
Set Ag = WScript.Arguments
set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
If Ag.count = 0 then
wscript.echo " ShVerb - No file specified"
wscript.echo HelpMsg
wscript.quit
Else If Ag.count = 1 then
If LCase(Replace(Ag(0),"-", "/")) = "/h" or Replace(Ag(0),"-", "/") = "/?" then
wscript.echo HelpMsg
wscript.quit
End If
ElseIf Ag.count > 2 then
wscript.echo vbcrlf & " ShVerb - To many parameters" & vbcrlf & " Use quotes around filenames and verbs containing spaces" & vbcrlf
wscript.echo HelpMsg
wscript.quit
End If
If fso.DriveExists(Ag(0)) = True then
Set objFolder = objShell.Namespace(fso.GetFileName(Ag(0)))
' Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
Set objFolderItem = objFolder.self
msgbox ag(0)
ElseIf fso.FolderExists(Ag(0)) = True then
Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
ElseIf fso.fileExists(Ag(0)) = True then
Set objFolder = objShell.Namespace(fso.GetParentFolderName(Ag(0)))
Set objFolderItem = objFolder.ParseName(fso.GetFileName(Ag(0)))
Else
wscript.echo " ShVerb - " & Ag(0) & " not found"
wscript.echo HelpMsg
wscript.quit
End If
Set objVerbs = objFolderItem.Verbs
'If only one argument list verbs for that item
If Ag.count = 1 then
For Each cmd in objFolderItem.Verbs
If len(cmd) <> 0 then CmdList = CmdList & vbcrlf & replace(cmd.name, "&", "")
Next
wscript.echo mid(CmdList, 2)
'If two arguments do verbs for that item
ElseIf Ag.count = 2 then
For Each cmd in objFolderItem.Verbs
If lcase(replace(cmd, "&", "")) = LCase(Ag(1)) then
wscript.echo Cmd.doit
Exit For
End If
Next
'Properties is special cased. Script has to stay running for Properties dialog to show.
If Lcase(Ag(1)) = "properties" then
WSHShell.AppActivate(ObjFolderItem.Name & " Properties")
msgbox "This message box has to stay open to keep the " & ObjFolderItem.Name & " Properties dialog open."
End If
End If
End If
also
wmic /node"#%userprofile%\desktop\ComputerName.txt" /user:username /password:password /failfast:on process call create c:\somefile.bat

Answer 2

It has help built in. The first three lines are the help file.
ShVerb
Lists or runs an explorer verb (right click menu) on a file or folder
ShVerb <filename> [verb]
Used without a verb it lists the verbs available for the file or folder
The program lists most verbs but only ones above the first separator
of the menu work when used this way
The Properties verb can be used. However the program has to keep running
to hold the properties dialog open. It keeps running by displaying
a message box.
You'll have to run it on the remote system.
But the two command line tools allow passwords to be entered. And as I've shown you can put the user name in automatically.