IF NOT EXIST against Prompting user to select a directory - batch-file

Question

If I were to create a condition where a user selects a directory by number, how would I test that to make sure it’s valid?
In other words, if a user were prompted:
C:\Program Files
C:\Userdata
Please select a directory: 3
In this unique scenario, how can I test against that and inform the user that 3 is a wrong selection and then loop back to the sub-routine?
I’ve sort of hit a dead end as I thought the “if not exist” would work.
I’ve tried the following without success:
If %errorlevel% equ 1 (command) else (command)
If errorlevel 1 (command) else (command)
If not exist !acctDir!!userDir! (command) else (command).
This is what I have:
:dir
echo.
set c=0
For /f %%a in ('dir !acctDir! /B /A:D') do (
set /a c+=1
echo !c! %%a >>!log!
echo !c! %%a
set dir!c!=%%a
)
echo.
set /p userIn=" Please select a directory [1-!c!]: "
set userDir=!dir%userIn%!
echo ***DEBUG*** Path=[!acctDir!\!userDir!]
pause
if not exist "!acctDir!\!userDir!" (
echo.
echo That is not a valid selection. Please try again. >>!log!
echo That is not a valid selection. Please try again.
echo.
ping 127.0.0.1 -n 3 -w 1000 >nul
cls
goto dir
) else (
echo.
echo You selected !userDir! for your data retrieval. >>!log!
echo You selected !userDir! for your data retrieval.
echo.
ping 127.0.0.1 -n 3 -w 1000 >nul
goto string
)
)
When I do some DEBUG testing to echo out the path before the IF statement is ran I get:
1 Jan_14_2014_12_49_11_900PM
2 Jan_20_2014_6_56_55_953PM
Please select a directory [1-2]: 3
***DEBUG*** Path=[x:\101004357\]
Press any key to continue . . .
So it returns a path as having the account number but not the sub-directory because of obvious reasons as input 3 is nothing. However, IF NOT EXIST should be followed then, right?
I don’t think Windows knows the numbers are related to the sub-directories?
So, I need a condition stating, IF NOT EXIST any subdirectory (which I thought would be the variable !userDir!). But the !userDir! is being assigned as nothing, so this is why it’s not working. Then I think I would need to get a list of the sub-directories to run this statement against.
**This is just 1 of 12 sub-routines, so these are the correct variables.
Any idea of how I can complete this task?

Answer 1

I was able to resolve the issue by solving the issue if there was a NULL output. Setting the variable around brackets and setting it to equal the null output surrounded by empty brackets allows me to test against the user input.
Simply did the following:
if [!userDir!]==[] (
echo.
echo That is not a valid selection. Please try again. >>!log!
echo That is not a valid selection. Please try again.
echo.
ping 127.0.0.1 -n 3 -w 1000 >nul
cls
goto dir
) else (
echo.
echo You selected !userDir! for your data retrieval. >>!log!
echo You selected !userDir! for your data retrieval.
echo.
ping 127.0.0.1 -n 3 -w 1000 >nul
goto string
)
)

Answer 2

Try this:
#echo off
setlocal Enabledelayedexpansion
set c=0
set "acctDir=U:\scripts\batch"
For /f %%a in ('dir !acctDir! /B /A:D') do (
set /a c+=1
echo !c! %%a
set dir!c!=%%a
set valid=!valid! !c!
)
:StartOver
set /p userIn=" Please select a directory [1-!c!]: "
set userDir=!dir%userIn%!
REM echo valid=%valid%
for %%a in (%valid%) do (
if %userIn% NEQ %%a (
set txt=!userIn! is not a valid selection. Please try again.
) ELSE (
set txt=You selected !userDir! for your data retrieval.
Goto :out
)
)
:out
If "%txt:~0,3%" EQU "You" Echo %txt%
if "%txt:~0,3%" NEQ "You" Echo %txt% & goto :StartOver

Answer 3

This should work: The trailing backslash tests only for a folder and not for a filename.
If not exist "!acctDir!\!userDir!\" (command) else (command)

Answer 4

#ECHO OFF
SETLOCAL
SET acctdir=.
:: remove variables starting $
FOR /F "delims==" %%a In ('set $ 2^>Nul') DO SET "%%a="
SET "$alphabet=0 1 2 3 4 5 6 7 8 9 A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
FOR /f "delims=" %%a IN ('dir "%acctDir%" /B /A:D') DO CALL :setchoices "%%a"
IF NOT DEFINED $_%$alphabet:~0,1% GOTO :EOF
FOR /f "tokens=2*delims=_=" %%a IN ('set $_') DO ECHO(%%a : %%b
choice /c %$$% /m "Choose from menu "
SET /a chosen=%ERRORLEVEL%-1
CALL SET $$=%%$$:~%chosen%,1%%
CALL SET $$=%%$_%$$%%%
ECHO CD "%acctDir%\%$$%"
GOTO :EOF
:setchoices
FOR %%i IN (%$alphabet%) DO IF NOT DEFINED $_%%i (
SET "$_%%i=%~1"
SET "$$=%$$%%%i"
GOTO :EOF
)
GOTO :eof
This works - I used . as acctdir for testing. Your choice of letters and numbers for choicenames in $alphabet
Target directory just echoed - remove the echo before the cd to activate.