For Command help - nested command - batch-file

Question

I have created the following simple batch file.... What I'm trying to accomplish here is to connect using Remote Command (RCMD utility) to a list o servers defined in (clusters.txt) and delete a list of video files difines in (assets.txt)... I want to delete those assets on every server. This Batch file works however it has to connect and disconnect to delete every piece of asset and that's exactly what I'm trying to avoid. I want to be able to connect to 1 server and delete my list of assets %%B using scp del cmd then disconnect from that server and go to the next one on the list %%A and delete all the assets from there with just one connection instead of having to connect and disconnect 200 times.
#echo off
FOR /F "tokens=*" %%A IN (clusters.txt) DO FOR /F "tokens=*" %%B in (assets.txt) DO rcmd \\%%A \vstrmkit\scp del %%B
This is what the list of files looks like:
11E8A51A*
11E8A51D*
11E8A614*
11E88E4E*
11E88E4C*
and the list of server it's just computer hostnames with letters and numbers:
SEA88630-N0
Any help would be greatly appreciate it.

Answer 1

Without knowing the server and client versions of the OS, it is possible to have some kind of command line limitations. But, let's try
#echo off
rem prepare environment
setlocal enableextensions enabledelayedexpansion
rem Define the command that will be executed for each element
set "command=echo \vstrmkit\scp del"
rem Prepare the command for the list of files into a environment variable
set "command=set c=%command% "
for /f "tokens=*" %%f in (assets.txt) do set "command=!command!/#c#%%~f"
rem Adjust the command variable to generate a valid concatenation of commands
set "command=%command:/=&%"
rem Connect to each of the servers sending the generated command
rem In the last step, change the # with ! to generate on remote, when
rem delayed expansion is applied, the correct final command to execute
setlocal disabledelayedexpansion
for /f "tokens=*" %%a in (clusters.txt) do rcmd \\%%a cmd.exe /v:on /c "%command:#=!%"
Note that the line where the main command in defined, there is a echo inserted for testing. If everything seems ok, remove echo to do it work.
EDITED - Option number 2
It seems that there is some problem with quotes. The previous code works in my system but not in the OP. Let's try another one. It also works on my system.
#echo off
rem prepare environment
setlocal enableextensions disabledelayedexpansion
rem Define the command that will be executed for each element
set "command=echo \vstrmkit\scp del"
rem Define a temporary file to contain commands to process
set "tempFile=%temp%\%~nx0.tmp"
rem Generate the content of the temp file with the list of commands
rem to execute for each server
(
for /f "tokens=*" %%f in (assets.txt) do echo %command% %%f
echo exit
) > "%tempFile%"
rem Connect to each of the servers sending the generated command list
for /f "tokens=*" %%a in (clusters.txt) do (
rcmd \\%%a < "%tempFile%"
)
del /f /q "%tempFile%" > nul 2>nul
endlocal

Answer 2

#ECHO OFF
SETLOCAL
SET "filelist="
FOR /f "delims=" %%A IN (assets.txt) DO CALL SET filelist=%%filelist%% %%A
FOR /F "tokens=*" %%A IN (clusters.txt) DO echo rcmd \\%%A \vstrmkit\scp del %filelist%
GOTO :EOF
The required commands are merely ECHOed for testing purposes. After you've verified that the commands are correct, change ECHO rcmd to rcmd to execute the deletion
Possible solution if the command can't take multiple arguments:
Create a batch file called delasset.bat and copy it either into \vstrmkit on each target machine or some other directory on the path of each machine (eg c:\windows or c:\windows\system32)
delasset.bat should contain
#ECHO OFF
ECHO DEL %*
(Again, I've simply ECHOed the DEL - you'd need to remove the echo after verifying to activate)
Then change ...rcmd \\%%A \vstrmkit\scp del %filelist% to ...rcmd \\%%A \vstrmkit\scp DELASSET %filelist%
(it's case-insensitive; I've UPPERCASED it for emphasis)
Another possible way:
#ECHO OFF
SETLOCAL
SET "filelist="
FOR /f "delims=" %%A IN (assets.txt) DO CALL SET filelist=%%filelist%%:%%A
SET filelist=%filelist:~1%
FOR /F "tokens=*" %%A IN (clusters.txt) DO echo rcmd \\%%A \vstrmkit\scp del %filelist::=^&\vstrmkit\scp del %
GOTO :EOF
which should generate (eg)
rcmd \\SEA88630-N0 \vstrmkit\scp del 11E8A51A*&\vstrmkit\scp del 11E8A51D*&\vstrmkit\scp del 11E8A614*&\vstrmkit\scp del 11E88E4E*&\vstrmkit\scp del 11E88E4C*
Note that filelist is now built with colons separating the items. Colon cannot be part of a filename. The first character (which will be a colon, since filelist has :filenamefromfile appended to it) is then stripped off (see set/? from the prompt for substring documentation)
The hieroglypics in %filelist::=^&\vstrmkit\scp del % mean 'with filelist, substitute for (first :) [the characters between the first : and the = - which happens to be a colon] with the string &\vstrmkit\scp del (ie. all characters between the = and the closing % - with the additional modification that since & is a special character to cmd (it means 'do the thing before the &, then the thing after') the & needs to be "escaped" by a caret (^) which says "this is a special character that I want to use as an ordinary character".
Leaving the echo firmly in place will allow you to see precisely what should be delivered. Sadly, I've no idea whether it's correct...

Answer 3

Something like this should help.
I don't now for what you have an * after the file-name but it have to be removed by
the script. Or is that a .* ???
EDIT : IF you have various file with the same name and various ("Unknown") extensions then you have to test for the extensions with a new FOR loop :
#echo off
setlocal EnableDelayedExpansion
FOR /F "tokens=*" %%A IN ('type clusters.txt') DO (
FOR /F "tokens=*" %%B in ('type assets.txt') DO (
set $asset=%%B
rcmd.exe \\%%A \vstrmkit\scp del !$asset:~0,-1!.*))