VB6, ADO, Asynchronous command and closing the connection - sql-server

Question

Quick question really, do I need to close an ADO command? I have read in several places that simply setting it to nothing does the same thing as closing it but I'm yet to find a definitive answer.
I have a VB6 routine that at runtime creates a connection and command object which execute asynchronously a stored procedure that doesn't return any results.
At the end of this routine both objects are set to nothing. The below code shows exactly what's performed
' Open connection
con.Open
'
' Create command to execute stored proc
Set cmd = New ADODB.Command
cmd.ActiveConnection = con
cmd.CommandType = adCmdStoredProc
cmd.CommandText = cSQLDelete
cmd.Parameters.Append cmd.CreateParameter _
("#ExpiryDate=", adDate, adParamInput, 20, ExpiryDate)
'
' Run procedure, no results
cmd.Execute , , adExecuteNoRecords + adAsyncExecute
'
' Tidy up
Set cmd = Nothing
Set con = Nothing
Note the absence of con.Close. If this is inserted before the con=nothing, the stored procedure does not run - I assume that since it's asynchronous it hasn't had time to execute before the connection is closed.
Without the con.Close, this works fine.
So, my question is what implications are there for not closing the connection. Will the connection simply timeout in the background?? Bear in mind that this function is called A LOT and so far testing hasn't shown any problems.
If I need to close the connection when the stored procedure finishes, how would I do this? Having a C# background, I'm unfamiliar with VB6 and find creating objects with events at runtime an awkward process.
p.s. Sql Server 2008
Thanks

Answer 1

You have to wait for command to complete or fail before tearing down the connection. Closing connection while command is executing will instantaneously raise an error, setting connection to nothing won't release the resources it is holding and may crash your program.
The correct method is to close the connection when the command completes, usually by monitoring the ExecuteComplete event (your connection must belong to a class or a form).
You can use a something similar:
Option Explicit
Dim WithEvents con As ADODB.Connection
Dim bExecuting As Boolean
Private Sub cmdCancel_Click()
If Not bExecuting Then Exit Sub
If Not con Is Nothing Then
con.Cancel
End If
bExecuting = False
End Sub
Private Sub cmdExecute_Click()
If bExecuting Then Exit Sub
If con Is Nothing Then
Set con = New ADODB.Connection
con.Open "Provider=..."
End If
bExecuting = True
con.Execute "WAITFOR DELAY '000:00:10'", , adExecuteNoRecords + adAsyncExecute
End Sub
Private Sub cmdExit_Click()
If bExecuting Then Exit Sub
Unload Me
End Sub
Private Sub con_ExecuteComplete(ByVal RecordsAffected As Long, ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pCommand As ADODB.Command, ByVal pRecordset As ADODB.Recordset, ByVal pConnection As ADODB.Connection)
If Not pError Is Nothing Then Debug.Print pError.Description
bExecuting = False
End Sub
Private Sub Form_Load()
bExecuting = False
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
If bExecuting Then Cancel = 1
End Sub
Private Sub Form_Unload()
If Not con Is Nothing Then
If con.State = adStateOpen Then con.Close
set con = Nothing
End If
End Sub

Answer 2

What this code does is execute the command if the connection is not busy (State=Open). Otherwise put it on a stack and execute it when the current command completes. My knowledge of VB arrays is limited so sorry its a bit ugly - there may be a better way to do a FIFO queue?
Dim WithEvents mobjAdoConn As ADODB.Connection
Dim CommandArray() As String
Private Sub Command1_Click()
Dim cmdNo As Integer
If mobjAdoConn.State <> adStateOpen Then
cmdNo = UBound(CommandArray)
ReDim Preserve CommandArray(cmdNo + 1)
CommandArray(cmdNo) = "WAITFOR DELAY '000:00:10'"
Label2.Caption = cmdNo
Else
mobjAdoConn.Execute "WAITFOR DELAY '000:00:10'", , adExecuteNoRecords + adAsyncExecute
End If
End Sub
Private Sub Form_Load()
On Error GoTo Err
Set mobjAdoConn = New ADODB.Connection
mobjAdoConn.ConnectionTimeout = 30
mobjAdoConn.ConnectionString = "Provider..."
mobjAdoConn.Open
ReDim CommandArray(1)
Exit Sub
Err:
MsgBox Err.Description, vbOKOnly
End Sub
Private Sub mobjAdoConn_ExecuteComplete(ByVal RecordsAffected As Long, ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pCommand As ADODB.Command, ByVal pRecordset As ADODB.Recordset, ByVal pConnection As ADODB.Connection)
Dim cmd As String
Dim i As Integer
Dim cmds As Integer
cmds = UBound(CommandArray)
If cmds > 1 Then
cmd = CommandArray(1)
If cmds = 2 Then
ReDim CommandArray(1)
Label2.Caption = 0
Else
For i = 2 To cmds - 1
CommandArray(i - 1) = CommandArray(i)
Next i
ReDim Preserve CommandArray(cmds - 1)
Label2.Caption = cmds - 2
End If
mobjAdoConn.Execute cmd, , adExecuteNoRecords + adAsyncExecute
End If
End Sub

Answer 3

I'm here because I'm considering using asynchExecute on a similar real-time application. The problem with setting the connection to nothing while it is open is that it may not get properly released and every 10Ms you create a new one, this could result in a memory leak. Mucker you should monitor memory usage when you are testing this to see if it happens.