how to encrypt a text file using batch? - batch-file

Question

How can i encrypt the content in a text file using batch? and how can i decrypt it?
i have tried setting each letter to a number but i do not know how to split the string into each letter and do that.
I watched a video on youtube that help turn letters into numbers but it did not do it with a file.
this is the code he provides in the video.
#echo off
setlocal enableDelayedExpansion
set /p code=Text:
set chars=0123456789abcdefghijklmnopqrstuvwxyz
for /L %%N in (10 1 36) do (
for /F %%C in ("!chars:~%%N,1!") do (
set "code=!code:%%C=%%N!"
)
)
echo !code!
pause
Please help Thank you

Answer 1

#ECHO OFF
SET abet=abcdefghijklmnopqrstuvwxyz!##-/\ .0123456789
SET cipher1=8p#j4 9z\6w.ae#0u2r5o!xk-cf1b3g7hmqil/sntdvy
(
FOR /f "delims=" %%a IN (q20794050.txt) DO (
SET line=%%a
CALL :encipher
)
)>q20794050.txt.1
(
FOR /f "delims=" %%a IN (q20794050.txt.1) DO (
SET line=%%a
CALL :decipher
)
)>q20794050.txt.2
GOTO :EOF
:decipher
SET morf=%abet%
SET from=%cipher1%
GOTO trans
:encipher
SET from=%abet%
SET morf=%cipher1%
:trans
SET "enil="
:transl
SET $1=%from%
SET $2=%morf%
:transc
IF /i "%line:~0,1%"=="%$1:~0,1%" SET enil=%enil%%$2:~0,1%&GOTO transnc
SET $1=%$1:~1%
SET $2=%$2:~1%
IF DEFINED $2 GOTO transc
:: No translation - keep
SET enil=%enil%%line:~0,1%
:transnc
SET line=%line:~1%
IF DEFINED line GOTO transl
ECHO %enil%
GOTO :eof
Here's a way to do it using a simple Cæsar (substitution) code.
abet can be set (possibly from a file) to the set of characters that you want to encode. Similarly, cipher1 can be set to the transled set - just make sure that each character in abet also appears in cipher1.
Any character that appears in the input text but not in abet will not be translated.
I used q20794050.txt:
The quick brown fox [jumps] {over} the lazy dog 9876543210.
9876543210 The quick brown fox !##-/\ jumps over the lazy dog.f
Which was encoded to q20794050.txt.1 :
5z4huo\#whp2#xeh #kh[6oa0r]h{#!42}h5z4h.8c-hj#9hyvdtns/liqm
yvdtns/liqh5z4huo\#whp2#xeh #khf1b3g7h6oa0rh#!42h5z4h.8c-hj#9m
(Note that there is a Space at the end of that last line...)
And was successfully disencrypted to q20794050.txt.2
Note: the above won't handle certain problem characters like %&|><
I've only used lower-case so any upper-case would be translated to lower-case by the process. If you remove the /i from the IF statement, then case will be preserved, but you'd have to add the upper-case letters to abet and cipher1 else the encrypted file will contain the upper-case characters verbatim.
Note that
(for...do (...))>somefilename
will create a new file somefilename containing any data ECHOed - even if the ECHO occurs in a subroutine.

Answer 2

#echo off
setlocal enableDelayedExpansion
for /f "tokens=* delims= " %%h in ('type %1') do (
set text=%%h
)
set chars=0123456789abcdefghijklmnopqrstuvwxyz
for /L %%N in (10 1 36) do (
for /F %%C in ("!chars:~%%N,1!") do (
set "text=!text:%%C=-%%N!"
)
)
echo !text! > %userprofile%\Desktop\encrypted.txt
pause
(using a different .bat file)
#echo off
setlocal enableDelayedExpansion
for /f "tokens=* delims= " %%h in ('type %1') do (
set text=%%h
)
set chars=0123456789abcdefghijklmnopqrstuvwxyz
for /L %%N in (10 1 36) do (
for /F %%C in ("!chars:~%%N,1!") do (
set "text=!text:%%N=%%C!"
)
)
for /f %%K in ("!text!") do (
set "text=!text:-=!"
)
echo !text! > %userprofile%\Desktop\decrypted.txt
pause