Extract only specific string using windows batch script - batch-file

Question

Using Windows Batch script, I need the output as shown below. Please help.
Input:
APP "Default Web Site/" (applicationPool:DefaultAppPool)
APP "Default Web Site/App1" (applicationPool:App1)
APP "Default Web Site/App1/Pages" (applicationPool:App1)
App "Site1/App2/" (applicationPool:App2)
App "Site1/App3/VD1" (applicationPool:VD1)
Output:
Default Web Site
Site1

Answer 1

This works with the sample data.
#echo off
(for /f "delims=/" %%a in (file.txt) do (
for /f "tokens=1,*" %%b in ("%%~a") do (
echo %%~c
)
))>temp.fil
sort <temp.fil |uniq
del temp.fil
pause
The code below is uniq.bat
Place uniq.bat in the same folder as the batch file above or in a directory on the path.
#if (#CodeSection == #Batch) #then
#CScript //nologo //E:JScript "%~F0" & goto :EOF & Rem aacini 2013
#end
var line, prevLine = "";
while ( ! WScript.Stdin.AtEndOfStream ) {
line = WScript.Stdin.ReadLine();
if ( line != prevLine ) {
WScript.Stdout.WriteLine(line);
prevLine = line;
}
}

Answer 2

#echo off
setlocal
set "arg_two=%~2"
for /f "tokens=1 delims=/" %%a in ("%arg_two%") do echo %%a
endlocal
test:
outputparser.bat APP "Default Web Site/" (applicationPool:DefaultAppPool)
>Default Web Site
outputparser.bat App "Site1/App3/VD1" (applicationPool:VD1)
>Site1
But if you set quotes around the input it will not work.
EDIT with a file to process (content is the same as in the question):
#echo off
setlocal
set "file_to_process=.\input_file.txt"
for /f "usebackq tokens=1 delims=(" %%W in ("%file_to_process%") do (
for /f usebackq^ tokens^=2^ delims^=/^" %%a in ('%%~W') do (
echo %%a
)
)
endlocal

Answer 3

#echo off
setlocal enableextensions enabledelayedexpansion
set "inputFile=c:\somewhere\file.dat"
rem Extract the required part of the lines
set "tempFile=%temp%\%~nx0.%random%.tmp"
> "%tempFile%" (
for /f usebackq^ tokens^=2^ delims^=^/^" %%a in ("file.txt") do (echo(%%a)
)
rem Remove the duplicates from the list
set "previous="
for /f "tokens=*" %%f in ('type "%tempFile%" ^| sort') do (
if not "%%f"=="!previous!" (
echo(%%f
set "previous=%%f"
)
)
rem Cleanup
del "%tempFile%" >nul 2>nul
endlocal
It uses the quotes and slashes as delimiters to cut the lines on the required points. Then the list is sorted to eliminate duplicates from the output

Answer 4

#echo off
setlocal enableDelayedExpansion
set "val="
for /f tokens^=2^ delims^=/^" %%A in ('sort input.txt') do (
if "!val!" neq "%%A" echo %%A
set "val=%%A"
)
In the unlikely event that a value may contain !, then you would need
#echo off
setlocal disableDelayedExpansion
set "val="
for /f tokens^=2^ delims^=/^" %%A in ('sort input.txt') do (
set "new=%%A"
setlocal enableDelayedExpansion
if "!val!" neq "!new!" echo !new!
endlocal
set "val=%%A"
)